xref: /openbmc/bmcweb/meson.build (revision c6178aba) 
1project(
2    'bmcweb',
3    'cpp',
4    version: '1.0',
5    meson_version: '>=1.3.0',
6    default_options: [
7        'b_lto_mode=default',
8        'b_lto_threads=0',
9        'b_lto=true',
10        'b_ndebug=if-release',
11        'buildtype=debugoptimized',
12        'cpp_rtti=false',
13        'cpp_std=c++23',
14        'warning_level=3',
15        'werror=true',
16    ],
17)
18
19# Project related links
20
21project_pretty_name = 'bmcweb'
22project_url = 'https://github.com/openbmc/' + project_pretty_name
23project_issues_url = project_url + '/issues/new'
24summary('Issues', project_issues_url, section: 'Report Issues')
25
26# Validate the c++ Standard
27
28if get_option('cpp_std') != 'c++23'
29    error('This project requires c++23 support')
30endif
31
32# Get compiler and default build type
33
34cxx = meson.get_compiler('cpp')
35build = get_option('buildtype')
36optimization = get_option('optimization')
37summary('Build Type', build, section: 'Build Info')
38summary('Optimization', optimization, section: 'Build Info')
39
40# remove debug information for minsize buildtype
41if (get_option('buildtype') == 'minsize')
42    add_project_arguments(
43        ['-fdata-sections', '-ffunction-sections'],
44        language: 'cpp',
45    )
46    add_project_arguments('-DNDEBUG', language: 'cpp')
47endif
48
49if (get_option('dns-resolver') == 'systemd-dbus')
50    add_project_arguments('-DBMCWEB_DBUS_DNS_RESOLVER', language: 'cpp')
51endif
52
53# Disable lto when compiling with no optimization
54if (get_option('optimization') == '0')
55    add_project_arguments('-fno-lto', language: 'cpp')
56    message('Disabling lto & its supported features as optimization is disabled')
57endif
58
59# Include Directories
60
61incdir = include_directories(
62    'include',
63    'redfish-core/include',
64    'redfish-core/lib',
65    'http',
66)
67incdir_cli = include_directories('http', 'include')
68
69if (get_option('tests').allowed())
70    summary('unittest', 'NA', section: 'Features')
71endif
72
73# Add compiler arguments
74
75if (cxx.get_id() == 'clang')
76    if (cxx.version().version_compare('<17.0'))
77        error('This project requires clang-17 or higher')
78    endif
79    add_project_arguments(
80        '-Weverything',
81        '-Wformat=2',
82        '-Wno-c++98-compat-pedantic',
83        '-Wno-c++98-compat',
84        '-Wno-c++20-extensions',
85        '-Wno-documentation-unknown-command',
86        '-Wno-documentation',
87        '-Wno-exit-time-destructors',
88        '-Wno-global-constructors',
89        '-Wno-newline-eof',
90        '-Wno-padded',
91        '-Wno-shadow',
92        '-Wno-used-but-marked-unused',
93        '-Wno-weak-vtables',
94        '-Wno-switch-enum',
95        '-Wno-unused-macros',
96        '-Wno-covered-switch-default',
97        '-Wno-disabled-macro-expansion',
98        '-Wno-unneeded-internal-declaration',
99        language: 'cpp',
100    )
101endif
102
103if (cxx.get_id() == 'gcc')
104    if (cxx.version().version_compare('<13.0'))
105        error('This project requires gcc-13 or higher')
106    endif
107
108    add_project_arguments(
109        '-Wformat=2',
110        '-Wcast-align',
111        '-Wconversion',
112        '-Woverloaded-virtual',
113        '-Wsign-conversion',
114        '-Wunused',
115        '-Wduplicated-cond',
116        '-Wduplicated-branches',
117        '-Wlogical-op',
118        '-Wnull-dereference',
119        '-Wunused-parameter',
120        '-Wdouble-promotion',
121        '-Wshadow',
122        '-Wno-psabi',
123        '-Wno-attributes',
124        language: 'cpp',
125    )
126endif
127
128if (get_option('buildtype') != 'plain')
129    if (get_option('b_lto') == true and get_option('optimization') != '0')
130        # Reduce the binary size by removing unnecessary
131        # dynamic symbol table entries
132
133        add_project_arguments(
134            cxx.get_supported_arguments(
135                [
136                    '-fno-fat-lto-objects',
137                    '-fvisibility=hidden',
138                    '-fvisibility-inlines-hidden',
139                ],
140            ),
141            language: 'cpp',
142        )
143
144        if cxx.has_link_argument('-Wl,--exclude-libs,ALL')
145            add_project_link_arguments('-Wl,--exclude-libs,ALL', language: 'cpp')
146        endif
147    endif
148endif
149# Set Compiler Security flags
150
151security_flags = [
152    '-fstack-protector-strong',
153    '-fPIE',
154    '-fPIC',
155    '-D_FORTIFY_SOURCE=2',
156    '-Wformat',
157    '-Wformat-security',
158]
159
160## Add security flags for builds of type 'release','debugoptimized' and 'minsize'
161
162if not (get_option('buildtype') == 'plain'
163or get_option('buildtype').startswith('debug')
164)
165    add_project_arguments(
166        cxx.get_supported_arguments([security_flags]),
167        language: 'cpp',
168    )
169endif
170
171# Boost dependency configuration
172
173add_project_arguments(
174    cxx.get_supported_arguments(
175        [
176            '-DBOOST_ASIO_DISABLE_CONCEPTS',
177            '-DBOOST_ALL_NO_LIB',
178            '-DBOOST_ALLOW_DEPRECATED_HEADERS',
179            '-DBOOST_ASIO_DISABLE_THREADS',
180            '-DBOOST_ASIO_NO_DEPRECATED',
181            '-DBOOST_ASIO_SEPARATE_COMPILATION',
182            '-DBOOST_BEAST_SEPARATE_COMPILATION',
183            '-DBOOST_EXCEPTION_DISABLE',
184            '-DBOOST_NO_EXCEPTIONS',
185            '-DBOOST_URL_NO_SOURCE_LOCATION',
186            '-DBOOST_SPIRIT_X3_NO_RTTI',
187            '-DJSON_NOEXCEPTION',
188            '-DOPENSSL_NO_FILENAMES',
189            '-DSDBUSPLUS_DISABLE_BOOST_COROUTINES',
190        ],
191    ),
192    language: 'cpp',
193)
194
195# Find the dependency modules, if not found use meson wrap to get them
196# automatically during the configure step
197bmcweb_dependencies = []
198bmcweb_cli_dependencies = []
199
200pam = cxx.find_library('pam', required: true)
201atomic = cxx.find_library('atomic', required: true)
202bmcweb_dependencies += [pam, atomic]
203
204openssl = dependency('openssl', required: false, version: '>=3.0.0')
205if not openssl.found() or get_option('b_sanitize') != 'none'
206    openssl_proj = subproject(
207        'openssl',
208        required: true,
209        default_options: ['warning_level=0', 'werror=false'],
210    )
211    openssl = openssl_proj.get_variable('openssl_dep')
212    openssl = openssl.as_system('system')
213endif
214bmcweb_dependencies += [openssl]
215
216nghttp2 = dependency('libnghttp2', version: '>=1.52.0', required: false)
217if not nghttp2.found()
218    cmake = import('cmake')
219    opt_var = cmake.subproject_options()
220    opt_var.add_cmake_defines(
221        {'ENABLE_LIB_ONLY': true, 'ENABLE_STATIC_LIB': true},
222    )
223    nghttp2_ex = cmake.subproject('nghttp2', options: opt_var)
224    nghttp2 = nghttp2_ex.dependency('nghttp2')
225endif
226bmcweb_dependencies += nghttp2
227
228sdbusplus = dependency('sdbusplus', required: false, include_type: 'system')
229if not sdbusplus.found()
230    sdbusplus_proj = subproject('sdbusplus', required: true)
231    sdbusplus = sdbusplus_proj.get_variable('sdbusplus_dep')
232    sdbusplus = sdbusplus.as_system('system')
233endif
234bmcweb_dependencies += sdbusplus
235bmcweb_cli_dependencies += sdbusplus
236
237cli11 = dependency('CLI11', required: false, include_type: 'system')
238if not cli11.found()
239    cli11_proj = subproject('cli11', required: true)
240    cli11 = cli11_proj.get_variable('CLI11_dep')
241    cli11 = cli11.as_system('system')
242endif
243bmcweb_cli_dependencies += cli11
244
245
246tinyxml = dependency(
247    'tinyxml2',
248    include_type: 'system',
249    version: '>=9.0.0',
250    default_options: ['tests=false'],
251)
252if not tinyxml.found()
253    tinyxml_proj = subproject('tinyxml2', required: true)
254    tinyxml = tinyxml_proj.get_variable('tinyxml_dep')
255    tinyxml = tinyxml.as_system('system')
256endif
257bmcweb_dependencies += tinyxml
258
259systemd = dependency('systemd')
260add_project_arguments('-DSYSTEMD_VERSION=' + systemd.version(), language: 'cpp')
261
262zlib = dependency('zlib')
263bmcweb_dependencies += [systemd, zlib]
264
265nlohmann_json_dep = dependency(
266    'nlohmann_json',
267    version: '>=3.11.2',
268    include_type: 'system',
269)
270bmcweb_dependencies += nlohmann_json_dep
271
272boost = dependency(
273    'boost',
274    modules: ['url'],
275    version: '>=1.84.0',
276    required: false,
277    include_type: 'system',
278)
279if boost.found()
280    bmcweb_dependencies += [boost]
281    bmcweb_cli_dependencies += [boost]
282else
283    cmake = import('cmake')
284    opt = cmake.subproject_options()
285    boost_libs = [
286        'asio',
287        'beast',
288        'circular_buffer',
289        'callable_traits',
290        'headers',
291        'process',
292        'type_index',
293        'url',
294        'uuid',
295        'spirit',
296    ]
297    opt.add_cmake_defines(
298        {
299            # 1.86.0 fails this.  Hopefully fixed in 1.86.1
300            'CMAKE_CXX_FLAGS': '-Wno-unused-parameter',
301            'BOOST_INCLUDE_LIBRARIES': ';'.join(boost_libs),
302            'BUILD_SHARED_LIBS': 'OFF',
303        },
304    )
305
306    boost = cmake.subproject('boost', required: true, options: opt)
307    foreach boost_lib : boost_libs
308        boost_lib_instance = boost.dependency('boost_' + boost_lib).as_system()
309        bmcweb_dependencies += [boost_lib_instance]
310        bmcweb_cli_dependencies += [boost_lib_instance]
311    endforeach
312endif
313
314if get_option('tests').allowed()
315    gtest = dependency(
316        'gtest',
317        main: true,
318        version: '>=1.14.0',
319        disabler: true,
320        required: false,
321    )
322    gmock = dependency('gmock', required: false)
323    if not gtest.found() and get_option('tests').allowed()
324        gtest_proj = subproject('gtest', required: true)
325        gtest = gtest_proj.get_variable('gtest_main_dep')
326        gmock = gtest_proj.get_variable('gmock_dep')
327    endif
328    gtest = gtest.as_system('system')
329    gmock = gmock.as_system('system')
330endif
331
332systemd_system_unit_dir = systemd.get_variable('systemdsystemunitdir')
333
334bindir = get_option('prefix') + '/' + get_option('bindir')
335libexec = get_option('prefix') + '/' + get_option('libexecdir')
336
337summary(
338    {
339        'prefix': get_option('prefix'),
340        'bindir': bindir,
341        'systemd unit directory': systemd_system_unit_dir,
342    },
343    section: 'Directories',
344)
345
346subdir('static')
347subdir('redfish-core')
348
349# Config subdirectory
350subdir('config')
351bmcweb_dependencies += conf_h_dep
352bmcweb_cli_dependencies += conf_h_dep
353
354# Source files
355fs = import('fs')
356
357srcfiles_bmcweb = files(
358    'http/mutual_tls.cpp',
359    'redfish-core/src/error_messages.cpp',
360    'redfish-core/src/filter_expr_executor.cpp',
361    'redfish-core/src/filter_expr_printer.cpp',
362    'redfish-core/src/redfish.cpp',
363    'redfish-core/src/registries.cpp',
364    'redfish-core/src/utils/dbus_utils.cpp',
365    'redfish-core/src/utils/json_utils.cpp',
366    'redfish-core/src/utils/time_utils.cpp',
367    'src/boost_asio.cpp',
368    'src/boost_asio_ssl.cpp',
369    'src/boost_beast.cpp',
370    'src/dbus_singleton.cpp',
371    'src/json_html_serializer.cpp',
372    'src/ossl_random.cpp',
373    'src/ssl_key_handler.cpp',
374    'src/webserver_run.cpp',
375)
376
377bmcweblib = static_library(
378    'bmcweblib',
379    srcfiles_bmcweb,
380    include_directories: incdir,
381    dependencies: bmcweb_dependencies,
382)
383
384# Generate the bmcwebd daemon
385executable(
386    'bmcwebd',
387    'src/webserver_main.cpp',
388    include_directories: incdir,
389    dependencies: bmcweb_dependencies,
390    link_with: bmcweblib,
391    link_args: '-Wl,--gc-sections',
392    install: true,
393    install_dir: libexec,
394)
395
396# Generate the bmcweb CLI application
397executable(
398    'bmcweb',
399    ['src/webserver_cli.cpp', 'src/boost_asio.cpp'],
400    include_directories: incdir_cli,
401    dependencies: bmcweb_cli_dependencies,
402    install: true,
403    install_dir: bindir,
404)
405
406srcfiles_unittest = files(
407    'test/http/crow_getroutes_test.cpp',
408    'test/http/http2_connection_test.cpp',
409    'test/http/http_body_test.cpp',
410    'test/http/http_connection_test.cpp',
411    'test/http/http_response_test.cpp',
412    'test/http/mutual_tls.cpp',
413    'test/http/mutual_tls_meta.cpp',
414    'test/http/parsing_test.cpp',
415    'test/http/router_test.cpp',
416    'test/http/server_sent_event_test.cpp',
417    'test/http/utility_test.cpp',
418    'test/http/verb_test.cpp',
419    'test/include/async_resolve_test.cpp',
420    'test/include/credential_pipe_test.cpp',
421    'test/include/dbus_utility_test.cpp',
422    'test/include/google/google_service_root_test.cpp',
423    'test/include/http_utility_test.cpp',
424    'test/include/human_sort_test.cpp',
425    'test/include/ibm/configfile_test.cpp',
426    'test/include/json_html_serializer.cpp',
427    'test/include/multipart_test.cpp',
428    'test/include/openbmc_dbus_rest_test.cpp',
429    'test/include/ossl_random.cpp',
430    'test/include/ssl_key_handler_test.cpp',
431    'test/include/str_utility_test.cpp',
432    'test/redfish-core/include/filter_expr_executor_test.cpp',
433    'test/redfish-core/include/filter_expr_parser_test.cpp',
434    'test/redfish-core/include/privileges_test.cpp',
435    'test/redfish-core/include/redfish_aggregator_test.cpp',
436    'test/redfish-core/include/registries_test.cpp',
437    'test/redfish-core/include/utils/dbus_utils.cpp',
438    'test/redfish-core/include/utils/hex_utils_test.cpp',
439    'test/redfish-core/include/utils/ip_utils_test.cpp',
440    'test/redfish-core/include/utils/json_utils_test.cpp',
441    'test/redfish-core/include/utils/query_param_test.cpp',
442    'test/redfish-core/include/utils/sensor_utils_test.cpp',
443    'test/redfish-core/include/utils/stl_utils_test.cpp',
444    'test/redfish-core/include/utils/time_utils_test.cpp',
445    'test/redfish-core/lib/chassis_test.cpp',
446    'test/redfish-core/lib/log_services_dump_test.cpp',
447    'test/redfish-core/lib/log_services_test.cpp',
448    'test/redfish-core/lib/manager_diagnostic_data_test.cpp',
449    'test/redfish-core/lib/metadata_test.cpp',
450    'test/redfish-core/lib/power_subsystem_test.cpp',
451    'test/redfish-core/lib/service_root_test.cpp',
452    'test/redfish-core/lib/system_test.cpp',
453    'test/redfish-core/lib/thermal_subsystem_test.cpp',
454    'test/redfish-core/lib/update_service_test.cpp',
455)
456
457if (get_option('tests').allowed())
458    # generate the test executable
459    foreach test_src : srcfiles_unittest
460        test_bin = executable(
461            fs.stem(test_src),
462            test_src,
463            link_with: bmcweblib,
464            include_directories: incdir,
465            install_dir: bindir,
466            dependencies: bmcweb_dependencies + [gtest, gmock],
467        )
468        test(fs.stem(test_src), test_bin)
469    endforeach
470endif
471