xref: /openbmc/bmcweb/meson.build (revision f175c280) 
1project(
2    'bmcweb',
3    'cpp',
4    version: '1.0',
5    meson_version: '>=1.3.0',
6    default_options: [
7        'b_lto_mode=default',
8        'b_lto_threads=0',
9        'b_lto=true',
10        'b_ndebug=if-release',
11        'buildtype=debugoptimized',
12        'cpp_rtti=false',
13        'cpp_std=c++23',
14        'warning_level=3',
15        'werror=true',
16    ],
17)
18
19# Project related links
20
21project_pretty_name = 'bmcweb'
22project_url = 'https://github.com/openbmc/' + project_pretty_name
23project_issues_url = project_url + '/issues/new'
24summary('Issues', project_issues_url, section: 'Report Issues')
25
26# Validate the c++ Standard
27
28if get_option('cpp_std') != 'c++23'
29    error('This project requires c++23 support')
30endif
31
32# Get compiler and default build type
33
34cxx = meson.get_compiler('cpp')
35build = get_option('buildtype')
36optimization = get_option('optimization')
37summary('Build Type', build, section: 'Build Info')
38summary('Optimization', optimization, section: 'Build Info')
39
40# remove debug information for minsize buildtype
41if (get_option('buildtype') == 'minsize')
42    add_project_arguments(
43        ['-fdata-sections', '-ffunction-sections'],
44        language: 'cpp',
45    )
46    add_project_arguments('-DNDEBUG', language: 'cpp')
47endif
48
49if (get_option('dns-resolver') == 'systemd-dbus')
50    add_project_arguments('-DBMCWEB_DBUS_DNS_RESOLVER', language: 'cpp')
51endif
52
53# Disable lto when compiling with no optimization
54if (get_option('optimization') == '0')
55    add_project_arguments('-fno-lto', language: 'cpp')
56    message('Disabling lto & its supported features as optimization is disabled')
57endif
58
59# Include Directories
60
61incdir = include_directories(
62    'include',
63    'redfish-core/include',
64    'redfish-core/lib',
65    'http',
66)
67incdir_cli = include_directories('http', 'include')
68
69if (get_option('tests').allowed())
70    summary('unittest', 'NA', section: 'Features')
71endif
72
73# Add compiler arguments
74
75if (cxx.get_id() == 'clang')
76    if (cxx.version().version_compare('<17.0'))
77        error('This project requires clang-17 or higher')
78    endif
79    add_project_arguments(
80        '-Weverything',
81        '-Wformat=2',
82        '-Wno-c++98-compat-pedantic',
83        '-Wno-c++98-compat',
84        '-Wno-c++20-extensions',
85        '-Wno-documentation-unknown-command',
86        '-Wno-documentation',
87        '-Wno-exit-time-destructors',
88        '-Wno-global-constructors',
89        '-Wno-newline-eof',
90        '-Wno-padded',
91        '-Wno-shadow',
92        '-Wno-used-but-marked-unused',
93        '-Wno-weak-vtables',
94        '-Wno-switch-enum',
95        '-Wno-unused-macros',
96        '-Wno-covered-switch-default',
97        '-Wno-disabled-macro-expansion',
98        '-Wno-unneeded-internal-declaration',
99        '-Wno-unsafe-buffer-usage-in-container',
100        language: 'cpp',
101    )
102endif
103
104if (cxx.get_id() == 'gcc')
105    if (cxx.version().version_compare('<13.0'))
106        error('This project requires gcc-13 or higher')
107    endif
108
109    add_project_arguments(
110        '-Wformat=2',
111        '-Wcast-align',
112        '-Wconversion',
113        '-Woverloaded-virtual',
114        '-Wsign-conversion',
115        '-Wunused',
116        '-Wduplicated-cond',
117        '-Wduplicated-branches',
118        '-Wlogical-op',
119        '-Wnull-dereference',
120        '-Wunused-parameter',
121        '-Wdouble-promotion',
122        '-Wshadow',
123        '-Wno-psabi',
124        '-Wno-attributes',
125        language: 'cpp',
126    )
127endif
128
129if (get_option('buildtype') != 'plain')
130    if (get_option('b_lto') == true and get_option('optimization') != '0')
131        # Reduce the binary size by removing unnecessary
132        # dynamic symbol table entries
133
134        add_project_arguments(
135            cxx.get_supported_arguments(
136                [
137                    '-fno-fat-lto-objects',
138                    '-fvisibility=hidden',
139                    '-fvisibility-inlines-hidden',
140                ],
141            ),
142            language: 'cpp',
143        )
144
145        if cxx.has_link_argument('-Wl,--exclude-libs,ALL')
146            add_project_link_arguments('-Wl,--exclude-libs,ALL', language: 'cpp')
147        endif
148    endif
149endif
150# Set Compiler Security flags
151
152security_flags = [
153    '-fstack-protector-strong',
154    '-fPIE',
155    '-fPIC',
156    '-D_FORTIFY_SOURCE=2',
157    '-Wformat',
158    '-Wformat-security',
159]
160
161## Add security flags for builds of type 'release','debugoptimized' and 'minsize'
162
163if not (get_option('buildtype') == 'plain'
164or get_option('buildtype').startswith('debug')
165)
166    add_project_arguments(
167        cxx.get_supported_arguments([security_flags]),
168        language: 'cpp',
169    )
170endif
171
172# Boost dependency configuration
173
174add_project_arguments(
175    cxx.get_supported_arguments(
176        [
177            '-DBOOST_ALL_NO_LIB',
178            '-DBOOST_ALLOW_DEPRECATED_HEADERS',
179            '-DBOOST_ASIO_DISABLE_THREADS',
180            '-DBOOST_ASIO_NO_DEPRECATED',
181            '-DBOOST_ASIO_SEPARATE_COMPILATION',
182            '-DBOOST_BEAST_SEPARATE_COMPILATION',
183            '-DBOOST_EXCEPTION_DISABLE',
184            '-DBOOST_NO_EXCEPTIONS',
185            '-DBOOST_URL_NO_SOURCE_LOCATION',
186            '-DBOOST_SPIRIT_X3_NO_RTTI',
187            '-DJSON_NOEXCEPTION',
188            '-DOPENSSL_NO_FILENAMES',
189            '-DSDBUSPLUS_DISABLE_BOOST_COROUTINES',
190        ],
191    ),
192    language: 'cpp',
193)
194
195# Find the dependency modules, if not found use meson wrap to get them
196# automatically during the configure step
197bmcweb_dependencies = []
198bmcweb_cli_dependencies = []
199
200pam = cxx.find_library('pam', required: true)
201atomic = cxx.find_library('atomic', required: true)
202bmcweb_dependencies += [pam, atomic]
203
204openssl = dependency('openssl', required: false, version: '>=3.0.0')
205if not openssl.found() or get_option('b_sanitize') != 'none'
206    openssl_proj = subproject(
207        'openssl',
208        required: true,
209        default_options: ['warning_level=0', 'werror=false'],
210    )
211    openssl = openssl_proj.get_variable('openssl_dep')
212    openssl = openssl.as_system('system')
213endif
214bmcweb_dependencies += [openssl]
215
216nghttp2 = dependency('libnghttp2', version: '>=1.52.0', required: false)
217if not nghttp2.found()
218    cmake = import('cmake')
219    opt_var = cmake.subproject_options()
220    opt_var.add_cmake_defines(
221        {'ENABLE_LIB_ONLY': true, 'ENABLE_STATIC_LIB': true},
222    )
223    nghttp2_ex = cmake.subproject('nghttp2', options: opt_var)
224    nghttp2 = nghttp2_ex.dependency('nghttp2')
225endif
226bmcweb_dependencies += nghttp2
227
228sdbusplus = dependency('sdbusplus', required: false, include_type: 'system')
229if not sdbusplus.found()
230    sdbusplus_proj = subproject('sdbusplus', required: true)
231    sdbusplus = sdbusplus_proj.get_variable('sdbusplus_dep')
232    sdbusplus = sdbusplus.as_system('system')
233endif
234bmcweb_dependencies += sdbusplus
235bmcweb_cli_dependencies += sdbusplus
236
237cli11 = dependency('CLI11', required: false, include_type: 'system')
238if not cli11.found()
239    cli11_proj = subproject('cli11', required: true)
240    cli11 = cli11_proj.get_variable('CLI11_dep')
241    cli11 = cli11.as_system('system')
242endif
243bmcweb_cli_dependencies += cli11
244
245
246tinyxml = dependency(
247    'tinyxml2',
248    include_type: 'system',
249    version: '>=9.0.0',
250    default_options: ['tests=false'],
251)
252if not tinyxml.found()
253    tinyxml_proj = subproject('tinyxml2', required: true)
254    tinyxml = tinyxml_proj.get_variable('tinyxml_dep')
255    tinyxml = tinyxml.as_system('system')
256endif
257bmcweb_dependencies += tinyxml
258
259systemd = dependency('systemd')
260libsystemd = dependency('libsystemd')
261add_project_arguments(
262    '-DLIBSYSTEMD_VERSION=' + libsystemd.version(),
263    language: 'cpp',
264)
265
266zlib = dependency('zlib')
267bmcweb_dependencies += [libsystemd, zlib]
268
269nlohmann_json_dep = dependency(
270    'nlohmann_json',
271    version: '>=3.11.3',
272    include_type: 'system',
273)
274bmcweb_dependencies += nlohmann_json_dep
275
276boost = dependency(
277    'boost',
278    modules: ['url'],
279    version: '>=1.84.0',
280    required: false,
281    include_type: 'system',
282)
283
284# Boost version is 1.86 or higher to include the 'process' module
285if boost.version().version_compare('>=1.86.0')
286    boost = dependency(
287        'boost',
288        modules: ['url', 'process'],
289        version: '>=1.86.0',
290        required: false,
291        include_type: 'system',
292    )
293endif
294
295if boost.found()
296    bmcweb_dependencies += [boost]
297    bmcweb_cli_dependencies += [boost]
298else
299    cmake = import('cmake')
300    opt = cmake.subproject_options()
301    boost_libs = [
302        'asio',
303        'beast',
304        'circular_buffer',
305        'callable_traits',
306        'headers',
307        'process',
308        'type_index',
309        'url',
310        'uuid',
311        'spirit',
312    ]
313    opt.add_cmake_defines(
314        {
315            # 1.86.0 fails this.  Hopefully fixed in 1.86.1
316            'CMAKE_CXX_FLAGS': '-Wno-unused-parameter',
317            'BOOST_INCLUDE_LIBRARIES': ';'.join(boost_libs),
318            'BUILD_SHARED_LIBS': 'OFF',
319        },
320    )
321
322    boost = cmake.subproject('boost', required: true, options: opt)
323    foreach boost_lib : boost_libs
324        boost_lib_instance = boost.dependency('boost_' + boost_lib).as_system()
325        bmcweb_dependencies += [boost_lib_instance]
326        bmcweb_cli_dependencies += [boost_lib_instance]
327    endforeach
328endif
329
330systemd_system_unit_dir = systemd.get_variable('systemdsystemunitdir')
331
332bindir = get_option('prefix') + '/' + get_option('bindir')
333libexec = get_option('prefix') + '/' + get_option('libexecdir')
334
335summary(
336    {
337        'prefix': get_option('prefix'),
338        'bindir': bindir,
339        'systemd unit directory': systemd_system_unit_dir,
340    },
341    section: 'Directories',
342)
343
344subdir('static')
345subdir('redfish-core')
346
347# Config subdirectory
348subdir('config')
349bmcweb_dependencies += conf_h_dep
350bmcweb_cli_dependencies += conf_h_dep
351
352# Source files
353fs = import('fs')
354
355srcfiles_bmcweb = files(
356    'http/mutual_tls.cpp',
357    'redfish-core/src/dbus_log_watcher.cpp',
358    'redfish-core/src/error_messages.cpp',
359    'redfish-core/src/task_messages.cpp',
360    'redfish-core/src/event_log.cpp',
361    'redfish-core/src/filesystem_log_watcher.cpp',
362    'redfish-core/src/filter_expr_executor.cpp',
363    'redfish-core/src/filter_expr_printer.cpp',
364    'redfish-core/src/redfish.cpp',
365    'redfish-core/src/registries.cpp',
366    'redfish-core/src/subscription.cpp',
367    'redfish-core/src/utils/dbus_utils.cpp',
368    'redfish-core/src/utils/json_utils.cpp',
369    'redfish-core/src/utils/time_utils.cpp',
370    'src/boost_asio.cpp',
371    'src/boost_asio_ssl.cpp',
372    'src/boost_beast.cpp',
373    'src/dbus_singleton.cpp',
374    'src/json_html_serializer.cpp',
375    'src/ossl_random.cpp',
376    'src/ssl_key_handler.cpp',
377    'src/webserver_run.cpp',
378)
379
380bmcweblib = static_library(
381    'bmcweblib',
382    srcfiles_bmcweb,
383    include_directories: incdir,
384    dependencies: bmcweb_dependencies,
385)
386
387# Generate the bmcwebd daemon
388executable(
389    'bmcwebd',
390    'src/webserver_main.cpp',
391    include_directories: incdir,
392    dependencies: bmcweb_dependencies,
393    link_with: bmcweblib,
394    link_args: '-Wl,--gc-sections',
395    install: true,
396    install_dir: libexec,
397)
398
399# Generate the bmcweb CLI application
400executable(
401    'bmcweb',
402    ['src/webserver_cli.cpp', 'src/boost_asio.cpp'],
403    include_directories: incdir_cli,
404    dependencies: bmcweb_cli_dependencies,
405    install: true,
406    install_dir: bindir,
407)
408
409srcfiles_unittest = files(
410    'test/http/crow_getroutes_test.cpp',
411    'test/http/http2_connection_test.cpp',
412    'test/http/http_body_test.cpp',
413    'test/http/http_connection_test.cpp',
414    'test/http/http_response_test.cpp',
415    'test/http/mutual_tls.cpp',
416    'test/http/mutual_tls_meta.cpp',
417    'test/http/parsing_test.cpp',
418    'test/http/router_test.cpp',
419    'test/http/server_sent_event_test.cpp',
420    'test/http/utility_test.cpp',
421    'test/http/verb_test.cpp',
422    'test/include/async_resolve_test.cpp',
423    'test/include/credential_pipe_test.cpp',
424    'test/include/dbus_utility_test.cpp',
425    'test/include/google/google_service_root_test.cpp',
426    'test/include/http_utility_test.cpp',
427    'test/include/human_sort_test.cpp',
428    'test/include/ibm/configfile_test.cpp',
429    'test/include/json_html_serializer.cpp',
430    'test/include/multipart_test.cpp',
431    'test/include/openbmc_dbus_rest_test.cpp',
432    'test/include/ossl_random.cpp',
433    'test/include/ssl_key_handler_test.cpp',
434    'test/include/str_utility_test.cpp',
435    'test/redfish-core/include/event_log_test.cpp',
436    'test/redfish-core/include/event_matches_filter_test.cpp',
437    'test/redfish-core/include/filter_expr_executor_test.cpp',
438    'test/redfish-core/include/filter_expr_parser_test.cpp',
439    'test/redfish-core/include/privileges_test.cpp',
440    'test/redfish-core/include/redfish_aggregator_test.cpp',
441    'test/redfish-core/include/registries_test.cpp',
442    'test/redfish-core/include/utils/dbus_utils.cpp',
443    'test/redfish-core/include/utils/hex_utils_test.cpp',
444    'test/redfish-core/include/utils/ip_utils_test.cpp',
445    'test/redfish-core/include/utils/json_utils_test.cpp',
446    'test/redfish-core/include/redfish_test.cpp',
447    'test/redfish-core/include/utils/query_param_test.cpp',
448    'test/redfish-core/include/utils/sensor_utils_test.cpp',
449    'test/redfish-core/include/utils/stl_utils_test.cpp',
450    'test/redfish-core/include/utils/time_utils_test.cpp',
451    'test/redfish-core/lib/chassis_test.cpp',
452    'test/redfish-core/lib/log_services_dump_test.cpp',
453    'test/redfish-core/lib/manager_diagnostic_data_test.cpp',
454    'test/redfish-core/lib/metadata_test.cpp',
455    'test/redfish-core/lib/power_subsystem_test.cpp',
456    'test/redfish-core/lib/service_root_test.cpp',
457    'test/redfish-core/lib/system_test.cpp',
458    'test/redfish-core/lib/systems_logservices_postcode.cpp',
459    'test/redfish-core/lib/thermal_subsystem_test.cpp',
460    'test/redfish-core/lib/update_service_test.cpp',
461)
462
463if (get_option('tests').allowed())
464    gtest = dependency(
465        'gtest_main',
466        main: true,
467        version: '>=1.15.0',
468        required: true,
469    )
470    gmock = dependency('gmock', required: true)
471    gtestlib = static_library('gtestlib', dependencies: [gtest, gmock])
472    gtestdep = declare_dependency(
473        link_with: gtestlib,
474        dependencies: [
475            gtest.partial_dependency(includes: true),
476            gmock.partial_dependency(includes: true),
477        ],
478    )
479    # generate the test executable
480    foreach test_src : srcfiles_unittest
481        test_bin = executable(
482            fs.stem(test_src),
483            test_src,
484            link_with: bmcweblib,
485            include_directories: incdir,
486            install_dir: bindir,
487            dependencies: bmcweb_dependencies + [gtestdep],
488        )
489        test(fs.stem(test_src), test_bin, protocol: 'gtest')
490    endforeach
491endif
492