xref: /openbmc/libcper/meson.build (revision a3663051b36d33dc4b102109666ee31b0c23582f)
1project(
2    'libcper',
3    ['c', 'cpp'],
4    version: '0.1',
5    meson_version: '>=1.1.1',
6    default_options: [
7        'c_std=c18',
8        'cpp_std=c++23',
9        'tests=' + (meson.is_subproject() ? 'disabled' : 'enabled'),
10        'warning_level=2',
11        'werror=true',
12    ],
13)
14
15add_project_arguments(
16    '-DLIBCPER_JSON_SPEC="'
17    + meson.current_source_dir() + '/specification/json"',
18    language: ['c', 'cpp'],
19)
20
21add_project_arguments('-DLIBCPER_EXAMPLES="'
22    + meson.current_source_dir() + '/examples"', language: ['c', 'cpp'])
23
24library_is_share = get_option('default_library') == 'shared'
25add_project_arguments('-D_POSIX_C_SOURCE=200809L', language: 'c')
26
27if get_option('output-all-properties').enabled()
28    add_project_arguments('-DOUTPUT_ALL_PROPERTIES', language: ['c', 'cpp'])
29endif
30
31project_description = 'libcper library'
32
33libcper_parse_sources = files(
34    'sections/cper-section-ampere.c',
35    'sections/cper-section-arm.c',
36    'sections/cper-section-ccix-per.c',
37    'sections/cper-section-cxl-component.c',
38    'sections/cper-section-cxl-protocol.c',
39    'sections/cper-section-dmar-generic.c',
40    'sections/cper-section-dmar-iommu.c',
41    'sections/cper-section-dmar-vtd.c',
42    'sections/cper-section-firmware.c',
43    'sections/cper-section-generic.c',
44    'sections/cper-section-ia32x64.c',
45    'sections/cper-section-ipf.c',
46    'sections/cper-section-memory.c',
47    'sections/cper-section-nvidia.c',
48    'sections/cper-section-pci-bus.c',
49    'sections/cper-section-pci-dev.c',
50    'sections/cper-section-pcie.c',
51    'sections/cper-section.c',
52)
53
54edk_sources = files('Cper.c')
55
56libcper_generate_sources = files(
57    'generator/sections/gen-section-ampere.c',
58    'generator/sections/gen-section-arm.c',
59    'generator/sections/gen-section-ccix-per.c',
60    'generator/sections/gen-section-cxl-component.c',
61    'generator/sections/gen-section-cxl-protocol.c',
62    'generator/sections/gen-section-dmar.c',
63    'generator/sections/gen-section-firmware.c',
64    'generator/sections/gen-section-generic.c',
65    'generator/sections/gen-section-ia32x64.c',
66    'generator/sections/gen-section-memory.c',
67    'generator/sections/gen-section-nvidia.c',
68    'generator/sections/gen-section-pci-bus.c',
69    'generator/sections/gen-section-pci-dev.c',
70    'generator/sections/gen-section-pcie.c',
71    'generator/sections/gen-section.c',
72)
73
74cc = meson.get_compiler('c')
75
76json_c_dep = dependency('json-c')
77
78libcper_include = ['include']
79libcper_include_dir = include_directories(libcper_include, is_system: true)
80
81
82libcper_parse_sources += files(
83    'base64.c',
84    'common-utils.c',
85    'cper-parse.c',
86    'cper-utils.c',
87    'ir-parse.c',
88    'log.c',
89)
90
91subdir('include')
92
93libcper_parse = library(
94    'cper-parse',
95    libcper_parse_sources,
96    edk_sources,
97    version: meson.project_version(),
98    include_directories: libcper_include_dir,
99    c_args: '-Wno-address-of-packed-member',
100    dependencies: [json_c_dep],
101    install: true,
102    install_dir: get_option('libdir'),
103)
104libcper_parse_dep = declare_dependency(
105    include_directories: libcper_include_dir,
106    link_with: [libcper_parse],
107)
108
109libcper_generate_sources += files(
110    'generator/cper-generate.c',
111    'generator/gen-utils.c',
112)
113
114libcper_generate = library(
115    'cper-generate',
116    libcper_generate_sources,
117    version: meson.project_version(),
118    include_directories: libcper_include_dir,
119    dependencies: [json_c_dep],
120    link_with: [libcper_parse],
121    install: true,
122    install_dir: get_option('libdir'),
123)
124libcper_generate_dep = declare_dependency(
125    include_directories: libcper_include_dir,
126    link_with: libcper_generate,
127)
128
129import('pkgconfig').generate(
130    libcper_parse,
131    name: meson.project_name(),
132    version: meson.project_version(),
133    description: 'C bindings for parsing CPER',
134)
135
136if get_option('utility').allowed()
137    executable(
138        'cper-convert',
139        'cli-app/cper-convert.c',
140        include_directories: libcper_include_dir,
141        dependencies: [json_c_dep],
142        link_with: [libcper_parse, libcper_generate],
143        install: true,
144        install_dir: get_option('bindir'),
145    )
146
147    executable(
148        'cper-generate',
149        'generator/cper-generate-cli.c',
150        edk_sources,
151        include_directories: libcper_include_dir,
152        link_with: [libcper_parse, libcper_generate],
153        install: true,
154        install_dir: get_option('bindir'),
155    )
156endif
157
158# Disable unit tests when output-all-properties is enabled
159# because it changes CPER-IR output format.
160if get_option('output-all-properties').disabled()
161    if get_option('tests').allowed()
162        subdir('tests')
163    endif
164endif
165