xref: /openbmc/libpldm/meson.build (revision e48fdd6e) 
1project('libpldm', 'c',
2    default_options: [
3      'debug=true',
4      'optimization=g',
5      'warning_level=3',
6      'werror=true',
7      'cpp_std=c++20',
8      'c_std=c17',
9      'b_ndebug=if-release',
10      'tests=' + (meson.is_subproject() ? 'disabled' : 'enabled'),
11    ],
12    version: '0.8.0',
13    meson_version: '>=1.1.0',
14)
15
16if get_option('tests').allowed()
17  add_languages('cpp')
18endif
19
20# For memmem() in src/msgbuf.h
21add_project_arguments('-D_GNU_SOURCE', language: ['c'])
22
23compiler = meson.get_compiler('c')
24conf = configuration_data()
25if compiler.has_header('poll.h')
26  conf.set('PLDM_HAS_POLL', 1)
27endif
28
29# ABI control
30visible =  '__attribute__((visibility("default")))'
31libpldm_deprecated_aliases = []
32if get_option('abi').contains('deprecated')
33  conf.set('LIBPLDM_ABI_DEPRECATED', visible)
34  add_project_arguments('-DLIBPLDM_API_DEPRECATED', language: ['c', 'cpp'])
35  libpldm_deprecated_aliases += [
36    ['get_fru_record_by_option_check', 'get_fru_record_by_option'],
37    ['pldm_bios_table_string_entry_encode_check', 'pldm_bios_table_string_entry_encode'],
38    ['pldm_entity_association_pdr_add_check', 'pldm_entity_association_pdr_add'],
39    ['pldm_entity_association_pdr_add_from_node_check', 'pldm_entity_association_pdr_add_from_node'],
40    ['pldm_pdr_add_check', 'pldm_pdr_add'],
41    ['pldm_pdr_add_fru_record_set_check', 'pldm_pdr_add_fru_record_set'],
42  ]
43else
44  conf.set('LIBPLDM_ABI_DEPRECATED', '')
45endif
46conf.set('LIBPLDM_ABI_STABLE', visible) # Always expose the stable symbols
47if get_option('abi').contains('testing')
48  conf.set('LIBPLDM_ABI_TESTING', visible)
49  add_project_arguments('-DLIBPLDM_API_TESTING', language: ['c', 'cpp'])
50else
51  conf.set('LIBPLDM_ABI_TESTING', '')
52endif
53
54config = configure_file(output: 'config.h',
55  configuration: conf
56)
57
58add_project_arguments('-include', '@0@'.format(config), language: 'c')
59
60libpldm_include_dir = include_directories('include', is_system: true)
61
62subdir('include')
63subdir('src')
64
65if get_option('tests').allowed()
66  subdir('tests')
67endif
68
69install_subdir('instance-db',
70               install_mode: 'r--r--r--',
71               install_dir: get_option('datadir') / meson.project_name())
72