xref: /openbmc/ibm-logging/configure.ac (revision 62011e26) 
1AC_PREREQ([2.69])
2AC_INIT([ibm-logging], [1.0], [https://github.com/openbmc/ibm-logging/issues])
3AC_LANG([C++])
4AC_CONFIG_HEADERS([config.h])
5AM_INIT_AUTOMAKE([subdir-objects -Wall -Werror foreign dist-xz])
6AM_SILENT_RULES([yes])
7
8# Checks for programs.
9AC_PROG_CXX
10AC_PROG_INSTALL
11AC_PROG_MAKE_SET
12
13PKG_CHECK_MODULES([PHOSPHOR_DBUS_INTERFACES], [phosphor-dbus-interfaces],,\
14    AC_MSG_ERROR(["Requires openbmc/phosphor-dbus-interfaces package."]))
15PKG_CHECK_MODULES([IBM_DBUS_INTERFACES], [ibm-dbus-interfaces],,\
16    AC_MSG_ERROR(["Requires openbmc/ibm-dbus-interfaces package."]))
17PKG_CHECK_MODULES([SDBUSPLUS], [sdbusplus],,
18    AC_MSG_ERROR(["Requires openbmc/sdbusplus package."]))
19PKG_CHECK_MODULES([PHOSPHOR_LOGGING], [phosphor-logging],,\
20    AC_MSG_ERROR(["Requires openbmc/phosphor-logging package."]))
21
22AC_CHECK_HEADER(nlohmann/json.hpp, ,
23                [AC_MSG_ERROR([Could not find nlohmann/json.hpp... nlohmann/json package required])])
24
25# Checks for typedefs, structures, and compiler characteristics.
26AX_CXX_COMPILE_STDCXX_14([noext])
27AX_APPEND_COMPILE_FLAGS([-Wall -Werror], [CXXFLAGS])
28
29LT_INIT
30
31# Check/set gtest specific functions.
32AX_PTHREAD([GTEST_CPPFLAGS="-DGTEST_HAS_PTHREAD=1"],[GTEST_CPPFLAGS="-DGTEST_HAS_PTHREAD=0"])
33AC_SUBST(GTEST_CPPFLAGS)
34AC_ARG_ENABLE([oe-sdk],
35    AS_HELP_STRING([--enable-oe-sdk], [Link testcases absolutely against OE SDK so they can be ran within it.])
36)
37AC_ARG_VAR(OECORE_TARGET_SYSROOT,
38    [Path to the OE SDK SYSROOT])
39AS_IF([test "x$enable_oe_sdk" == "xyes"],
40    AS_IF([test "x$OECORE_TARGET_SYSROOT" == "x"],
41          AC_MSG_ERROR([OECORE_TARGET_SYSROOT must be set with --enable-oe-sdk])
42    )
43    AC_MSG_NOTICE([Enabling OE-SDK at $OECORE_TARGET_SYSROOT])
44    [
45        testcase_flags="-Wl,-rpath,\${OECORE_TARGET_SYSROOT}/lib"
46        testcase_flags="${testcase_flags} -Wl,-rpath,\${OECORE_TARGET_SYSROOT}/usr/lib"
47        testcase_flags="${testcase_flags} -Wl,-dynamic-linker,`find \${OECORE_TARGET_SYSROOT}/lib/ld-*.so | sort -r -n | head -n1`"
48    ]
49    AC_SUBST([OESDK_TESTCASE_FLAGS], [$testcase_flags])
50)
51
52#The policy data must have been defined by the service folks
53#for it to be used, so allow its use to be configurable and
54#default it to off.
55AC_ARG_ENABLE([policy-interface],
56              AS_HELP_STRING([--enable-policy-interface],
57                             [Enable the Policy D-Bus interface])
58)
59
60AC_ARG_VAR(USE_POLICY_INTERFACE, [If the Policy D-Bus interface should be created])
61
62AS_IF([test "x$enable_policy_interface" == "xyes"],
63      [USE_POLICY_INTERFACE="yes"]
64      AC_DEFINE_UNQUOTED([USE_POLICY_INTERFACE], ["$USE_POLICY_INTERFACE"],
65                         [If the Policy D-Bus interface should be created])
66)
67
68AC_DEFINE(LOGGING_PATH, "/xyz/openbmc_project/logging",
69          [The xyz log manager DBus object path])
70AC_DEFINE(LOGGING_IFACE, "xyz.openbmc_project.Logging.Entry",
71          [The xyz log entry interface])
72AC_DEFINE(LOGGING_BUSNAME, "xyz.openbmc_project.Logging",
73          [The xyz logging busname])
74AC_DEFINE(IBM_LOGGING_BUSNAME, "com.ibm.Logging",
75          [The IBM log manager DBus busname to own])
76
77AC_DEFINE(DEFAULT_POLICY_EID, "None",
78          [The default event ID to use])
79AC_DEFINE(DEFAULT_POLICY_MSG, "An internal BMC error occurred",
80          [The default policy message to use])
81
82AC_ARG_VAR(POLICY_JSON_PATH, [The path to the policy json file])
83AS_IF([test "x$POLICY_JSON_PATH" == "x"], [POLICY_JSON_PATH="/usr/share/ibm-logging/policy.json"])
84AC_DEFINE_UNQUOTED([POLICY_JSON_PATH], ["$POLICY_JSON_PATH"], [The path to the policy json file on the BMC])
85
86AC_CONFIG_FILES([Makefile test/Makefile])
87AC_OUTPUT
88