xref: /openbmc/google-ipmi-sys/meson.build (revision 8d618532) 
1project(
2  'google-ipmi-sys',
3  'cpp',
4  version: '0.1',
5  meson_version: '>=1.1.1',
6  default_options: [
7    'cpp_std=c++23',
8    'warning_level=3',
9    'werror=true',
10  ])
11
12root_inc = include_directories('.')
13
14conf_data = configuration_data()
15conf_data.set_quoted('STATIC_BIFURCATION_CONFIG', get_option('static-bifurcation'))
16conf_h = configure_file(
17  output: 'config.h',
18  configuration: conf_data)
19
20bm_conf_data = configuration_data()
21bm_conf_data.set10('BARE_METAL', get_option('bare_metal'))
22bm_conf_data.set_quoted('BM_SIGNAL_PATH', get_option('bm-signal-path'))
23bm_conf_h = configure_file(
24  output: 'bm_config.h',
25  configuration: bm_conf_data)
26
27meson.get_compiler('cpp').has_header_symbol(
28  'ipmid/api.h',
29  'ipmid_get_sd_bus_connection')
30
31json_dep = dependency('nlohmann_json', required: false)
32meson.get_compiler('cpp').has_header_symbol(
33  'nlohmann/json.hpp',
34  'nlohmann::json',
35  dependencies: json_dep)
36
37fmt_dep = dependency('fmt', required: false)
38if not fmt_dep.found()
39  fmt_proj = import('cmake').subproject(
40    'fmt',
41    cmake_options: [
42      '-DCMAKE_POSITION_INDEPENDENT_CODE=ON',
43      '-DMASTER_PROJECT=OFF'
44    ],
45    required: false)
46  assert(fmt_proj.found(), 'fmtlib is required')
47  fmt_dep = fmt_proj.dependency('fmt')
48endif
49
50subdir('bifurcation')
51
52sys_pre = declare_dependency(
53  include_directories: root_inc,
54  dependencies: [
55    json_dep,
56    fmt_dep,
57    dependency('phosphor-dbus-interfaces'),
58    dependency('phosphor-logging'),
59    dependency('sdbusplus'),
60    dependency('stdplus'),
61    bifurcation_dep,
62  ])
63
64sys_lib = static_library(
65  'sys',
66  'bmc_mode.cpp',
67  'cable.cpp',
68  'cpld.cpp',
69  'entity_name.cpp',
70  'eth.cpp',
71  'flash_size.cpp',
72  'handler.cpp',
73  'host_power_off.cpp',
74  'ipmi.cpp',
75  'linux_boot_done.cpp',
76  'machine_name.cpp',
77  'pcie_i2c.cpp',
78  'google_accel_oob.cpp',
79  'pcie_bifurcation.cpp',
80  'file_system_wrapper.cpp',
81  'psu.cpp',
82  'util.cpp',
83  implicit_include_directories: false,
84  dependencies: sys_pre)
85
86sys_dep = declare_dependency(
87  link_with: sys_lib,
88  dependencies: sys_pre)
89
90if not get_option('tests').disabled()
91  subdir('test')
92endif
93
94shared_module(
95  'googlesys',
96  'main.cpp',
97  implicit_include_directories: false,
98  dependencies: [
99    dependency('libipmid'),
100    sys_dep,
101  ],
102  install: true,
103  install_dir: get_option('libdir') / 'ipmid-providers')
104
105systemd_dep = dependency('systemd')
106if systemd_dep.found()
107  install_data(
108    'gbmc-bare-metal-active.target',
109    'gbmc-host-poweroff.target',
110    'gbmc-psu-hardreset.target',
111    'gbmc-psu-hardreset-pre.target',
112    'gbmc-psu-hardreset-time.service',
113    install_dir: systemd_dep.get_variable('systemdsystemunitdir'))
114endif
115