xref: /openbmc/bmcweb/meson.build (revision bd79bce8c3f1deb1fb2773868b9ece25233cf27b) 
1project(
2    'bmcweb',
3    'cpp',
4    version: '1.0',
5    meson_version: '>=1.3.0',
6    default_options: [
7        'b_lto_mode=default',
8        'b_lto_threads=0',
9        'b_lto=true',
10        'b_ndebug=if-release',
11        'buildtype=debugoptimized',
12        'cpp_rtti=false',
13        'cpp_std=c++20',
14        'warning_level=3',
15        'werror=true',
16    ],
17)
18
19# Project related links
20
21project_pretty_name = 'bmcweb'
22project_url = 'https://github.com/openbmc/' + project_pretty_name
23project_issues_url = project_url + '/issues/new'
24summary('Issues', project_issues_url, section: 'Report Issues')
25
26# Validate the c++ Standard
27
28if get_option('cpp_std') != 'c++20'
29    error('This project requires c++20 support')
30endif
31
32# Get compiler and default build type
33
34cxx = meson.get_compiler('cpp')
35build = get_option('buildtype')
36optimization = get_option('optimization')
37summary('Build Type', build, section: 'Build Info')
38summary('Optimization', optimization, section: 'Build Info')
39
40# remove debug information for minsize buildtype
41if (get_option('buildtype') == 'minsize')
42    add_project_arguments(['-fdata-sections', '-ffunction-sections'], language: 'cpp')
43    add_project_arguments('-DNDEBUG', language: 'cpp')
44endif
45
46if (get_option('dns-resolver') == 'systemd-dbus')
47    add_project_arguments('-DBMCWEB_DBUS_DNS_RESOLVER', language: 'cpp')
48endif
49
50# Disable lto when compiling with no optimization
51if (get_option('optimization') == '0')
52    add_project_arguments('-fno-lto', language: 'cpp')
53    message('Disabling lto & its supported features as optimization is disabled')
54endif
55
56# Include Directories
57
58incdir = include_directories('include', 'redfish-core/include', 'redfish-core/lib', 'http')
59
60if (get_option('tests').allowed())
61    summary('unittest', 'NA', section: 'Features')
62endif
63
64# Add compiler arguments
65
66if (cxx.get_id() == 'clang')
67    if (cxx.version().version_compare('<17.0'))
68        error('This project requires clang-17 or higher')
69    endif
70    add_project_arguments(
71        '-Weverything',
72        '-Wformat=2',
73        '-Wno-c++98-compat-pedantic',
74        '-Wno-c++98-compat',
75        '-Wno-c++20-extensions',
76        '-Wno-documentation-unknown-command',
77        '-Wno-documentation',
78        '-Wno-exit-time-destructors',
79        '-Wno-global-constructors',
80        '-Wno-newline-eof',
81        '-Wno-padded',
82        '-Wno-shadow',
83        '-Wno-used-but-marked-unused',
84        '-Wno-weak-vtables',
85        '-Wno-switch-enum',
86        '-Wno-unused-macros',
87        '-Wno-covered-switch-default',
88        '-Wno-disabled-macro-expansion',
89        '-Wno-unneeded-internal-declaration',
90        language: 'cpp',
91    )
92endif
93
94if (cxx.get_id() == 'gcc')
95    if (cxx.version().version_compare('<13.0'))
96        error('This project requires gcc-13 or higher')
97    endif
98
99    add_project_arguments(
100        '-Wformat=2',
101        '-Wcast-align',
102        '-Wconversion',
103        '-Woverloaded-virtual',
104        '-Wsign-conversion',
105        '-Wunused',
106        '-Wduplicated-cond',
107        '-Wduplicated-branches',
108        '-Wlogical-op',
109        '-Wnull-dereference',
110        '-Wunused-parameter',
111        '-Wdouble-promotion',
112        '-Wshadow',
113        '-Wno-psabi',
114        '-Wno-attributes',
115        language: 'cpp',
116    )
117endif
118
119if (get_option('buildtype') != 'plain')
120    if (get_option('b_lto') == true and get_option('optimization') != '0')
121        # Reduce the binary size by removing unnecessary
122        # dynamic symbol table entries
123
124        add_project_arguments(
125            cxx.get_supported_arguments(
126                [
127                    '-fno-fat-lto-objects',
128                    '-fvisibility=hidden',
129                    '-fvisibility-inlines-hidden',
130                ],
131            ),
132            language: 'cpp',
133        )
134
135        if cxx.has_link_argument('-Wl,--exclude-libs,ALL')
136            add_project_link_arguments('-Wl,--exclude-libs,ALL', language: 'cpp')
137        endif
138    endif
139endif
140# Set Compiler Security flags
141
142security_flags = [
143    '-fstack-protector-strong',
144    '-fPIE',
145    '-fPIC',
146    '-D_FORTIFY_SOURCE=2',
147    '-Wformat',
148    '-Wformat-security',
149]
150
151## Add security flags for builds of type 'release','debugoptimized' and 'minsize'
152
153if not (
154    get_option('buildtype') == 'plain'
155    or get_option('buildtype').startswith('debug')
156)
157    add_project_arguments(cxx.get_supported_arguments([security_flags]), language: 'cpp')
158endif
159
160# Boost dependency configuration
161
162add_project_arguments(
163    cxx.get_supported_arguments(
164        [
165            '-DBOOST_ASIO_DISABLE_CONCEPTS',
166            '-DBOOST_ALL_NO_LIB',
167            '-DBOOST_ALLOW_DEPRECATED_HEADERS',
168            '-DBOOST_ASIO_DISABLE_THREADS',
169            '-DBOOST_ASIO_NO_DEPRECATED',
170            '-DBOOST_ASIO_SEPARATE_COMPILATION',
171            '-DBOOST_BEAST_SEPARATE_COMPILATION',
172            '-DBOOST_EXCEPTION_DISABLE',
173            '-DBOOST_NO_EXCEPTIONS',
174            '-DBOOST_URL_NO_SOURCE_LOCATION',
175            '-DBOOST_SPIRIT_X3_NO_RTTI',
176            '-DJSON_NOEXCEPTION',
177            '-DOPENSSL_NO_FILENAMES',
178            '-DSDBUSPLUS_DISABLE_BOOST_COROUTINES',
179        ],
180    ),
181    language: 'cpp',
182)
183
184# Find the dependency modules, if not found use meson wrap to get them
185# automatically during the configure step
186bmcweb_dependencies = []
187
188pam = cxx.find_library('pam', required: true)
189atomic = cxx.find_library('atomic', required: true)
190bmcweb_dependencies += [pam, atomic]
191
192openssl = dependency('openssl', required: false, version: '>=3.0.0')
193if not openssl.found() or get_option('b_sanitize') != 'none'
194    openssl_proj = subproject(
195        'openssl',
196        required: true,
197        default_options: ['warning_level=0', 'werror=false'],
198    )
199    openssl = openssl_proj.get_variable('openssl_dep')
200    openssl = openssl.as_system('system')
201endif
202bmcweb_dependencies += [openssl]
203
204nghttp2 = dependency('libnghttp2', version: '>=1.52.0', required: false)
205if not nghttp2.found()
206    cmake = import('cmake')
207    opt_var = cmake.subproject_options()
208    opt_var.add_cmake_defines(
209        {
210            'ENABLE_LIB_ONLY': true,
211            'ENABLE_STATIC_LIB': true,
212        },
213    )
214    nghttp2_ex = cmake.subproject('nghttp2', options: opt_var)
215    nghttp2 = nghttp2_ex.dependency('nghttp2')
216endif
217bmcweb_dependencies += nghttp2
218
219sdbusplus = dependency('sdbusplus', required: false, include_type: 'system')
220if not sdbusplus.found()
221    sdbusplus_proj = subproject('sdbusplus', required: true)
222    sdbusplus = sdbusplus_proj.get_variable('sdbusplus_dep')
223    sdbusplus = sdbusplus.as_system('system')
224endif
225bmcweb_dependencies += sdbusplus
226
227tinyxml = dependency(
228    'tinyxml2',
229    include_type: 'system',
230    version: '>=9.0.0',
231    default_options: ['tests=false'],
232)
233if not tinyxml.found()
234    tinyxml_proj = subproject('tinyxml2', required: true)
235    tinyxml = tinyxml_proj.get_variable('tinyxml_dep')
236    tinyxml = tinyxml.as_system('system')
237endif
238bmcweb_dependencies += tinyxml
239
240systemd = dependency('systemd')
241add_project_arguments('-DSYSTEMD_VERSION=' + systemd.version(), language: 'cpp')
242
243zlib = dependency('zlib')
244bmcweb_dependencies += [systemd, zlib]
245
246nlohmann_json_dep = dependency('nlohmann_json', version: '>=3.11.2', include_type: 'system')
247bmcweb_dependencies += nlohmann_json_dep
248
249boost = dependency(
250    'boost',
251    modules: [
252        'url',
253    ],
254    version: '>=1.84.0',
255    required: false,
256    include_type: 'system',
257)
258if boost.found()
259    bmcweb_dependencies += [boost]
260else
261    cmake = import('cmake')
262    opt = cmake.subproject_options()
263    boost_libs = [
264        'asio',
265        'beast',
266        'circular_buffer',
267        'callable_traits',
268        'headers',
269        'process',
270        'type_index',
271        'url',
272        'uuid',
273        'spirit',
274    ]
275    opt.add_cmake_defines(
276        {
277            'BOOST_INCLUDE_LIBRARIES': ';'.join(boost_libs),
278            'BUILD_SHARED_LIBS': 'OFF',
279        },
280    )
281
282    boost = cmake.subproject('boost', required: true, options: opt)
283    foreach boost_lib : boost_libs
284        boost_lib_instance = boost.dependency('boost_' + boost_lib).as_system()
285        bmcweb_dependencies += [boost_lib_instance]
286    endforeach
287endif
288
289if get_option('tests').allowed()
290    gtest = dependency(
291        'gtest',
292        main: true,
293        version: '>=1.14.0',
294        disabler: true,
295        required: false,
296    )
297    gmock = dependency('gmock', required: false)
298    if not gtest.found() and get_option('tests').allowed()
299        gtest_proj = subproject('gtest', required: true)
300        gtest = gtest_proj.get_variable('gtest_main_dep')
301        gmock = gtest_proj.get_variable('gmock_dep')
302    endif
303    gtest = gtest.as_system('system')
304    gmock = gmock.as_system('system')
305endif
306
307systemd_system_unit_dir = systemd.get_variable('systemdsystemunitdir')
308
309bindir = get_option('prefix') + '/' + get_option('bindir')
310
311summary(
312    {
313        'prefix': get_option('prefix'),
314        'bindir': bindir,
315        'systemd unit directory': systemd_system_unit_dir,
316    },
317    section: 'Directories',
318)
319
320subdir('static')
321subdir('redfish-core')
322
323# Config subdirectory
324subdir('config')
325bmcweb_dependencies += conf_h_dep
326
327# Source files
328fs = import('fs')
329
330srcfiles_bmcweb = files(
331    'http/mutual_tls.cpp',
332    'redfish-core/src/error_messages.cpp',
333    'redfish-core/src/filter_expr_executor.cpp',
334    'redfish-core/src/filter_expr_printer.cpp',
335    'redfish-core/src/redfish.cpp',
336    'redfish-core/src/registries.cpp',
337    'redfish-core/src/utils/dbus_utils.cpp',
338    'redfish-core/src/utils/json_utils.cpp',
339    'redfish-core/src/utils/time_utils.cpp',
340    'src/boost_asio.cpp',
341    'src/boost_asio_ssl.cpp',
342    'src/boost_beast.cpp',
343    'src/dbus_singleton.cpp',
344    'src/json_html_serializer.cpp',
345    'src/ossl_random.cpp',
346    'src/ssl_key_handler.cpp',
347    'src/webserver_run.cpp',
348)
349
350bmcweblib = static_library(
351    'bmcweblib',
352    srcfiles_bmcweb,
353    include_directories: incdir,
354    dependencies: bmcweb_dependencies,
355)
356
357# Generate the bmcweb executable
358executable(
359    'bmcweb',
360    'src/webserver_main.cpp',
361    include_directories: incdir,
362    dependencies: bmcweb_dependencies,
363    link_with: bmcweblib,
364    link_args: '-Wl,--gc-sections',
365    install: true,
366    install_dir: bindir,
367)
368
369srcfiles_unittest = files(
370    'test/http/crow_getroutes_test.cpp',
371    'test/http/http2_connection_test.cpp',
372    'test/http/http_body_test.cpp',
373    'test/http/http_connection_test.cpp',
374    'test/http/http_response_test.cpp',
375    'test/http/mutual_tls.cpp',
376    'test/http/mutual_tls_meta.cpp',
377    'test/http/parsing_test.cpp',
378    'test/http/router_test.cpp',
379    'test/http/server_sent_event_test.cpp',
380    'test/http/utility_test.cpp',
381    'test/http/verb_test.cpp',
382    'test/include/async_resolve_test.cpp',
383    'test/include/credential_pipe_test.cpp',
384    'test/include/dbus_utility_test.cpp',
385    'test/include/google/google_service_root_test.cpp',
386    'test/include/http_utility_test.cpp',
387    'test/include/human_sort_test.cpp',
388    'test/include/ibm/configfile_test.cpp',
389    'test/include/json_html_serializer.cpp',
390    'test/include/multipart_test.cpp',
391    'test/include/openbmc_dbus_rest_test.cpp',
392    'test/include/ossl_random.cpp',
393    'test/include/ssl_key_handler_test.cpp',
394    'test/include/str_utility_test.cpp',
395    'test/redfish-core/include/privileges_test.cpp',
396    'test/redfish-core/include/filter_expr_executor_test.cpp',
397    'test/redfish-core/include/filter_expr_parser_test.cpp',
398    'test/redfish-core/include/redfish_aggregator_test.cpp',
399    'test/redfish-core/include/registries_test.cpp',
400    'test/redfish-core/include/utils/dbus_utils.cpp',
401    'test/redfish-core/include/utils/hex_utils_test.cpp',
402    'test/redfish-core/include/utils/ip_utils_test.cpp',
403    'test/redfish-core/include/utils/json_utils_test.cpp',
404    'test/redfish-core/include/utils/query_param_test.cpp',
405    'test/redfish-core/include/utils/stl_utils_test.cpp',
406    'test/redfish-core/include/utils/time_utils_test.cpp',
407    'test/redfish-core/lib/chassis_test.cpp',
408    'test/redfish-core/lib/log_services_dump_test.cpp',
409    'test/redfish-core/lib/log_services_test.cpp',
410    'test/redfish-core/lib/manager_diagnostic_data_test.cpp',
411    'test/redfish-core/lib/metadata_test.cpp',
412    'test/redfish-core/lib/power_subsystem_test.cpp',
413    'test/redfish-core/lib/sensors_test.cpp',
414    'test/redfish-core/lib/service_root_test.cpp',
415    'test/redfish-core/lib/system_test.cpp',
416    'test/redfish-core/lib/thermal_subsystem_test.cpp',
417    'test/redfish-core/lib/update_service_test.cpp',
418)
419
420if (get_option('tests').allowed())
421    # generate the test executable
422    foreach test_src : srcfiles_unittest
423        test_bin = executable(
424            fs.stem(test_src),
425            test_src,
426            link_with: bmcweblib,
427            include_directories: incdir,
428            install_dir: bindir,
429            dependencies: bmcweb_dependencies
430            + [
431                gtest,
432                gmock,
433            ],
434        )
435        test(fs.stem(test_src), test_bin)
436    endforeach
437endif
438