xref: /openbmc/libpldm/tests/meson.build (revision 2643f83c) 
1gtest_dep = dependency('gtest', main: true, disabler: true, required: false)
2gmock_dep = dependency('gmock', disabler: true, required: false)
3if not gtest_dep.found() or not gmock_dep.found()
4    gtest_proj = import('cmake').subproject('googletest', required: true)
5    gtest_dep = declare_dependency(
6            dependencies: [
7                dependency('threads'),
8                gtest_proj.dependency('gtest'),
9                gtest_proj.dependency('gtest_main'),
10            ]
11        )
12        gmock_dep = gtest_proj.dependency('gmock')
13endif
14
15
16tests = [
17  'instance-id',
18  'libpldm_base_test',
19  'libpldm_platform_test',
20  'libpldm_bios_test',
21  'libpldm_bios_table_test',
22  'libpldm_fru_test',
23  'libpldm_utils_test',
24  'libpldm_pdr_test',
25  'libpldm_firmware_update_test',
26  'msgbuf',
27  'responder',
28]
29
30if get_option('abi').contains('testing')
31  tests += [
32    'transport',
33    'transport/send_recv_one',
34    'transport/send_recv_timeout',
35    'transport/send_recv_unwanted',
36    'transport/send_recv_wrong_pldm_type',
37    'transport/send_recv_wrong_command_code'
38  ]
39endif
40
41if get_option('oem-ibm').allowed()
42  tests += [
43    'oem/ibm/libpldm_fileio_test',
44    'oem/ibm/libpldm_host_test',
45  ]
46endif
47
48if get_option('oem-meta').allowed()
49  tests += [
50    'oem/meta/libpldm_fileio_test',
51  ]
52endif
53
54test_include_dirs = [ libpldm_include_dir, include_directories('../src') ]
55
56foreach t : tests
57  test(t, executable(t.underscorify(), t + '.cpp',
58                     implicit_include_directories: false,
59                     include_directories: test_include_dirs,
60                     dependencies: [
61                         libpldm_dep,
62                         gtest_dep,
63                         gmock_dep]),
64       workdir: meson.current_source_dir())
65endforeach
66
67test('bios_table_iter', executable('bios_table_iter',
68                                   'bios_table_iter.c',
69                                   implicit_include_directories: false,
70                                   include_directories: test_include_dirs))
71
72test('msgbuf_generic', executable('msgbuf_generic',
73                                  'msgbuf_generic.c',
74                                  implicit_include_directories: false,
75                                  include_directories: test_include_dirs))
76