xref: /openbmc/libmctp/configure.ac (revision 13a4041f) 
1# Initialization
2AC_PREREQ([2.69])
3AC_INIT([libmctp], 0.9, [https://github.com/openbmc/libmctp/issues])
4AC_CONFIG_HEADERS([config.h])
5AC_CONFIG_MACRO_DIRS([m4])
6AM_INIT_AUTOMAKE([subdir-objects -Wall -Werror foreign dist-xz])
7AM_SILENT_RULES([yes])
8
9# Checks for programs.
10AC_PROG_CC
11AM_PROG_AR
12AC_PROG_INSTALL
13AC_PROG_MAKE_SET
14
15# libtool init
16LT_INIT
17
18# pkg-config
19PKG_PROG_PKG_CONFIG
20PKG_INSTALLDIR
21AC_ARG_WITH([systemdsystemunitdir],
22     [AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files])],
23     [],
24     [with_systemdsystemunitdir=auto]
25)
26AS_IF([test "x$with_systemdsystemunitdir" = "xyes" -o "x$with_systemdsystemunitdir" = "xauto"],
27    [def_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
28     AS_IF([test "x$def_systemdsystemunitdir" = "x"],
29           [AS_IF([test "x$with_systemdsystemunitdir" = "xyes"],
30                  [AC_MSG_ERROR([systemd support requested but pkg-config unable to query systemd package])]
31            )
32            with_systemdsystemunitdir=no],
33           [with_systemdsystemunitdir="$def_systemdsystemunitdir"]
34     )]
35)
36AS_IF([test "x$with_systemdsystemunitdir" != "xno"],
37      [AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])]
38)
39AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$with_systemdsystemunitdir" != "xno"])
40
41# Set defaults for standard library compiles. We may want to
42# AC_ARG_WITH these in the future.
43AC_DEFINE([MCTP_HAVE_SYSLOG], [1], [Define to enable syslog])
44AC_DEFINE([MCTP_HAVE_FILEIO], [1], [Define to enable filesystem functions])
45AC_DEFINE([MCTP_HAVE_STDIO], [1], [Define to enable stdio functions])
46AC_DEFINE([MCTP_DEFAULT_ALLOC], [1],
47    [Define to populate allocation functions to defaults (malloc/free)])
48
49# Enable all bindings. AC_ARG_ENABLE in future.
50AM_CONDITIONAL([LIBMCTP_BINDING_serial], [true])
51AM_CONDITIONAL([LIBMCTP_BINDING_astlpc], [true])
52
53AX_CODE_COVERAGE
54m4_ifdef([_AX_CODE_COVERAGE_RULES],
55    [AM_CONDITIONAL(AUTOCONF_CODE_COVERAGE_2019_01_06, [true])],
56    [AM_CONDITIONAL(AUTOCONF_CODE_COVERAGE_2019_01_06, [false])])
57AX_ADD_AM_MACRO_STATIC([])
58
59AC_CONFIG_FILES([Makefile libmctp.pc])
60AC_OUTPUT
61