xref: /openbmc/libpldm/meson.build (revision f5c63dfd) 
1project(
2    'libpldm',
3    'c',
4    default_options: [
5        'debug=true',
6        'optimization=g',
7        'warning_level=3',
8        'werror=true',
9        'cpp_std=c++23',
10        'c_std=c17',
11        'b_ndebug=if-release',
12        'tests=' + (meson.is_subproject() ? 'disabled' : 'enabled'),
13    ],
14    version: '0.9.1',
15    meson_version: '>=1.1.1',
16)
17
18if get_option('tests').allowed()
19    add_languages('cpp')
20endif
21
22# For memmem() in src/msgbuf.h
23add_project_arguments('-D_GNU_SOURCE', language: ['c'])
24
25compiler = meson.get_compiler('c')
26conf = configuration_data()
27if compiler.has_header('poll.h')
28    conf.set('PLDM_HAS_POLL', 1)
29endif
30
31# ABI control
32visible = '__attribute__((visibility("default")))'
33libpldm_deprecated_aliases = []
34if get_option('abi').contains('deprecated')
35    conf.set('LIBPLDM_ABI_DEPRECATED', visible)
36    add_project_arguments('-DLIBPLDM_API_DEPRECATED', language: ['c', 'cpp'])
37    libpldm_deprecated_aliases += [
38        ['get_fru_record_by_option_check', 'get_fru_record_by_option'],
39        [
40            'pldm_bios_table_attr_entry_string_decode_def_string_length_check',
41            'pldm_bios_table_attr_entry_string_decode_def_string_length',
42        ],
43        [
44            'pldm_bios_table_attr_entry_string_encode_check',
45            'pldm_bios_table_attr_entry_string_encode',
46        ],
47        [
48            'pldm_bios_table_attr_value_entry_encode_enum_check',
49            'pldm_bios_table_attr_value_entry_encode_enum',
50        ],
51        [
52            'pldm_bios_table_attr_value_entry_encode_integer_check',
53            'pldm_bios_table_attr_value_entry_encode_integer',
54        ],
55        [
56            'pldm_bios_table_attr_value_entry_encode_string_check',
57            'pldm_bios_table_attr_value_entry_encode_string',
58        ],
59        [
60            'pldm_bios_table_string_entry_decode_string_check',
61            'pldm_bios_table_string_entry_decode_string',
62        ],
63        [
64            'pldm_bios_table_string_entry_encode_check',
65            'pldm_bios_table_string_entry_encode',
66        ],
67        [
68            'pldm_entity_association_pdr_add_check',
69            'pldm_entity_association_pdr_add',
70        ],
71        [
72            'pldm_entity_association_pdr_add_from_node_check',
73            'pldm_entity_association_pdr_add_from_node',
74        ],
75        ['pldm_pdr_add_check', 'pldm_pdr_add'],
76        ['pldm_pdr_add_fru_record_set_check', 'pldm_pdr_add_fru_record_set'],
77    ]
78else
79    conf.set('LIBPLDM_ABI_DEPRECATED', '')
80endif
81conf.set('LIBPLDM_ABI_STABLE', visible)  # Always expose the stable symbols
82if get_option('abi').contains('testing')
83    conf.set('LIBPLDM_ABI_TESTING', visible)
84    add_project_arguments('-DLIBPLDM_API_TESTING', language: ['c', 'cpp'])
85else
86    conf.set('LIBPLDM_ABI_TESTING', '')
87endif
88
89config = configure_file(output: 'config.h', configuration: conf)
90
91add_project_arguments('-include', '@0@'.format(config), language: 'c')
92
93libpldm_include_dir = include_directories('include', is_system: true)
94
95subdir('include')
96subdir('src')
97
98if get_option('tests').allowed()
99    subdir('tests')
100endif
101
102install_subdir(
103    'instance-db',
104    install_mode: 'r--r--r--',
105    install_dir: get_option('datadir') / meson.project_name(),
106)
107