xref: /openbmc/bmcweb/meson.build (revision d02aad3988620c648d6e696b67d6c542857f5bfc) 
1project('bmcweb', 'cpp',
2        version : '1.0',
3        meson_version: '>=0.63.0',
4        default_options: [
5            'b_lto_mode=default',
6            'b_lto_threads=0',
7            'b_lto=true',
8            'b_ndebug=if-release',
9            'buildtype=debugoptimized',
10            'cpp_rtti=false',
11            'cpp_std=c++20',
12            'warning_level=3',
13            'werror=true',
14           ])
15
16# Project related links
17
18project_pretty_name = 'bmcweb'
19project_url = 'https://github.com/openbmc/' + project_pretty_name
20project_issues_url = project_url + '/issues/new'
21summary('Issues',project_issues_url, section: 'Report Issues')
22
23# Validate the c++ Standard
24
25if get_option('cpp_std') != 'c++20'
26    error('This project requires c++20 support')
27endif
28
29# Get compiler and default build type
30
31cxx = meson.get_compiler('cpp')
32build = get_option('buildtype')
33optimization = get_option('optimization')
34summary('Build Type',build, section : 'Build Info')
35summary('Optimization',optimization, section : 'Build Info')
36
37
38# remove debug information for minsize buildtype
39if(get_option('buildtype') == 'minsize')
40  add_project_arguments(['-fdata-sections', '-ffunction-sections'], language : 'cpp')
41  add_project_arguments('-DNDEBUG', language : 'cpp')
42endif
43
44if(get_option('dns-resolver') == 'systemd-dbus')
45  add_project_arguments('-DBMCWEB_DBUS_DNS_RESOLVER', language : 'cpp')
46endif
47
48# Disable lto when compiling with no optimization
49if(get_option('optimization') == '0')
50  add_project_arguments('-fno-lto', language: 'cpp')
51  message('Disabling lto & its supported features as optimization is disabled')
52endif
53
54# Include Directories
55
56incdir = include_directories(
57  'include',
58  'redfish-core/include',
59  'redfish-core/lib',
60  'http'
61)
62
63# Get the options and enable the respective features
64## create a MAP of  "options : feature_flag"
65
66feature_map = {
67  'basic-auth'                                  : '-DBMCWEB_ENABLE_BASIC_AUTHENTICATION',
68  'cookie-auth'                                 : '-DBMCWEB_ENABLE_COOKIE_AUTHENTICATION',
69  'google-api'                                  : '-DBMCWEB_ENABLE_GOOGLE_API',
70  'host-serial-socket'                          : '-DBMCWEB_ENABLE_HOST_SERIAL_WEBSOCKET',
71  'ibm-management-console'                      : '-DBMCWEB_ENABLE_IBM_MANAGEMENT_CONSOLE',
72  'insecure-disable-auth'                       : '-DBMCWEB_INSECURE_DISABLE_AUTHX',
73  'insecure-disable-csrf'                       : '-DBMCWEB_INSECURE_DISABLE_CSRF_PREVENTION',
74  'insecure-disable-ssl'                        : '-DBMCWEB_INSECURE_DISABLE_SSL',
75  'insecure-push-style-notification'            : '-DBMCWEB_INSECURE_ENABLE_HTTP_PUSH_STYLE_EVENTING',
76  'insecure-tftp-update'                        : '-DBMCWEB_INSECURE_ENABLE_REDFISH_FW_TFTP_UPDATE',
77  'insecure-ignore-content-type'                : '-DBMCWEB_INSECURE_IGNORE_CONTENT_TYPE',
78  'kvm'                                         : '-DBMCWEB_ENABLE_KVM' ,
79  'mutual-tls-auth'                             : '-DBMCWEB_ENABLE_MUTUAL_TLS_AUTHENTICATION',
80  'redfish-aggregation'                         : '-DBMCWEB_ENABLE_REDFISH_AGGREGATION',
81  'redfish-allow-deprecated-power-thermal'      : '-DBMCWEB_ALLOW_DEPRECATED_POWER_THERMAL',
82  'redfish-bmc-journal'                         : '-DBMCWEB_ENABLE_REDFISH_BMC_JOURNAL',
83  'redfish-cpu-log'                             : '-DBMCWEB_ENABLE_REDFISH_CPU_LOG',
84  'redfish-dbus-log'                            : '-DBMCWEB_ENABLE_REDFISH_DBUS_LOG_ENTRIES',
85  'redfish-dump-log'                            : '-DBMCWEB_ENABLE_REDFISH_DUMP_LOG',
86  'redfish-host-logger'                         : '-DBMCWEB_ENABLE_REDFISH_HOST_LOGGER',
87  'redfish-new-powersubsystem-thermalsubsystem' : '-DBMCWEB_NEW_POWERSUBSYSTEM_THERMALSUBSYSTEM',
88  'redfish-oem-manager-fan-data'                : '-DBMCWEB_ENABLE_REDFISH_OEM_MANAGER_FAN_DATA',
89  'redfish-provisioning-feature'                : '-DBMCWEB_ENABLE_REDFISH_PROVISIONING_FEATURE',
90  'redfish'                                     : '-DBMCWEB_ENABLE_REDFISH',
91  'rest'                                        : '-DBMCWEB_ENABLE_DBUS_REST',
92  'session-auth'                                : '-DBMCWEB_ENABLE_SESSION_AUTHENTICATION',
93  'static-hosting'                              : '-DBMCWEB_ENABLE_STATIC_HOSTING',
94  'experimental-redfish-multi-computer-system'  : '-DBMCWEB_ENABLE_MULTI_COMPUTERSYSTEM',
95  'vm-websocket'                                : '-DBMCWEB_ENABLE_VM_WEBSOCKET',
96  'xtoken-auth'                                 : '-DBMCWEB_ENABLE_XTOKEN_AUTHENTICATION',
97  #'vm-nbdproxy'                                : '-DBMCWEB_ENABLE_VM_NBDPROXY',
98}
99
100# Get the options status and build a project summary to show which flags are
101# being enabled during the configuration time.
102
103foreach option_key,option_value : feature_map
104  if(get_option(option_key).allowed())
105    if(option_key == 'mutual-tls-auth' or option_key == 'insecure-disable-ssl')
106      if(get_option('insecure-disable-ssl').disabled() or get_option('mutual-tls-auth').disabled())
107        add_project_arguments(option_value,language:'cpp')
108        summary(option_key,option_value, section : 'Enabled Features')
109      endif
110    elif (option_key in ['basic-auth', 'cookie-auth', 'session-auth', 'xtoken-auth', 'mutual-tls-auth'])
111      if (get_option('insecure-disable-auth').disabled())
112        add_project_arguments(option_value, language:'cpp')
113        summary(option_key,option_value, section : 'Enabled Features')
114      endif
115    else
116      summary(option_key,option_value, section : 'Enabled Features')
117      add_project_arguments(option_value,language:'cpp')
118    endif
119  else
120      if(option_key == 'insecure-disable-ssl')
121        summary('ssl','-DBMCWEB_ENABLE_SSL', section : 'Enabled Features')
122        add_project_arguments('-DBMCWEB_ENABLE_SSL', language : 'cpp')
123      endif
124  endif
125endforeach
126
127if(get_option('tests').allowed())
128  summary('unittest','NA', section : 'Enabled Features')
129endif
130
131# Add compiler arguments
132
133if (cxx.get_id() == 'clang')
134  if (cxx.version().version_compare('<17.0'))
135    error('This project requires clang-17 or higher')
136  endif
137  add_project_arguments(
138    '-Weverything',
139    '-Wformat=2',
140    '-Wno-c++98-compat-pedantic',
141    '-Wno-c++98-compat',
142    '-Wno-documentation-unknown-command',
143    '-Wno-documentation',
144    '-Wno-exit-time-destructors',
145    '-Wno-global-constructors',
146    '-Wno-newline-eof',
147    '-Wno-padded',
148    '-Wno-shadow',
149    '-Wno-used-but-marked-unused',
150    '-Wno-weak-vtables',
151    '-Wno-switch-enum',
152    '-Wno-unused-macros',
153    language:'cpp')
154endif
155
156if (cxx.get_id() == 'gcc')
157  if (cxx.version().version_compare('<13.0'))
158    error('This project requires gcc-13 or higher')
159  endif
160
161  add_project_arguments(
162    '-Wformat=2',
163    '-Wcast-align',
164    '-Wconversion',
165    '-Woverloaded-virtual',
166    '-Wsign-conversion',
167    '-Wunused',
168    '-Wduplicated-cond',
169    '-Wduplicated-branches',
170    '-Wlogical-op',
171    '-Wnull-dereference',
172    '-Wunused-parameter',
173    '-Wdouble-promotion',
174    '-Wshadow',
175    '-Wno-psabi',
176    '-Wno-attributes',
177    language:'cpp')
178endif
179
180if (get_option('buildtype') != 'plain')
181  if (get_option('b_lto') == true and get_option('optimization')!='0')
182    # Reduce the binary size by removing unnecessary
183    # dynamic symbol table entries
184
185    add_project_arguments(
186     cxx.get_supported_arguments([
187     '-fno-fat-lto-objects',
188     '-fvisibility=hidden',
189     '-fvisibility-inlines-hidden'
190     ]),
191     language: 'cpp')
192
193    if cxx.has_link_argument('-Wl,--exclude-libs,ALL')
194      add_project_link_arguments('-Wl,--exclude-libs,ALL', language: 'cpp')
195    endif
196  endif
197endif
198
199if( get_option('bmcweb-logging') != 'disabled' or \
200    get_option('buildtype').startswith('debug'))
201 add_project_arguments([
202   '-DBMCWEB_ENABLE_DEBUG'
203   ],
204  language : 'cpp')
205
206  summary('debug', '-DBMCWEB_ENABLE_DEBUG', section : 'Enabled Features')
207endif
208
209# Set Compiler Security flags
210
211security_flags = [
212  '-fstack-protector-strong',
213  '-fPIE',
214  '-fPIC',
215  '-D_FORTIFY_SOURCE=2',
216  '-Wformat',
217  '-Wformat-security'
218]
219
220## Add security flags for builds of type 'release','debugoptimized' and 'minsize'
221
222if not (get_option('buildtype') == 'plain' or get_option('buildtype').startswith('debug'))
223  add_project_arguments(
224   cxx.get_supported_arguments([
225    security_flags
226  ]),
227  language: 'cpp')
228endif
229
230# Boost dependency configuration
231
232add_project_arguments(
233cxx.get_supported_arguments([
234  '-DBOOST_ASIO_DISABLE_CONCEPTS',
235  '-DBOOST_ALL_NO_LIB',
236  '-DBOOST_ALLOW_DEPRECATED_HEADERS',
237  '-DBOOST_ASIO_DISABLE_THREADS',
238  '-DBOOST_ASIO_NO_DEPRECATED',
239  '-DBOOST_ASIO_SEPARATE_COMPILATION',
240  '-DBOOST_BEAST_SEPARATE_COMPILATION',
241  '-DBOOST_EXCEPTION_DISABLE',
242  '-DBOOST_NO_EXCEPTIONS',
243  '-DBOOST_URL_NO_SOURCE_LOCATION',
244  '-DJSON_NOEXCEPTION',
245  '-DOPENSSL_NO_FILENAMES',
246  '-DSDBUSPLUS_DISABLE_BOOST_COROUTINES',
247]),
248language : 'cpp')
249
250# Find the dependency modules, if not found use meson wrap to get them
251# automatically during the configure step
252bmcweb_dependencies = []
253
254pam = cxx.find_library('pam', required: true)
255atomic =  cxx.find_library('atomic', required: true)
256bmcweb_dependencies += [pam, atomic]
257
258openssl = dependency('openssl', required : false, version: '>=3.0.0')
259if not openssl.found() or get_option('b_sanitize') != 'none'
260  openssl_proj = subproject(
261    'openssl',
262    required: true,
263    default_options: ['warning_level=0', 'werror=false']
264  )
265  openssl = openssl_proj.get_variable('openssl_dep')
266  openssl = openssl.as_system('system')
267else
268  # When we build openssl as a subproject, the warnings analyzer starts
269  # flagging all the C macros as old style casts, so only enable the
270  # warning for non subprojects.
271  add_project_arguments('-Wold-style-cast', language: 'cpp')
272endif
273bmcweb_dependencies += [openssl]
274
275nghttp2 = dependency('libnghttp2', version: '>=1.52.0', required : false)
276if not nghttp2.found()
277  cmake = import('cmake')
278  opt_var = cmake.subproject_options()
279  opt_var.add_cmake_defines({
280    'ENABLE_LIB_ONLY': true,
281    'ENABLE_STATIC_LIB': true
282  })
283  nghttp2_ex = cmake.subproject('nghttp2', options: opt_var)
284  nghttp2 = nghttp2_ex.dependency('nghttp2')
285endif
286bmcweb_dependencies += nghttp2
287
288sdbusplus = dependency('sdbusplus', required : false, include_type: 'system')
289if not sdbusplus.found()
290  sdbusplus_proj = subproject('sdbusplus', required: true)
291  sdbusplus = sdbusplus_proj.get_variable('sdbusplus_dep')
292  sdbusplus = sdbusplus.as_system('system')
293endif
294bmcweb_dependencies += sdbusplus
295
296tinyxml = dependency(
297    'tinyxml2',
298    include_type: 'system',
299    version: '>=9.0.0',
300)
301if not tinyxml.found()
302    tinyxml_proj = subproject('tinyxml2', required: true)
303    tinyxml = tinyxml_proj.get_variable('tinyxml_dep')
304    tinyxml = tinyxml.as_system('system')
305endif
306bmcweb_dependencies += tinyxml
307
308systemd = dependency('systemd')
309zlib = dependency('zlib')
310bmcweb_dependencies += [systemd, zlib]
311
312nlohmann_json_dep = dependency('nlohmann_json', version: '>=3.11.2', include_type: 'system')
313bmcweb_dependencies += nlohmann_json_dep
314
315boost = dependency(
316  'boost',
317  modules: [
318    'url',
319    ],
320  version : '>=1.84.0',
321  required : false,
322  include_type: 'system'
323)
324if boost.found()
325  bmcweb_dependencies += [boost]
326else
327  cmake = import('cmake')
328  opt = cmake.subproject_options()
329  opt.add_cmake_defines({
330    'BOOST_INCLUDE_LIBRARIES': 'asio;beast;callable_traits;headers;process;type_index;url;uuid'
331  })
332  boost = cmake.subproject('boost', required: true, options: opt)
333  boost_asio = boost.dependency('boost_asio').as_system()
334  boost_beast = boost.dependency('boost_beast').as_system()
335  boost_callable_traits = boost.dependency('boost_callable_traits').as_system()
336  boost_headers = boost.dependency('boost_headers').as_system()
337  boost_process = boost.dependency('boost_process').as_system()
338  boost_type_index = boost.dependency('boost_type_index').as_system()
339  boost_url = boost.dependency('boost_url').as_system()
340  boost_uuid = boost.dependency('boost_uuid').as_system()
341  bmcweb_dependencies += [
342    boost_asio,
343    boost_beast,
344    boost_callable_traits,
345    boost_headers,
346    boost_process,
347    boost_type_index,
348    boost_url,
349    boost_uuid
350  ]
351endif
352
353if get_option('tests').allowed()
354  gtest = dependency('gtest', main: true, version: '>=1.14.0', disabler: true, required : false)
355  gmock = dependency('gmock', required : false)
356  if not gtest.found() and get_option('tests').allowed()
357    gtest_proj = subproject('gtest', required: true)
358    gtest = gtest_proj.get_variable('gtest_main_dep')
359    gmock = gtest_proj.get_variable('gmock_dep')
360  endif
361  gtest = gtest.as_system('system')
362  gmock = gmock.as_system('system')
363endif
364
365systemd_system_unit_dir = systemd.get_variable('systemdsystemunitdir')
366
367bindir = get_option('prefix') + '/' +get_option('bindir')
368
369summary({
370          'prefix' : get_option('prefix'),
371          'bindir' : bindir,
372          'systemd unit directory' : systemd_system_unit_dir
373        }, section : 'Directories')
374
375install_subdir('static', install_dir : 'share/www', strip_directory : true)
376
377# Config subdirectory
378
379subdir('config')
380bmcweb_dependencies += conf_h_dep
381
382# Source files
383fs = import('fs')
384
385srcfiles_bmcweb = files(
386  'redfish-core/src/error_messages.cpp',
387  'redfish-core/src/registries.cpp',
388  'redfish-core/src/utils/dbus_utils.cpp',
389  'redfish-core/src/utils/time_utils.cpp',
390  'redfish-core/src/utils/json_utils.cpp',
391  'src/boost_asio_ssl.cpp',
392  'src/boost_asio.cpp',
393  'src/boost_beast.cpp',
394  'src/dbus_singleton.cpp',
395  'src/json_html_serializer.cpp',
396  'src/ossl_random.cpp',
397)
398
399bmcweblib = static_library(
400  'bmcweblib',
401  srcfiles_bmcweb,
402  include_directories : incdir,
403  dependencies: bmcweb_dependencies,
404)
405
406# Generate the bmcweb executable
407executable(
408  'bmcweb',
409  'src/webserver_main.cpp',
410  include_directories : incdir,
411  dependencies: bmcweb_dependencies,
412  link_with: bmcweblib,
413  link_args: '-Wl,--gc-sections',
414  install: true,
415  install_dir:bindir
416)
417
418srcfiles_unittest = files(
419  'test/http/crow_getroutes_test.cpp',
420  'test/http/http2_connection_test.cpp',
421  'test/http/http_connection_test.cpp',
422  'test/http/mutual_tls.cpp',
423  'test/http/router_test.cpp',
424  'test/http/parsing_test.cpp',
425  'test/http/http_response_test.cpp',
426  'test/http/utility_test.cpp',
427  'test/http/verb_test.cpp',
428  'test/http/server_sent_event_test.cpp',
429  'test/http/mutual_tls_meta.cpp',
430  'test/http/http_body_test.cpp',
431  'test/include/dbus_utility_test.cpp',
432  'test/include/google/google_service_root_test.cpp',
433  'test/include/json_html_serializer.cpp',
434  'test/include/http_utility_test.cpp',
435  'test/include/human_sort_test.cpp',
436  'test/include/async_resolve_test.cpp',
437  'test/include/credential_pipe_test.cpp',
438  'test/include/ibm/configfile_test.cpp',
439  'test/include/ibm/lock_test.cpp',
440  'test/include/multipart_test.cpp',
441  'test/include/openbmc_dbus_rest_test.cpp',
442  'test/include/str_utility_test.cpp',
443  'test/include/ossl_random.cpp',
444  'test/redfish-core/include/privileges_test.cpp',
445  'test/redfish-core/include/redfish_aggregator_test.cpp',
446  'test/redfish-core/include/registries_test.cpp',
447  'test/redfish-core/include/utils/hex_utils_test.cpp',
448  'test/redfish-core/include/utils/dbus_utils.cpp',
449  'test/redfish-core/include/utils/ip_utils_test.cpp',
450  'test/redfish-core/include/utils/json_utils_test.cpp',
451  'test/redfish-core/include/utils/query_param_test.cpp',
452  'test/redfish-core/include/utils/stl_utils_test.cpp',
453  'test/redfish-core/include/utils/time_utils_test.cpp',
454  'test/redfish-core/lib/chassis_test.cpp',
455  'test/redfish-core/lib/sensors_test.cpp',
456  'test/redfish-core/lib/system_test.cpp',
457  'test/redfish-core/lib/log_services_dump_test.cpp',
458  'test/redfish-core/lib/log_services_test.cpp',
459  'test/redfish-core/lib/update_service_test.cpp',
460  'test/redfish-core/lib/service_root_test.cpp',
461  'test/redfish-core/lib/thermal_subsystem_test.cpp',
462  'test/redfish-core/lib/power_subsystem_test.cpp',
463  'test/redfish-core/lib/manager_diagnostic_data_test.cpp',
464)
465
466
467if(get_option('tests').allowed())
468    # generate the test executable
469    foreach test_src : srcfiles_unittest
470      test_bin = executable(
471        fs.stem(test_src),
472        test_src,
473        link_with: bmcweblib,
474        include_directories : incdir,
475        install_dir: bindir,
476        dependencies: bmcweb_dependencies + [
477          gtest,
478          gmock,
479        ]
480      )
481      test(fs.stem(test_src), test_bin)
482    endforeach
483endif
484