xref: /openbmc/bmcweb/meson.build (revision 852432ac) 
1project('bmcweb', 'cpp',
2        version : '1.0',
3        meson_version: '>=0.57.0',
4        default_options: [
5            'b_lto_mode=default',
6            'b_lto_threads=0',
7            'b_lto=true',
8            'b_ndebug=if-release',
9            'buildtype=debugoptimized',
10            'cpp_rtti=false',
11            'cpp_std=c++20',
12            'warning_level=3',
13            'werror=true',
14           ])
15
16# Project related links
17
18project_pretty_name = 'bmcweb'
19project_url = 'https://github.com/openbmc/' + project_pretty_name
20project_issues_url = project_url + '/issues/new'
21summary('Issues',project_issues_url, section: 'Report Issues')
22
23# Validate the c++ Standard
24
25if get_option('cpp_std') != 'c++20'
26    error('This project requires c++20 support')
27endif
28
29# Get compiler and default build type
30
31cxx = meson.get_compiler('cpp')
32build = get_option('buildtype')
33optimization = get_option('optimization')
34summary('Build Type',build, section : 'Build Info')
35summary('Optimization',optimization, section : 'Build Info')
36
37
38# remove debug information for minsize buildtype
39if(get_option('buildtype') == 'minsize')
40  add_project_arguments(['-fdata-sections', '-ffunction-sections'], language : 'cpp')
41  add_project_arguments('-DNDEBUG', language : 'cpp')
42endif
43
44# Disable lto when compiling with no optimization
45if(get_option('optimization') == '0')
46  add_project_arguments('-fno-lto', language: 'cpp')
47  message('Disabling lto & its supported features as optimization is disabled')
48endif
49
50# Include Directories
51
52incdir = include_directories(
53  'include',
54  'redfish-core/include',
55  'redfish-core/lib',
56  'http'
57)
58
59# Get the options and enable the respective features
60## create a MAP of  "options : feature_flag"
61
62feature_map = {
63  'basic-auth'                                  : '-DBMCWEB_ENABLE_BASIC_AUTHENTICATION',
64  'cookie-auth'                                 : '-DBMCWEB_ENABLE_COOKIE_AUTHENTICATION',
65  'google-api'                                  : '-DBMCWEB_ENABLE_GOOGLE_API',
66  'host-serial-socket'                          : '-DBMCWEB_ENABLE_HOST_SERIAL_WEBSOCKET',
67  'ibm-management-console'                      : '-DBMCWEB_ENABLE_IBM_MANAGEMENT_CONSOLE',
68  'insecure-disable-auth'                       : '-DBMCWEB_INSECURE_DISABLE_AUTHX',
69  'insecure-disable-csrf'                       : '-DBMCWEB_INSECURE_DISABLE_CSRF_PREVENTION',
70  'insecure-disable-ssl'                        : '-DBMCWEB_INSECURE_DISABLE_SSL',
71  'insecure-push-style-notification'            : '-DBMCWEB_INSECURE_ENABLE_HTTP_PUSH_STYLE_EVENTING',
72  'insecure-tftp-update'                        : '-DBMCWEB_INSECURE_ENABLE_REDFISH_FW_TFTP_UPDATE',
73  'kvm'                                         : '-DBMCWEB_ENABLE_KVM' ,
74  'mutual-tls-auth'                             : '-DBMCWEB_ENABLE_MUTUAL_TLS_AUTHENTICATION',
75  'redfish-aggregation'                         : '-DBMCWEB_ENABLE_REDFISH_AGGREGATION',
76  'redfish-allow-deprecated-power-thermal'      : '-DBMCWEB_ALLOW_DEPRECATED_POWER_THERMAL',
77  'redfish-bmc-journal'                         : '-DBMCWEB_ENABLE_REDFISH_BMC_JOURNAL',
78  'redfish-cpu-log'                             : '-DBMCWEB_ENABLE_REDFISH_CPU_LOG',
79  'redfish-dbus-log'                            : '-DBMCWEB_ENABLE_REDFISH_DBUS_LOG_ENTRIES',
80  'redfish-dump-log'                            : '-DBMCWEB_ENABLE_REDFISH_DUMP_LOG',
81  'redfish-host-logger'                         : '-DBMCWEB_ENABLE_REDFISH_HOST_LOGGER',
82  'redfish-new-powersubsystem-thermalsubsystem' : '-DBMCWEB_NEW_POWERSUBSYSTEM_THERMALSUBSYSTEM',
83  'redfish-provisioning-feature'                : '-DBMCWEB_ENABLE_REDFISH_PROVISIONING_FEATURE',
84  'redfish-post-to-old-updateservice'           : '-DBMCWEB_ENABLE_REDFISH_UPDATESERVICE_OLD_POST_URL',
85  'redfish'                                     : '-DBMCWEB_ENABLE_REDFISH',
86  'rest'                                        : '-DBMCWEB_ENABLE_DBUS_REST',
87  'session-auth'                                : '-DBMCWEB_ENABLE_SESSION_AUTHENTICATION',
88  'static-hosting'                              : '-DBMCWEB_ENABLE_STATIC_HOSTING',
89  'vm-websocket'                                : '-DBMCWEB_ENABLE_VM_WEBSOCKET',
90  'xtoken-auth'                                 : '-DBMCWEB_ENABLE_XTOKEN_AUTHENTICATION',
91  #'vm-nbdproxy'                                : '-DBMCWEB_ENABLE_VM_NBDPROXY',
92}
93
94# Get the options status and build a project summary to show which flags are
95# being enabled during the configuration time.
96
97foreach option_key,option_value : feature_map
98  if(get_option(option_key).enabled())
99    if(option_key == 'mutual-tls-auth' or option_key == 'insecure-disable-ssl')
100      if(get_option('insecure-disable-ssl').disabled() or get_option('mutual-tls-auth').disabled())
101        add_project_arguments(option_value,language:'cpp')
102        summary(option_key,option_value, section : 'Enabled Features')
103      endif
104    elif (option_key in ['basic-auth', 'cookie-auth', 'session-auth', 'xtoken-auth', 'mutual-tls-auth'])
105      if (get_option('insecure-disable-auth').disabled())
106        add_project_arguments(option_value, language:'cpp')
107        summary(option_key,option_value, section : 'Enabled Features')
108      endif
109    else
110      summary(option_key,option_value, section : 'Enabled Features')
111      add_project_arguments(option_value,language:'cpp')
112    endif
113  else
114      if(option_key == 'insecure-disable-ssl')
115        summary('ssl','-DBMCWEB_ENABLE_SSL', section : 'Enabled Features')
116        add_project_arguments('-DBMCWEB_ENABLE_SSL', language : 'cpp')
117      endif
118  endif
119endforeach
120
121if(get_option('tests').enabled())
122  summary('unittest','NA', section : 'Enabled Features')
123endif
124
125# Add compiler arguments
126
127# -Wpedantic, -Wextra comes by default with warning level
128add_project_arguments(
129  cxx.get_supported_arguments([
130  '-Wcast-align',
131  '-Wconversion',
132  '-Wformat=2',
133  '-Wold-style-cast',
134  '-Woverloaded-virtual',
135  '-Wsign-conversion',
136  '-Wunused',
137  '-Wno-attributes',
138  ]),
139  language: 'cpp'
140)
141
142if (cxx.get_id() == 'clang' and cxx.version().version_compare('>9.0'))
143add_project_arguments(
144  cxx.get_supported_arguments([
145    '-Weverything',
146    '-Wno-c++98-compat-pedantic',
147    '-Wno-c++98-compat',
148    '-Wno-documentation-unknown-command',
149    '-Wno-documentation',
150    '-Wno-exit-time-destructors',
151    '-Wno-global-constructors',
152    '-Wno-newline-eof',
153    '-Wno-padded',
154    '-Wno-shadow',
155    '-Wno-used-but-marked-unused',
156    '-Wno-weak-vtables',
157  ]),
158  language:'cpp')
159endif
160
161# if compiler is gnu-gcc , and version is > 8.0 then we add few more
162# compiler arguments , we know that will pass
163
164if (cxx.get_id() == 'gcc' and cxx.version().version_compare('>8.0'))
165  add_project_arguments(
166    cxx.get_supported_arguments([
167     '-Wduplicated-cond',
168     '-Wduplicated-branches',
169     '-Wlogical-op',
170     '-Wunused-parameter',
171     '-Wnull-dereference',
172     '-Wdouble-promotion',
173     '-Wshadow',
174     '-Wno-psabi',
175     ]),
176    language:'cpp')
177endif
178
179if (get_option('buildtype') != 'plain')
180  if (get_option('b_lto') == true and get_option('optimization')!='0')
181    # Reduce the binary size by removing unnecessary
182    # dynamic symbol table entries
183
184    add_project_arguments(
185     cxx.get_supported_arguments([
186     '-fno-fat-lto-objects',
187     '-fvisibility=hidden',
188     '-fvisibility-inlines-hidden'
189     ]),
190     language: 'cpp')
191
192    if cxx.has_link_argument('-Wl,--exclude-libs,ALL')
193      add_project_link_arguments('-Wl,--exclude-libs,ALL', language: 'cpp')
194    endif
195  endif
196endif
197
198if( get_option('bmcweb-logging').enabled() or \
199    get_option('buildtype').startswith('debug'))
200 add_project_arguments([
201   '-DBMCWEB_ENABLE_LOGGING',
202   '-DBMCWEB_ENABLE_DEBUG'
203   ],
204  language : 'cpp')
205
206  summary({'debug' :'-DBMCWEB_ENABLE_DEBUG',
207     'logging' : '-DBMCWEB_ENABLE_LOGGING',
208
209    },section : 'Enabled Features')
210endif
211
212# Set Compiler Security flags
213
214security_flags = [
215  '-fstack-protector-strong',
216  '-fPIE',
217  '-fPIC',
218  '-D_FORTIFY_SOURCE=2',
219  '-Wformat',
220  '-Wformat-security'
221]
222
223## Add security flags for builds of type 'release','debugoptimized' and 'minsize'
224
225if not (get_option('buildtype') == 'plain' or get_option('buildtype').startswith('debug'))
226  add_project_arguments(
227   cxx.get_supported_arguments([
228    security_flags
229  ]),
230  language: 'cpp')
231endif
232
233# Boost dependency configuration
234
235add_project_arguments(
236cxx.get_supported_arguments([
237  '-DBOOST_ALL_NO_LIB',
238  '-DBOOST_ALLOW_DEPRECATED_HEADERS',
239  '-DBOOST_ASIO_DISABLE_THREADS',
240  '-DBOOST_ASIO_NO_DEPRECATED',
241  '-DBOOST_ASIO_SEPARATE_COMPILATION',
242  '-DBOOST_BEAST_SEPARATE_COMPILATION',
243  '-DBOOST_BEAST_USE_STD_STRING_VIEW',
244  '-DBOOST_EXCEPTION_DISABLE',
245  '-DJSON_NOEXCEPTION',
246]),
247language : 'cpp')
248
249# Find the dependency modules, if not found use meson wrap to get them
250# automatically during the configure step
251bmcweb_dependencies = []
252
253pam = cxx.find_library('pam', required: true)
254atomic =  cxx.find_library('atomic', required: true)
255openssl = dependency('openssl', required : true)
256bmcweb_dependencies += [pam, atomic, openssl]
257
258sdbusplus = dependency('sdbusplus', required : false, include_type: 'system')
259if not sdbusplus.found()
260  sdbusplus_proj = subproject('sdbusplus', required: true)
261  sdbusplus = sdbusplus_proj.get_variable('sdbusplus_dep')
262  sdbusplus = sdbusplus.as_system('system')
263endif
264bmcweb_dependencies += sdbusplus
265
266tinyxml = dependency('tinyxml2',
267    default_options: ['tests=false'],
268    include_type: 'system',
269)
270bmcweb_dependencies += tinyxml
271
272systemd = dependency('systemd')
273zlib = dependency('zlib')
274bmcweb_dependencies += [systemd, zlib]
275
276if cxx.has_header('nlohmann/json.hpp')
277    nlohmann_json = declare_dependency()
278else
279    nlohmann_json_proj = subproject('nlohmann', required: true)
280    nlohmann_json = nlohmann_json_proj.get_variable('nlohmann_json_dep')
281    nlohmann_json = nlohmann_json.as_system('system')
282endif
283bmcweb_dependencies += nlohmann_json
284
285boost = dependency('boost',version : '>=1.78.0', required : false, include_type: 'system')
286if not boost.found()
287  subproject('boost', required: false)
288  boost_inc = include_directories('subprojects/boost_1_78_0/', is_system:true)
289  boost  = declare_dependency(include_directories : boost_inc)
290  boost = boost.as_system('system')
291endif
292bmcweb_dependencies += boost
293
294if cxx.has_header('boost/url/url_view.hpp')
295  boost_url = declare_dependency()
296else
297  subproject('boost-url', required: false)
298  boost_url_inc = include_directories('subprojects/boost-url/include', is_system:true)
299  boost_url= declare_dependency(include_directories : boost_url_inc)
300  boost_url = boost_url.as_system('system')
301endif
302bmcweb_dependencies += boost_url
303
304if get_option('tests').enabled()
305  gtest = dependency('gtest', main: true,disabler: true, required : false)
306  gmock = dependency('gmock', required : false)
307  if not gtest.found() and get_option('tests').enabled()
308    gtest_proj = subproject('gtest', required: true)
309    gtest = gtest_proj.get_variable('gtest_main_dep')
310    gmock = gtest_proj.get_variable('gmock_dep')
311  endif
312  gtest = gtest.as_system('system')
313  gmock = gmock.as_system('system')
314endif
315
316# Gather the Configuration data
317
318conf_data = configuration_data()
319conf_data.set('BMCWEB_HTTP_REQ_BODY_LIMIT_MB', get_option('http-body-limit'))
320xss_enabled = get_option('insecure-disable-xss')
321conf_data.set10('BMCWEB_INSECURE_DISABLE_XSS_PREVENTION', xss_enabled.enabled())
322enable_redfish_query = get_option('insecure-enable-redfish-query')
323conf_data.set10('BMCWEB_INSECURE_ENABLE_QUERY_PARAMS', enable_redfish_query.enabled())
324# enable_redfish_aggregation = get_option('redfish-aggregation')
325# conf_data.set10('BMCWEB_ENABLE_REDFISH_AGGREGATION', enable_redfish_aggregation.enabled())
326insecure_push_style_notification = get_option('insecure-push-style-notification')
327conf_data.set10('BMCWEB_INSECURE_ENABLE_HTTP_PUSH_STYLE_EVENTING', insecure_push_style_notification.enabled())
328conf_data.set('MESON_INSTALL_PREFIX', get_option('prefix'))
329conf_data.set('HTTPS_PORT', get_option('https_port'))
330configure_file(input: 'bmcweb_config.h.in',
331               output: 'bmcweb_config.h',
332               configuration: conf_data)
333
334# Configure and install systemd unit files
335
336systemd_system_unit_dir = systemd.get_variable(pkgconfig: 'systemdsystemunitdir')
337
338bindir = get_option('prefix') + '/' +get_option('bindir')
339
340summary({
341          'prefix' : get_option('prefix'),
342          'bindir' : bindir,
343          'systemd unit directory' : systemd_system_unit_dir
344        }, section : 'Directories')
345
346configure_file(input : 'bmcweb.socket.in',
347               output : 'bmcweb.socket',
348               install_dir: systemd_system_unit_dir,
349               configuration: conf_data,
350               install : true)
351
352configure_file(input : 'bmcweb.service.in',
353               output : 'bmcweb.service',
354               install_dir: systemd_system_unit_dir,
355               configuration: conf_data,
356               install : true)
357
358# Copy pam-webserver to etc/pam.d
359configure_file(input : 'pam-webserver',
360               output : 'webserver',
361               copy : true,
362               install_dir: '/etc/pam.d',
363               install : true)
364
365install_subdir('static', install_dir : 'share/www', strip_directory : true)
366
367# Source files
368
369srcfiles_bmcweb = [
370  'redfish-core/src/error_messages.cpp',
371  'redfish-core/src/utils/json_utils.cpp',
372  'src/boost_asio_ssl.cpp',
373  'src/boost_asio.cpp',
374  'src/boost_beast.cpp',
375  'src/boost_url.cpp',
376  'src/dbus_singleton.cpp',
377]
378
379# Generate the bmcweb executable
380executable(
381  'bmcweb',
382  srcfiles_bmcweb + ['src/webserver_main.cpp'],
383  include_directories : incdir,
384  dependencies: bmcweb_dependencies,
385  link_args: '-Wl,--gc-sections',
386  install: true,
387  install_dir:bindir
388)
389
390srcfiles_unittest = [
391  'http/ut/utility_test.cpp',
392  'http/ut/router_test.cpp',
393  'include/google/google_service_root_test.cpp',
394  'include/ut/dbus_utility_test.cpp',
395  'include/ut/http_utility_test.cpp',
396  'include/ut/human_sort_test.cpp',
397  'include/ut/multipart_test.cpp',
398  'include/ut/openbmc_dbus_rest_test.cpp',
399  'redfish-core/include/utils/query_param_test.cpp',
400  'redfish-core/lib/ut/service_root_test.cpp',
401  'redfish-core/lib/chassis_test.cpp',
402  'redfish-core/ut/configfile_test.cpp',
403  'redfish-core/ut/hex_utils_test.cpp',
404  'redfish-core/ut/ip_utils_test.cpp',
405  'redfish-core/ut/json_utils_test.cpp',
406  'redfish-core/ut/lock_test.cpp',
407  'redfish-core/ut/privileges_test.cpp',
408  'redfish-core/ut/registries_test.cpp',
409  'redfish-core/ut/stl_utils_test.cpp',
410  'redfish-core/ut/time_utils_test.cpp',
411  'src/crow_getroutes_test.cpp',
412]
413
414if(get_option('tests').enabled())
415    # generate the test executable
416    ut_bin = executable(
417      'bmcweb_unit_test',
418      srcfiles_unittest + srcfiles_bmcweb,
419      include_directories : incdir,
420      install_dir: bindir,
421      dependencies: bmcweb_dependencies + [
422        gtest,
423        gmock,
424      ]
425    )
426    test('bmcweb_unit_test', ut_bin)
427endif
428