xref: /openbmc/libpldm/meson.build (revision c79375df) 
1project(
2    'libpldm',
3    'c',
4    default_options: [
5        'debug=true',
6        'optimization=g',
7        'warning_level=3',
8        'werror=true',
9        'cpp_std=c++23',
10        'c_std=c17',
11        'b_ndebug=if-release',
12        'tests=' + (meson.is_subproject() ? 'disabled' : 'enabled'),
13    ],
14    version: '0.9.1',
15    meson_version: '>=1.1.1',
16)
17
18if get_option('tests').allowed()
19    add_languages('cpp')
20endif
21
22# For memmem() in src/msgbuf.h
23add_project_arguments('-D_GNU_SOURCE', language: ['c'])
24
25compiler = meson.get_compiler('c')
26conf = configuration_data()
27if compiler.has_header('poll.h')
28    conf.set('PLDM_HAS_POLL', 1)
29endif
30
31# ABI control
32visible = '__attribute__((visibility("default")))'
33libpldm_deprecated_aliases = []
34if get_option('abi').contains('deprecated')
35    conf.set('LIBPLDM_ABI_DEPRECATED', visible)
36    add_project_arguments('-DLIBPLDM_API_DEPRECATED', language: ['c', 'cpp'])
37    libpldm_deprecated_aliases += [
38        ['get_fru_record_by_option_check', 'get_fru_record_by_option'],
39        [
40            'pldm_entity_association_pdr_add_check',
41            'pldm_entity_association_pdr_add',
42        ],
43        [
44            'pldm_entity_association_pdr_add_from_node_check',
45            'pldm_entity_association_pdr_add_from_node',
46        ],
47        ['pldm_pdr_add_check', 'pldm_pdr_add'],
48        ['pldm_pdr_add_fru_record_set_check', 'pldm_pdr_add_fru_record_set'],
49    ]
50else
51    conf.set('LIBPLDM_ABI_DEPRECATED', '')
52endif
53conf.set('LIBPLDM_ABI_STABLE', visible)  # Always expose the stable symbols
54if get_option('abi').contains('testing')
55    conf.set('LIBPLDM_ABI_TESTING', visible)
56    add_project_arguments('-DLIBPLDM_API_TESTING', language: ['c', 'cpp'])
57else
58    conf.set('LIBPLDM_ABI_TESTING', '')
59endif
60
61config = configure_file(output: 'config.h', configuration: conf)
62
63add_project_arguments('-include', '@0@'.format(config), language: 'c')
64
65libpldm_include_dir = include_directories('include', is_system: true)
66
67subdir('include')
68subdir('src')
69
70if get_option('tests').allowed()
71    subdir('tests')
72endif
73
74install_subdir(
75    'instance-db',
76    install_mode: 'r--r--r--',
77    install_dir: get_option('datadir') / meson.project_name(),
78)
79