xref: /openbmc/bmcweb/meson.build (revision cfe3bc0a) 
1project('bmcweb', 'cpp',
2        version : '1.0',
3        meson_version: '>=0.63.0',
4        default_options: [
5            'b_lto_mode=default',
6            'b_lto_threads=0',
7            'b_lto=true',
8            'b_ndebug=if-release',
9            'buildtype=debugoptimized',
10            'cpp_rtti=false',
11            'cpp_std=c++20',
12            'warning_level=3',
13            'werror=true',
14           ])
15
16# Project related links
17
18project_pretty_name = 'bmcweb'
19project_url = 'https://github.com/openbmc/' + project_pretty_name
20project_issues_url = project_url + '/issues/new'
21summary('Issues',project_issues_url, section: 'Report Issues')
22
23# Validate the c++ Standard
24
25if get_option('cpp_std') != 'c++20'
26    error('This project requires c++20 support')
27endif
28
29# Get compiler and default build type
30
31cxx = meson.get_compiler('cpp')
32build = get_option('buildtype')
33optimization = get_option('optimization')
34summary('Build Type',build, section : 'Build Info')
35summary('Optimization',optimization, section : 'Build Info')
36
37
38# remove debug information for minsize buildtype
39if(get_option('buildtype') == 'minsize')
40  add_project_arguments(['-fdata-sections', '-ffunction-sections'], language : 'cpp')
41  add_project_arguments('-DNDEBUG', language : 'cpp')
42endif
43
44if(get_option('dns-resolver') == 'systemd-dbus')
45  add_project_arguments('-DBMCWEB_DBUS_DNS_RESOLVER', language : 'cpp')
46endif
47
48# Disable lto when compiling with no optimization
49if(get_option('optimization') == '0')
50  add_project_arguments('-fno-lto', language: 'cpp')
51  message('Disabling lto & its supported features as optimization is disabled')
52endif
53
54# Include Directories
55
56incdir = include_directories(
57  'include',
58  'redfish-core/include',
59  'redfish-core/lib',
60  'http'
61)
62
63# Get the options and enable the respective features
64## create a MAP of  "options : feature_flag"
65
66feature_map = {
67  'basic-auth'                                  : '-DBMCWEB_ENABLE_BASIC_AUTHENTICATION',
68  'cookie-auth'                                 : '-DBMCWEB_ENABLE_COOKIE_AUTHENTICATION',
69  'google-api'                                  : '-DBMCWEB_ENABLE_GOOGLE_API',
70  'host-serial-socket'                          : '-DBMCWEB_ENABLE_HOST_SERIAL_WEBSOCKET',
71  'ibm-management-console'                      : '-DBMCWEB_ENABLE_IBM_MANAGEMENT_CONSOLE',
72  'insecure-disable-auth'                       : '-DBMCWEB_INSECURE_DISABLE_AUTHX',
73  'insecure-disable-csrf'                       : '-DBMCWEB_INSECURE_DISABLE_CSRF_PREVENTION',
74  'insecure-disable-ssl'                        : '-DBMCWEB_INSECURE_DISABLE_SSL',
75  'insecure-push-style-notification'            : '-DBMCWEB_INSECURE_ENABLE_HTTP_PUSH_STYLE_EVENTING',
76  'insecure-tftp-update'                        : '-DBMCWEB_INSECURE_ENABLE_REDFISH_FW_TFTP_UPDATE',
77  'insecure-ignore-content-type'                : '-DBMCWEB_INSECURE_IGNORE_CONTENT_TYPE',
78  'kvm'                                         : '-DBMCWEB_ENABLE_KVM' ,
79  'mutual-tls-auth'                             : '-DBMCWEB_ENABLE_MUTUAL_TLS_AUTHENTICATION',
80  'redfish-aggregation'                         : '-DBMCWEB_ENABLE_REDFISH_AGGREGATION',
81  'redfish-allow-deprecated-power-thermal'      : '-DBMCWEB_ALLOW_DEPRECATED_POWER_THERMAL',
82  'redfish-bmc-journal'                         : '-DBMCWEB_ENABLE_REDFISH_BMC_JOURNAL',
83  'redfish-cpu-log'                             : '-DBMCWEB_ENABLE_REDFISH_CPU_LOG',
84  'redfish-dbus-log'                            : '-DBMCWEB_ENABLE_REDFISH_DBUS_LOG_ENTRIES',
85  'redfish-dump-log'                            : '-DBMCWEB_ENABLE_REDFISH_DUMP_LOG',
86  'redfish-host-logger'                         : '-DBMCWEB_ENABLE_REDFISH_HOST_LOGGER',
87  'redfish-new-powersubsystem-thermalsubsystem' : '-DBMCWEB_NEW_POWERSUBSYSTEM_THERMALSUBSYSTEM',
88  'redfish-oem-manager-fan-data'                : '-DBMCWEB_ENABLE_REDFISH_OEM_MANAGER_FAN_DATA',
89  'redfish-provisioning-feature'                : '-DBMCWEB_ENABLE_REDFISH_PROVISIONING_FEATURE',
90  'redfish'                                     : '-DBMCWEB_ENABLE_REDFISH',
91  'rest'                                        : '-DBMCWEB_ENABLE_DBUS_REST',
92  'session-auth'                                : '-DBMCWEB_ENABLE_SESSION_AUTHENTICATION',
93  'static-hosting'                              : '-DBMCWEB_ENABLE_STATIC_HOSTING',
94  'experimental-redfish-multi-computer-system'  : '-DBMCWEB_ENABLE_MULTI_COMPUTERSYSTEM',
95  'vm-websocket'                                : '-DBMCWEB_ENABLE_VM_WEBSOCKET',
96  'xtoken-auth'                                 : '-DBMCWEB_ENABLE_XTOKEN_AUTHENTICATION',
97  #'vm-nbdproxy'                                : '-DBMCWEB_ENABLE_VM_NBDPROXY',
98}
99
100# Get the options status and build a project summary to show which flags are
101# being enabled during the configuration time.
102
103foreach option_key,option_value : feature_map
104  if(get_option(option_key).enabled())
105    if(option_key == 'mutual-tls-auth' or option_key == 'insecure-disable-ssl')
106      if(get_option('insecure-disable-ssl').disabled() or get_option('mutual-tls-auth').disabled())
107        add_project_arguments(option_value,language:'cpp')
108        summary(option_key,option_value, section : 'Enabled Features')
109      endif
110    elif (option_key in ['basic-auth', 'cookie-auth', 'session-auth', 'xtoken-auth', 'mutual-tls-auth'])
111      if (get_option('insecure-disable-auth').disabled())
112        add_project_arguments(option_value, language:'cpp')
113        summary(option_key,option_value, section : 'Enabled Features')
114      endif
115    else
116      summary(option_key,option_value, section : 'Enabled Features')
117      add_project_arguments(option_value,language:'cpp')
118    endif
119  else
120      if(option_key == 'insecure-disable-ssl')
121        summary('ssl','-DBMCWEB_ENABLE_SSL', section : 'Enabled Features')
122        add_project_arguments('-DBMCWEB_ENABLE_SSL', language : 'cpp')
123      endif
124  endif
125endforeach
126
127if(get_option('tests').enabled())
128  summary('unittest','NA', section : 'Enabled Features')
129endif
130
131# Add compiler arguments
132
133# -Wpedantic, -Wextra comes by default with warning level
134add_project_arguments(
135  cxx.get_supported_arguments([
136  '-Wcast-align',
137  '-Wconversion',
138  '-Wformat=2',
139  '-Wold-style-cast',
140  '-Woverloaded-virtual',
141  '-Wsign-conversion',
142  '-Wunused',
143  '-Wno-attributes',
144  ]),
145  language: 'cpp'
146)
147
148if (cxx.get_id() == 'clang' and cxx.version().version_compare('>9.0'))
149add_project_arguments(
150  cxx.get_supported_arguments([
151    '-Weverything',
152    '-Wno-c++98-compat-pedantic',
153    '-Wno-c++98-compat',
154    '-Wno-documentation-unknown-command',
155    '-Wno-documentation',
156    '-Wno-exit-time-destructors',
157    '-Wno-global-constructors',
158    '-Wno-newline-eof',
159    '-Wno-padded',
160    '-Wno-shadow',
161    '-Wno-used-but-marked-unused',
162    '-Wno-weak-vtables',
163    '-Wno-switch-enum',
164  ]),
165  language:'cpp')
166endif
167
168# if compiler is gnu-gcc , and version is > 8.0 then we add few more
169# compiler arguments , we know that will pass
170
171if (cxx.get_id() == 'gcc' and cxx.version().version_compare('>8.0'))
172  add_project_arguments(
173    cxx.get_supported_arguments([
174     '-Wduplicated-cond',
175     '-Wduplicated-branches',
176     '-Wlogical-op',
177     '-Wnull-dereference',
178     '-Wunused-parameter',
179     '-Wdouble-promotion',
180     '-Wshadow',
181     '-Wno-psabi',
182     ]),
183    language:'cpp')
184endif
185
186if (get_option('buildtype') != 'plain')
187  if (get_option('b_lto') == true and get_option('optimization')!='0')
188    # Reduce the binary size by removing unnecessary
189    # dynamic symbol table entries
190
191    add_project_arguments(
192     cxx.get_supported_arguments([
193     '-fno-fat-lto-objects',
194     '-fvisibility=hidden',
195     '-fvisibility-inlines-hidden'
196     ]),
197     language: 'cpp')
198
199    if cxx.has_link_argument('-Wl,--exclude-libs,ALL')
200      add_project_link_arguments('-Wl,--exclude-libs,ALL', language: 'cpp')
201    endif
202  endif
203endif
204
205if( get_option('bmcweb-logging') != 'disabled' or \
206    get_option('buildtype').startswith('debug'))
207 add_project_arguments([
208   '-DBMCWEB_ENABLE_DEBUG'
209   ],
210  language : 'cpp')
211
212  summary('debug', '-DBMCWEB_ENABLE_DEBUG', section : 'Enabled Features')
213endif
214
215# Set Compiler Security flags
216
217security_flags = [
218  '-fstack-protector-strong',
219  '-fPIE',
220  '-fPIC',
221  '-D_FORTIFY_SOURCE=2',
222  '-Wformat',
223  '-Wformat-security'
224]
225
226## Add security flags for builds of type 'release','debugoptimized' and 'minsize'
227
228if not (get_option('buildtype') == 'plain' or get_option('buildtype').startswith('debug'))
229  add_project_arguments(
230   cxx.get_supported_arguments([
231    security_flags
232  ]),
233  language: 'cpp')
234endif
235
236# Boost dependency configuration
237
238add_project_arguments(
239cxx.get_supported_arguments([
240  '-DBOOST_ALL_NO_LIB',
241  '-DBOOST_ALLOW_DEPRECATED_HEADERS',
242  '-DBOOST_ASIO_DISABLE_THREADS',
243  '-DBOOST_ASIO_NO_DEPRECATED',
244  '-DBOOST_ASIO_SEPARATE_COMPILATION',
245  '-DBOOST_BEAST_SEPARATE_COMPILATION',
246  '-DBOOST_EXCEPTION_DISABLE',
247  '-DBOOST_URL_NO_SOURCE_LOCATION',
248  '-DJSON_NOEXCEPTION',
249  '-DOPENSSL_NO_FILENAMES',
250]),
251language : 'cpp')
252
253# Find the dependency modules, if not found use meson wrap to get them
254# automatically during the configure step
255bmcweb_dependencies = []
256
257pam = cxx.find_library('pam', required: true)
258atomic =  cxx.find_library('atomic', required: true)
259openssl = dependency('openssl', required : true)
260bmcweb_dependencies += [pam, atomic, openssl]
261
262sdbusplus = dependency('sdbusplus', required : false, include_type: 'system')
263if not sdbusplus.found()
264  sdbusplus_proj = subproject('sdbusplus', required: true)
265  sdbusplus = sdbusplus_proj.get_variable('sdbusplus_dep')
266  sdbusplus = sdbusplus.as_system('system')
267endif
268bmcweb_dependencies += sdbusplus
269
270tinyxml = dependency(
271    'tinyxml2',
272    include_type: 'system',
273    version: '>=9.0.0',
274)
275if not tinyxml.found()
276    tinyxml_proj = subproject('tinyxml2', required: true)
277    tinyxml = tinyxml_proj.get_variable('tinyxml_dep')
278    tinyxml = tinyxml.as_system('system')
279endif
280bmcweb_dependencies += tinyxml
281
282systemd = dependency('systemd')
283zlib = dependency('zlib')
284bmcweb_dependencies += [systemd, zlib]
285
286nlohmann_json = dependency('nlohmann_json', version: '>=3.9.2', required: false, include_type: 'system')
287if not nlohmann_json.found()
288    nlohmann_json_proj = subproject('nlohmann_json', required: true)
289    nlohmann_json = nlohmann_json_proj.get_variable('nlohmann_json_dep')
290    nlohmann_json = nlohmann_json.as_system('system')
291endif
292bmcweb_dependencies += nlohmann_json
293
294boost = dependency('boost',version : '>=1.82.0', required : false, include_type: 'system')
295if not boost.found()
296  boost = subproject('boost', required: true).get_variable('boost_dep')
297  boost = boost.as_system('system')
298endif
299bmcweb_dependencies += boost
300
301if get_option('tests').enabled()
302  gtest = dependency('gtest', main: true, disabler: true, required : false)
303  gmock = dependency('gmock', required : false)
304  if not gtest.found() and get_option('tests').enabled()
305    gtest_proj = subproject('gtest', required: true)
306    gtest = gtest_proj.get_variable('gtest_main_dep')
307    gmock = gtest_proj.get_variable('gmock_dep')
308  endif
309  gtest = gtest.as_system('system')
310  gmock = gmock.as_system('system')
311endif
312
313systemd_system_unit_dir = systemd.get_variable('systemdsystemunitdir')
314
315bindir = get_option('prefix') + '/' +get_option('bindir')
316
317summary({
318          'prefix' : get_option('prefix'),
319          'bindir' : bindir,
320          'systemd unit directory' : systemd_system_unit_dir
321        }, section : 'Directories')
322
323install_subdir('static', install_dir : 'share/www', strip_directory : true)
324
325# Config subdirectory
326
327subdir('config')
328bmcweb_dependencies += conf_h_dep
329
330# Source files
331fs = import('fs')
332
333srcfiles_bmcweb = files(
334  'redfish-core/src/error_messages.cpp',
335  'redfish-core/src/registries.cpp',
336  'redfish-core/src/utils/json_utils.cpp',
337  'src/boost_asio_ssl.cpp',
338  'src/boost_asio.cpp',
339  'src/boost_beast.cpp',
340  'src/boost_url.cpp',
341  'src/dbus_singleton.cpp',
342  'src/json_html_serializer.cpp',
343)
344
345bmcweblib = static_library(
346  'bmcweblib',
347  srcfiles_bmcweb,
348  include_directories : incdir,
349  dependencies: bmcweb_dependencies,
350)
351
352# Generate the bmcweb executable
353executable(
354  'bmcweb',
355  'src/webserver_main.cpp',
356  include_directories : incdir,
357  dependencies: bmcweb_dependencies,
358  link_with: bmcweblib,
359  link_args: '-Wl,--gc-sections',
360  install: true,
361  install_dir:bindir
362)
363
364srcfiles_unittest = files(
365  'test/http/crow_getroutes_test.cpp',
366  'test/http/router_test.cpp',
367  'test/http/utility_test.cpp',
368  'test/http/verb_test.cpp',
369  'test/include/dbus_utility_test.cpp',
370  'test/include/google/google_service_root_test.cpp',
371  'test/include/json_html_serializer.cpp',
372  'test/include/http_utility_test.cpp',
373  'test/include/human_sort_test.cpp',
374  'test/include/ibm/configfile_test.cpp',
375  'test/include/ibm/lock_test.cpp',
376  'test/include/multipart_test.cpp',
377  'test/include/openbmc_dbus_rest_test.cpp',
378  'test/include/str_utility_test.cpp',
379  'test/redfish-core/include/privileges_test.cpp',
380  'test/redfish-core/include/redfish_aggregator_test.cpp',
381  'test/redfish-core/include/registries_test.cpp',
382  'test/redfish-core/include/utils/hex_utils_test.cpp',
383  'test/redfish-core/include/utils/ip_utils_test.cpp',
384  'test/redfish-core/include/utils/json_utils_test.cpp',
385  'test/redfish-core/include/utils/query_param_test.cpp',
386  'test/redfish-core/include/utils/stl_utils_test.cpp',
387  'test/redfish-core/include/utils/time_utils_test.cpp',
388  'test/redfish-core/lib/chassis_test.cpp',
389  'test/redfish-core/lib/sensors_test.cpp',
390  'test/redfish-core/lib/log_services_dump_test.cpp',
391  'test/redfish-core/lib/service_root_test.cpp',
392  'test/redfish-core/lib/thermal_subsystem_test.cpp',
393  'test/redfish-core/lib/power_subsystem_test.cpp',
394)
395
396if(get_option('tests').enabled())
397    # generate the test executable
398    foreach test_src : srcfiles_unittest
399      test_bin = executable(
400        fs.stem(test_src),
401        test_src,
402        link_with: bmcweblib,
403        include_directories : incdir,
404        install_dir: bindir,
405        dependencies: bmcweb_dependencies + [
406          gtest,
407          gmock,
408        ]
409      )
410      test(fs.stem(test_src), test_bin)
411    endforeach
412endif
413