xref: /openbmc/dbus-sensors/meson.build (revision 8a9ff14a) 
1project(
2    'dbus-sensors',
3    'cpp',
4    default_options: ['warning_level=3', 'werror=true', 'cpp_std=c++20'],
5    license: 'Apache-2.0',
6    version: '0.1',
7    meson_version: '>=1.1',
8)
9
10# Enable io_uring for all daemons with below flags.
11#    '-DBOOST_ASIO_HAS_IO_URING',
12#    '-DBOOST_ASIO_DISABLE_EPOLL',
13#    '-DBOOST_ASIO_USE_TS_EXECUTOR_AS_DEFAULT',
14# Note, there is currently an issue with CPUSensor when used in
15# conjunction with io_uring. So it has not been changed to use
16# random file access. But we'd like to enable it for all daemons.
17# https://github.com/openbmc/dbus-sensors/issues/19
18
19add_project_arguments(
20    '-Wno-psabi',
21    '-Wuninitialized',
22    '-DBOOST_SYSTEM_NO_DEPRECATED',
23    '-DBOOST_ASIO_NO_DEPRECATED',
24    '-DBOOST_ERROR_CODE_HEADER_ONLY',
25    '-DBOOST_NO_RTTI',
26    '-DBOOST_NO_TYPEID',
27    '-DBOOST_ALL_NO_LIB',
28    '-DBOOST_ASIO_DISABLE_THREADS',
29    '-DBOOST_ALLOW_DEPRECATED_HEADERS',
30    '-DBOOST_ASIO_HAS_IO_URING',
31    '-DBOOST_ASIO_DISABLE_EPOLL',
32    '-DBOOST_ASIO_USE_TS_EXECUTOR_AS_DEFAULT',
33    language: 'cpp',
34)
35
36gpiodcxx = dependency(
37    'libgpiodcxx',
38    default_options: ['bindings=cxx'],
39)
40
41# i2c-tools doesn't ship a pkg-config file for libi2c
42i2c = meson.get_compiler('cpp').find_library('i2c')
43
44sdbusplus = dependency('sdbusplus', required: false, include_type: 'system')
45if not sdbusplus.found()
46    sdbusplus_proj = subproject('sdbusplus', required: true)
47    sdbusplus = sdbusplus_proj.get_variable('sdbusplus_dep')
48    sdbusplus = sdbusplus.as_system('system')
49endif
50
51phosphor_logging_dep = dependency('phosphor-logging')
52nlohmann_json_dep = dependency('nlohmann_json', include_type: 'system')
53
54threads = dependency('threads')
55
56boost = dependency(
57    'boost',
58    version: '>=1.79.0',
59    required: false,
60    include_type: 'system',
61)
62if not boost.found()
63    subproject('boost', required: false)
64    boost_inc = include_directories(
65        'subprojects/boost_1_79_0/',
66        is_system: true,
67    )
68    boost = declare_dependency(include_directories: boost_inc)
69    boost = boost.as_system('system')
70endif
71
72uring = dependency('liburing', required: false, include_type: 'system')
73if not uring.found()
74    uring_proj = subproject('liburing', required: true)
75    uring = uring_proj.get_variable('uring')
76    uring = uring.as_system('system')
77endif
78
79default_deps = [
80    boost,
81    nlohmann_json_dep,
82    phosphor_logging_dep,
83    sdbusplus,
84    uring,
85]
86
87subdir('service_files')
88subdir('src')
89
90if not get_option('tests').disabled()
91    subdir('tests')
92endif
93