xref: /openbmc/bmcweb/meson.build (revision 56d0bb06) 
1project(
2    'bmcweb',
3    'cpp',
4    version: '1.0',
5    meson_version: '>=0.63.0',
6    default_options: [
7        'b_lto_mode=default',
8        'b_lto_threads=0',
9        'b_lto=true',
10        'b_ndebug=if-release',
11        'buildtype=debugoptimized',
12        'cpp_rtti=false',
13        'cpp_std=c++20',
14        'warning_level=3',
15        'werror=true',
16    ],
17)
18
19# Project related links
20
21project_pretty_name = 'bmcweb'
22project_url = 'https://github.com/openbmc/' + project_pretty_name
23project_issues_url = project_url + '/issues/new'
24summary('Issues', project_issues_url, section: 'Report Issues')
25
26# Validate the c++ Standard
27
28if get_option('cpp_std') != 'c++20'
29    error('This project requires c++20 support')
30endif
31
32# Get compiler and default build type
33
34cxx = meson.get_compiler('cpp')
35build = get_option('buildtype')
36optimization = get_option('optimization')
37summary('Build Type', build, section: 'Build Info')
38summary('Optimization', optimization, section: 'Build Info')
39
40# remove debug information for minsize buildtype
41if (get_option('buildtype') == 'minsize')
42    add_project_arguments(['-fdata-sections', '-ffunction-sections'], language: 'cpp')
43    add_project_arguments('-DNDEBUG', language: 'cpp')
44endif
45
46if (get_option('dns-resolver') == 'systemd-dbus')
47    add_project_arguments('-DBMCWEB_DBUS_DNS_RESOLVER', language: 'cpp')
48endif
49
50# Disable lto when compiling with no optimization
51if (get_option('optimization') == '0')
52    add_project_arguments('-fno-lto', language: 'cpp')
53    message('Disabling lto & its supported features as optimization is disabled')
54endif
55
56# Include Directories
57
58incdir = include_directories('include', 'redfish-core/include', 'redfish-core/lib', 'http')
59
60# Get the options and enable the respective features
61## create a MAP of  "options : feature_flag"
62
63feature_map = {
64    'basic-auth': '-DBMCWEB_ENABLE_BASIC_AUTHENTICATION',
65    'cookie-auth': '-DBMCWEB_ENABLE_COOKIE_AUTHENTICATION',
66    'google-api': '-DBMCWEB_ENABLE_GOOGLE_API',
67    'host-serial-socket': '-DBMCWEB_ENABLE_HOST_SERIAL_WEBSOCKET',
68    'ibm-management-console': '-DBMCWEB_ENABLE_IBM_MANAGEMENT_CONSOLE',
69    'insecure-disable-auth': '-DBMCWEB_INSECURE_DISABLE_AUTHX',
70    'insecure-disable-csrf': '-DBMCWEB_INSECURE_DISABLE_CSRF_PREVENTION',
71    'insecure-disable-ssl': '-DBMCWEB_INSECURE_DISABLE_SSL',
72    'insecure-push-style-notification': '-DBMCWEB_INSECURE_ENABLE_HTTP_PUSH_STYLE_EVENTING',
73    'insecure-tftp-update': '-DBMCWEB_INSECURE_ENABLE_REDFISH_FW_TFTP_UPDATE',
74    'insecure-ignore-content-type': '-DBMCWEB_INSECURE_IGNORE_CONTENT_TYPE',
75    'kvm': '-DBMCWEB_ENABLE_KVM',
76    'mutual-tls-auth': '-DBMCWEB_ENABLE_MUTUAL_TLS_AUTHENTICATION',
77    'redfish-aggregation': '-DBMCWEB_ENABLE_REDFISH_AGGREGATION',
78    'redfish-allow-deprecated-power-thermal': '-DBMCWEB_ALLOW_DEPRECATED_POWER_THERMAL',
79    'redfish-bmc-journal': '-DBMCWEB_ENABLE_REDFISH_BMC_JOURNAL',
80    'redfish-cpu-log': '-DBMCWEB_ENABLE_REDFISH_CPU_LOG',
81    'redfish-dbus-log': '-DBMCWEB_ENABLE_REDFISH_DBUS_LOG_ENTRIES',
82    'redfish-dump-log': '-DBMCWEB_ENABLE_REDFISH_DUMP_LOG',
83    'redfish-host-logger': '-DBMCWEB_ENABLE_REDFISH_HOST_LOGGER',
84    'redfish-new-powersubsystem-thermalsubsystem': '-DBMCWEB_NEW_POWERSUBSYSTEM_THERMALSUBSYSTEM',
85    'redfish-oem-manager-fan-data': '-DBMCWEB_ENABLE_REDFISH_OEM_MANAGER_FAN_DATA',
86    'redfish-provisioning-feature': '-DBMCWEB_ENABLE_REDFISH_PROVISIONING_FEATURE',
87    'redfish': '-DBMCWEB_ENABLE_REDFISH',
88    'rest': '-DBMCWEB_ENABLE_DBUS_REST',
89    'session-auth': '-DBMCWEB_ENABLE_SESSION_AUTHENTICATION',
90    'static-hosting': '-DBMCWEB_ENABLE_STATIC_HOSTING',
91    'experimental-redfish-multi-computer-system': '-DBMCWEB_ENABLE_MULTI_COMPUTERSYSTEM',
92    'vm-websocket': '-DBMCWEB_ENABLE_VM_WEBSOCKET',
93    'xtoken-auth': '-DBMCWEB_ENABLE_XTOKEN_AUTHENTICATION',
94    #'vm-nbdproxy'                                : '-DBMCWEB_ENABLE_VM_NBDPROXY',
95}
96
97# Get the options status and build a project summary to show which flags are
98# being enabled during the configuration time.
99
100foreach option_key, option_value : feature_map
101    if (get_option(option_key).allowed())
102        if (
103            option_key == 'mutual-tls-auth'
104            or option_key == 'insecure-disable-ssl'
105        )
106            if (
107                get_option('insecure-disable-ssl').disabled()
108                or get_option('mutual-tls-auth').disabled()
109            )
110                add_project_arguments(option_value, language: 'cpp')
111                summary(option_key, option_value, section: 'Enabled Features')
112            endif
113        elif (
114            option_key in [
115                'basic-auth',
116                'cookie-auth',
117                'session-auth',
118                'xtoken-auth',
119                'mutual-tls-auth',
120            ]
121        )
122            if (get_option('insecure-disable-auth').disabled())
123                add_project_arguments(option_value, language: 'cpp')
124                summary(option_key, option_value, section: 'Enabled Features')
125            endif
126        else
127            summary(option_key, option_value, section: 'Enabled Features')
128            add_project_arguments(option_value, language: 'cpp')
129        endif
130    else
131        if (option_key == 'insecure-disable-ssl')
132            summary('ssl', '-DBMCWEB_ENABLE_SSL', section: 'Enabled Features')
133            add_project_arguments('-DBMCWEB_ENABLE_SSL', language: 'cpp')
134        endif
135    endif
136endforeach
137
138if (get_option('tests').allowed())
139    summary('unittest', 'NA', section: 'Enabled Features')
140endif
141
142# Add compiler arguments
143
144if (cxx.get_id() == 'clang')
145    if (cxx.version().version_compare('<17.0'))
146        error('This project requires clang-17 or higher')
147    endif
148    add_project_arguments(
149        '-Weverything',
150        '-Wformat=2',
151        '-Wno-c++98-compat-pedantic',
152        '-Wno-c++98-compat',
153        '-Wno-documentation-unknown-command',
154        '-Wno-documentation',
155        '-Wno-exit-time-destructors',
156        '-Wno-global-constructors',
157        '-Wno-newline-eof',
158        '-Wno-padded',
159        '-Wno-shadow',
160        '-Wno-used-but-marked-unused',
161        '-Wno-weak-vtables',
162        '-Wno-switch-enum',
163        '-Wno-unused-macros',
164        '-Wno-covered-switch-default',
165        language: 'cpp',
166    )
167endif
168
169if (cxx.get_id() == 'gcc')
170    if (cxx.version().version_compare('<13.0'))
171        error('This project requires gcc-13 or higher')
172    endif
173
174    add_project_arguments(
175        '-Wformat=2',
176        '-Wcast-align',
177        '-Wconversion',
178        '-Woverloaded-virtual',
179        '-Wsign-conversion',
180        '-Wunused',
181        '-Wduplicated-cond',
182        '-Wduplicated-branches',
183        '-Wlogical-op',
184        '-Wnull-dereference',
185        '-Wunused-parameter',
186        '-Wdouble-promotion',
187        '-Wshadow',
188        '-Wno-psabi',
189        '-Wno-attributes',
190        language: 'cpp',
191    )
192endif
193
194if (get_option('buildtype') != 'plain')
195    if (get_option('b_lto') == true and get_option('optimization') != '0')
196        # Reduce the binary size by removing unnecessary
197        # dynamic symbol table entries
198
199        add_project_arguments(
200            cxx.get_supported_arguments(
201                [
202                    '-fno-fat-lto-objects',
203                    '-fvisibility=hidden',
204                    '-fvisibility-inlines-hidden',
205                ],
206            ),
207            language: 'cpp',
208        )
209
210        if cxx.has_link_argument('-Wl,--exclude-libs,ALL')
211            add_project_link_arguments('-Wl,--exclude-libs,ALL', language: 'cpp')
212        endif
213    endif
214endif
215
216if (
217    get_option('bmcweb-logging') != 'disabled'
218    or get_option('buildtype').startswith('debug')
219)
220    add_project_arguments(['-DBMCWEB_ENABLE_DEBUG'], language: 'cpp')
221
222    summary('debug', '-DBMCWEB_ENABLE_DEBUG', section: 'Enabled Features')
223endif
224
225# Set Compiler Security flags
226
227security_flags = [
228    '-fstack-protector-strong',
229    '-fPIE',
230    '-fPIC',
231    '-D_FORTIFY_SOURCE=2',
232    '-Wformat',
233    '-Wformat-security',
234]
235
236## Add security flags for builds of type 'release','debugoptimized' and 'minsize'
237
238if not (
239    get_option('buildtype') == 'plain'
240    or get_option('buildtype').startswith('debug')
241)
242    add_project_arguments(cxx.get_supported_arguments([security_flags]), language: 'cpp')
243endif
244
245# Boost dependency configuration
246
247add_project_arguments(
248    cxx.get_supported_arguments(
249        [
250            '-DBOOST_ASIO_DISABLE_CONCEPTS',
251            '-DBOOST_ALL_NO_LIB',
252            '-DBOOST_ALLOW_DEPRECATED_HEADERS',
253            '-DBOOST_ASIO_DISABLE_THREADS',
254            '-DBOOST_ASIO_NO_DEPRECATED',
255            '-DBOOST_ASIO_SEPARATE_COMPILATION',
256            '-DBOOST_BEAST_SEPARATE_COMPILATION',
257            '-DBOOST_EXCEPTION_DISABLE',
258            '-DBOOST_NO_EXCEPTIONS',
259            '-DBOOST_URL_NO_SOURCE_LOCATION',
260            '-DJSON_NOEXCEPTION',
261            '-DOPENSSL_NO_FILENAMES',
262            '-DSDBUSPLUS_DISABLE_BOOST_COROUTINES',
263        ],
264    ),
265    language: 'cpp',
266)
267
268# Find the dependency modules, if not found use meson wrap to get them
269# automatically during the configure step
270bmcweb_dependencies = []
271
272pam = cxx.find_library('pam', required: true)
273atomic = cxx.find_library('atomic', required: true)
274bmcweb_dependencies += [pam, atomic]
275
276openssl = dependency('openssl', required: false, version: '>=3.0.0')
277if not openssl.found() or get_option('b_sanitize') != 'none'
278    openssl_proj = subproject(
279        'openssl',
280        required: true,
281        default_options: ['warning_level=0', 'werror=false'],
282    )
283    openssl = openssl_proj.get_variable('openssl_dep')
284    openssl = openssl.as_system('system')
285endif
286bmcweb_dependencies += [openssl]
287
288nghttp2 = dependency('libnghttp2', version: '>=1.52.0', required: false)
289if not nghttp2.found()
290    cmake = import('cmake')
291    opt_var = cmake.subproject_options()
292    opt_var.add_cmake_defines({'ENABLE_LIB_ONLY': true, 'ENABLE_STATIC_LIB': true})
293    nghttp2_ex = cmake.subproject('nghttp2', options: opt_var)
294    nghttp2 = nghttp2_ex.dependency('nghttp2_static')
295endif
296bmcweb_dependencies += nghttp2
297
298sdbusplus = dependency('sdbusplus', required: false, include_type: 'system')
299if not sdbusplus.found()
300    sdbusplus_proj = subproject('sdbusplus', required: true)
301    sdbusplus = sdbusplus_proj.get_variable('sdbusplus_dep')
302    sdbusplus = sdbusplus.as_system('system')
303endif
304bmcweb_dependencies += sdbusplus
305
306tinyxml = dependency(
307    'tinyxml2',
308    include_type: 'system',
309    version: '>=9.0.0',
310    default_options: ['tests=false'],
311)
312if not tinyxml.found()
313    tinyxml_proj = subproject('tinyxml2', required: true)
314    tinyxml = tinyxml_proj.get_variable('tinyxml_dep')
315    tinyxml = tinyxml.as_system('system')
316endif
317bmcweb_dependencies += tinyxml
318
319systemd = dependency('systemd')
320zlib = dependency('zlib')
321bmcweb_dependencies += [systemd, zlib]
322
323nlohmann_json_dep = dependency('nlohmann_json', version: '>=3.11.2', include_type: 'system')
324bmcweb_dependencies += nlohmann_json_dep
325
326boost = dependency(
327    'boost',
328    modules: [
329        'url',
330    ],
331    version: '>=1.84.0',
332    required: false,
333    include_type: 'system',
334)
335if boost.found()
336    bmcweb_dependencies += [boost]
337else
338    cmake = import('cmake')
339    opt = cmake.subproject_options()
340    opt.add_cmake_defines(
341        {
342            'BOOST_INCLUDE_LIBRARIES': 'asio;beast;callable_traits;headers;process;type_index;url;uuid',
343            'BUILD_SHARED_LIBS': 'OFF',
344        },
345    )
346
347    boost = cmake.subproject('boost', required: true, options: opt)
348    boost_asio = boost.dependency('boost_asio').as_system()
349    boost_beast = boost.dependency('boost_beast').as_system()
350    boost_callable_traits = boost.dependency('boost_callable_traits').as_system()
351    boost_headers = boost.dependency('boost_headers').as_system()
352    boost_process = boost.dependency('boost_process').as_system()
353    boost_type_index = boost.dependency('boost_type_index').as_system()
354    boost_url = boost.dependency('boost_url').as_system()
355    boost_uuid = boost.dependency('boost_uuid').as_system()
356    bmcweb_dependencies += [
357        boost_asio,
358        boost_beast,
359        boost_callable_traits,
360        boost_headers,
361        boost_process,
362        boost_type_index,
363        boost_url,
364        boost_uuid,
365    ]
366endif
367
368if get_option('tests').allowed()
369    gtest = dependency(
370        'gtest',
371        main: true,
372        version: '>=1.14.0',
373        disabler: true,
374        required: false,
375    )
376    gmock = dependency('gmock', required: false)
377    if not gtest.found() and get_option('tests').allowed()
378        gtest_proj = subproject('gtest', required: true)
379        gtest = gtest_proj.get_variable('gtest_main_dep')
380        gmock = gtest_proj.get_variable('gmock_dep')
381    endif
382    gtest = gtest.as_system('system')
383    gmock = gmock.as_system('system')
384endif
385
386systemd_system_unit_dir = systemd.get_variable('systemdsystemunitdir')
387
388bindir = get_option('prefix') + '/' + get_option('bindir')
389
390summary(
391    {
392        'prefix': get_option('prefix'),
393        'bindir': bindir,
394        'systemd unit directory': systemd_system_unit_dir,
395    },
396    section: 'Directories',
397)
398
399install_subdir('static', install_dir: 'share/www', strip_directory: true)
400
401# Config subdirectory
402
403subdir('config')
404bmcweb_dependencies += conf_h_dep
405
406# Source files
407fs = import('fs')
408
409srcfiles_bmcweb = files(
410    # end large files
411
412    'redfish-core/src/error_messages.cpp',
413    # Begin large files, should be at the beginning
414    'redfish-core/src/redfish.cpp',
415    'redfish-core/src/registries.cpp',
416    'redfish-core/src/utils/dbus_utils.cpp',
417    'redfish-core/src/utils/json_utils.cpp',
418    'redfish-core/src/utils/time_utils.cpp',
419    'src/boost_asio.cpp',
420    'src/boost_asio_ssl.cpp',
421    'src/boost_beast.cpp',
422    'src/dbus_singleton.cpp',
423    'src/json_html_serializer.cpp',
424    'src/ossl_random.cpp',
425    'src/webserver_run.cpp',
426)
427
428bmcweblib = static_library(
429    'bmcweblib',
430    srcfiles_bmcweb,
431    include_directories: incdir,
432    dependencies: bmcweb_dependencies,
433)
434
435# Generate the bmcweb executable
436executable(
437    'bmcweb',
438    'src/webserver_main.cpp',
439    include_directories: incdir,
440    dependencies: bmcweb_dependencies,
441    link_with: bmcweblib,
442    link_args: '-Wl,--gc-sections',
443    install: true,
444    install_dir: bindir,
445)
446
447srcfiles_unittest = files(
448    'test/http/crow_getroutes_test.cpp',
449    'test/http/http2_connection_test.cpp',
450    'test/http/http_body_test.cpp',
451    'test/http/http_connection_test.cpp',
452    'test/http/http_response_test.cpp',
453    'test/http/mutual_tls.cpp',
454    'test/http/mutual_tls_meta.cpp',
455    'test/http/parsing_test.cpp',
456    'test/http/router_test.cpp',
457    'test/http/server_sent_event_test.cpp',
458    'test/http/utility_test.cpp',
459    'test/http/verb_test.cpp',
460    'test/include/async_resolve_test.cpp',
461    'test/include/credential_pipe_test.cpp',
462    'test/include/dbus_utility_test.cpp',
463    'test/include/google/google_service_root_test.cpp',
464    'test/include/http_utility_test.cpp',
465    'test/include/human_sort_test.cpp',
466    'test/include/ibm/configfile_test.cpp',
467    'test/include/json_html_serializer.cpp',
468    'test/include/multipart_test.cpp',
469    'test/include/openbmc_dbus_rest_test.cpp',
470    'test/include/ossl_random.cpp',
471    'test/include/str_utility_test.cpp',
472    'test/redfish-core/include/privileges_test.cpp',
473    'test/redfish-core/include/redfish_aggregator_test.cpp',
474    'test/redfish-core/include/registries_test.cpp',
475    'test/redfish-core/include/utils/dbus_utils.cpp',
476    'test/redfish-core/include/utils/hex_utils_test.cpp',
477    'test/redfish-core/include/utils/ip_utils_test.cpp',
478    'test/redfish-core/include/utils/json_utils_test.cpp',
479    'test/redfish-core/include/utils/query_param_test.cpp',
480    'test/redfish-core/include/utils/stl_utils_test.cpp',
481    'test/redfish-core/include/utils/time_utils_test.cpp',
482    'test/redfish-core/lib/chassis_test.cpp',
483    'test/redfish-core/lib/log_services_dump_test.cpp',
484    'test/redfish-core/lib/log_services_test.cpp',
485    'test/redfish-core/lib/manager_diagnostic_data_test.cpp',
486    'test/redfish-core/lib/power_subsystem_test.cpp',
487    'test/redfish-core/lib/sensors_test.cpp',
488    'test/redfish-core/lib/service_root_test.cpp',
489    'test/redfish-core/lib/system_test.cpp',
490    'test/redfish-core/lib/thermal_subsystem_test.cpp',
491    'test/redfish-core/lib/update_service_test.cpp',
492)
493
494if (get_option('tests').allowed())
495    # generate the test executable
496    foreach test_src : srcfiles_unittest
497        test_bin = executable(
498            fs.stem(test_src),
499            test_src,
500            link_with: bmcweblib,
501            include_directories: incdir,
502            install_dir: bindir,
503            dependencies: bmcweb_dependencies
504            + [
505                gtest,
506                gmock,
507            ],
508        )
509        test(fs.stem(test_src), test_bin)
510    endforeach
511endif
512