xref: /openbmc/bmcweb/meson.build (revision 4cee35e7) 
1project('bmcweb', 'cpp',
2        version : '1.0',
3        meson_version: '>=0.57.0',
4        default_options: [
5            'b_lto_mode=default',
6            'b_lto_threads=0',
7            'b_lto=true',
8            'b_ndebug=if-release',
9            'buildtype=debugoptimized',
10            'cpp_rtti=false',
11            'cpp_std=c++20',
12            'warning_level=3',
13            'werror=true',
14           ])
15
16# Project related links
17
18project_pretty_name = 'bmcweb'
19project_url = 'https://github.com/openbmc/' + project_pretty_name
20project_issues_url = project_url + '/issues/new'
21summary('Issues',project_issues_url, section: 'Report Issues')
22
23# Validate the c++ Standard
24
25if get_option('cpp_std') != 'c++20'
26    error('This project requires c++20 support')
27endif
28
29# Get compiler and default build type
30
31cxx = meson.get_compiler('cpp')
32build = get_option('buildtype')
33optimization = get_option('optimization')
34summary('Build Type',build, section : 'Build Info')
35summary('Optimization',optimization, section : 'Build Info')
36
37
38# remove debug information for minsize buildtype
39if(get_option('buildtype') == 'minsize')
40  add_project_arguments(['-fdata-sections', '-ffunction-sections'], language : 'cpp')
41  add_project_arguments('-DNDEBUG', language : 'cpp')
42endif
43
44# Disable lto when compiling with no optimization
45if(get_option('optimization') == '0')
46  add_project_arguments('-fno-lto', language: 'cpp')
47  message('Disabling lto & its supported features as optimization is disabled')
48endif
49
50# Include Directories
51
52incdir = include_directories(
53  'include',
54  'redfish-core/include',
55  'redfish-core/lib',
56  'http'
57)
58
59# Get the options and enable the respective features
60## create a MAP of  "options : feature_flag"
61
62feature_map = {
63  'basic-auth'                                  : '-DBMCWEB_ENABLE_BASIC_AUTHENTICATION',
64  'cookie-auth'                                 : '-DBMCWEB_ENABLE_COOKIE_AUTHENTICATION',
65  'google-api'                                  : '-DBMCWEB_ENABLE_GOOGLE_API',
66  'host-serial-socket'                          : '-DBMCWEB_ENABLE_HOST_SERIAL_WEBSOCKET',
67  'ibm-management-console'                      : '-DBMCWEB_ENABLE_IBM_MANAGEMENT_CONSOLE',
68  'insecure-disable-auth'                       : '-DBMCWEB_INSECURE_DISABLE_AUTHENTICATION',
69  'insecure-disable-csrf'                       : '-DBMCWEB_INSECURE_DISABLE_CSRF_PREVENTION',
70  'insecure-disable-ssl'                        : '-DBMCWEB_INSECURE_DISABLE_SSL',
71  'insecure-push-style-notification'            : '-DBMCWEB_INSECURE_ENABLE_HTTP_PUSH_STYLE_EVENTING',
72  'insecure-tftp-update'                        : '-DBMCWEB_INSECURE_ENABLE_REDFISH_FW_TFTP_UPDATE',
73  'kvm'                                         : '-DBMCWEB_ENABLE_KVM' ,
74  'mutual-tls-auth'                             : '-DBMCWEB_ENABLE_MUTUAL_TLS_AUTHENTICATION',
75  'redfish-allow-deprecated-power-thermal'      : '-DBMCWEB_ALLOW_DEPRECATED_POWER_THERMAL',
76  'redfish-bmc-journal'                         : '-DBMCWEB_ENABLE_REDFISH_BMC_JOURNAL',
77  'redfish-cpu-log'                             : '-DBMCWEB_ENABLE_REDFISH_CPU_LOG',
78  'redfish-dbus-log'                            : '-DBMCWEB_ENABLE_REDFISH_DBUS_LOG_ENTRIES',
79  'redfish-dump-log'                            : '-DBMCWEB_ENABLE_REDFISH_DUMP_LOG',
80  'redfish-host-logger'                         : '-DBMCWEB_ENABLE_REDFISH_HOST_LOGGER',
81  'redfish-new-powersubsystem-thermalsubsystem' : '-DBMCWEB_NEW_POWERSUBSYSTEM_THERMALSUBSYSTEM',
82  'redfish-provisioning-feature'                : '-DBMCWEB_ENABLE_REDFISH_PROVISIONING_FEATURE',
83  'redfish-post-to-old-updateservice'           : '-DBMCWEB_ENABLE_REDFISH_UPDATESERVICE_OLD_POST_URL',
84  'redfish'                                     : '-DBMCWEB_ENABLE_REDFISH',
85  'rest'                                        : '-DBMCWEB_ENABLE_DBUS_REST',
86  'session-auth'                                : '-DBMCWEB_ENABLE_SESSION_AUTHENTICATION',
87  'static-hosting'                              : '-DBMCWEB_ENABLE_STATIC_HOSTING',
88  'vm-websocket'                                : '-DBMCWEB_ENABLE_VM_WEBSOCKET',
89  'xtoken-auth'                                 : '-DBMCWEB_ENABLE_XTOKEN_AUTHENTICATION',
90  #'vm-nbdproxy'                                : '-DBMCWEB_ENABLE_VM_NBDPROXY',
91}
92
93# Get the options status and build a project summary to show which flags are
94# being enabled during the configuration time.
95
96foreach option_key,option_value : feature_map
97  if(get_option(option_key).enabled())
98    if(option_key == 'mutual-tls-auth' or option_key == 'insecure-disable-ssl')
99      if(get_option('insecure-disable-ssl').disabled() or get_option('mutual-tls-auth').disabled())
100        add_project_arguments(option_value,language:'cpp')
101        summary(option_key,option_value, section : 'Enabled Features')
102      endif
103    else
104      summary(option_key,option_value, section : 'Enabled Features')
105      add_project_arguments(option_value,language:'cpp')
106    endif
107  else
108      if(option_key == 'insecure-disable-ssl')
109        summary('ssl','-DBMCWEB_ENABLE_SSL', section : 'Enabled Features')
110        add_project_arguments('-DBMCWEB_ENABLE_SSL', language : 'cpp')
111      endif
112  endif
113endforeach
114
115if(get_option('tests').enabled())
116  summary('unittest','NA', section : 'Enabled Features')
117endif
118
119# Add compiler arguments
120
121# -Wpedantic, -Wextra comes by default with warning level
122add_project_arguments(
123  cxx.get_supported_arguments([
124  '-Wcast-align',
125  '-Wconversion',
126  '-Wformat=2',
127  '-Wold-style-cast',
128  '-Woverloaded-virtual',
129  '-Wsign-conversion',
130  '-Wunused',
131  '-Wno-attributes',
132  ]),
133  language: 'cpp'
134)
135
136if (cxx.get_id() == 'clang' and cxx.version().version_compare('>9.0'))
137add_project_arguments(
138  cxx.get_supported_arguments([
139    '-Weverything',
140    '-Wno-c++98-compat-pedantic',
141    '-Wno-c++98-compat',
142    '-Wno-documentation-unknown-command',
143    '-Wno-documentation',
144    '-Wno-exit-time-destructors',
145    '-Wno-global-constructors',
146    '-Wno-newline-eof',
147    '-Wno-padded',
148    '-Wno-shadow',
149    '-Wno-used-but-marked-unused',
150    '-Wno-weak-vtables',
151  ]),
152  language:'cpp')
153endif
154
155# if compiler is gnu-gcc , and version is > 8.0 then we add few more
156# compiler arguments , we know that will pass
157
158if (cxx.get_id() == 'gcc' and cxx.version().version_compare('>8.0'))
159  add_project_arguments(
160    cxx.get_supported_arguments([
161     '-Wduplicated-cond',
162     '-Wduplicated-branches',
163     '-Wlogical-op',
164     '-Wunused-parameter',
165     '-Wnull-dereference',
166     '-Wdouble-promotion',
167     ]),
168    language:'cpp')
169endif
170
171if (get_option('buildtype') != 'plain')
172  if (get_option('b_lto') == true and get_option('optimization')!='0')
173    # Reduce the binary size by removing unnecessary
174    # dynamic symbol table entries
175
176    add_project_arguments(
177     cxx.get_supported_arguments([
178     '-fno-fat-lto-objects',
179     '-fvisibility=hidden',
180     '-fvisibility-inlines-hidden'
181     ]),
182     language: 'cpp')
183
184    if cxx.has_link_argument('-Wl,--exclude-libs,ALL')
185      add_project_link_arguments('-Wl,--exclude-libs,ALL', language: 'cpp')
186    endif
187  endif
188endif
189
190if( get_option('bmcweb-logging').enabled() or \
191    get_option('buildtype').startswith('debug'))
192 add_project_arguments([
193   '-DBMCWEB_ENABLE_LOGGING',
194   '-DBMCWEB_ENABLE_DEBUG'
195   ],
196  language : 'cpp')
197
198  summary({'debug' :'-DBMCWEB_ENABLE_DEBUG',
199     'logging' : '-DBMCWEB_ENABLE_LOGGING',
200
201    },section : 'Enabled Features')
202endif
203
204# Set Compiler Security flags
205
206security_flags = [
207  '-fstack-protector-strong',
208  '-fPIE',
209  '-fPIC',
210  '-D_FORTIFY_SOURCE=2',
211  '-Wformat',
212  '-Wformat-security'
213]
214
215## Add security flags for builds of type 'release','debugoptimized' and 'minsize'
216
217if not (get_option('buildtype') == 'plain' or get_option('buildtype').startswith('debug'))
218  add_project_arguments(
219   cxx.get_supported_arguments([
220    security_flags
221  ]),
222  language: 'cpp')
223endif
224
225# Boost dependency configuration
226
227add_project_arguments(
228cxx.get_supported_arguments([
229  '-DBOOST_ALL_NO_LIB',
230  '-DBOOST_ALLOW_DEPRECATED_HEADERS',
231  '-DBOOST_ASIO_DISABLE_THREADS',
232  '-DBOOST_ASIO_NO_DEPRECATED',
233  '-DBOOST_ASIO_SEPARATE_COMPILATION',
234  '-DBOOST_BEAST_SEPARATE_COMPILATION',
235  '-DBOOST_BEAST_USE_STD_STRING_VIEW',
236  '-DBOOST_EXCEPTION_DISABLE',
237  '-DJSON_NOEXCEPTION',
238]),
239language : 'cpp')
240
241# Find the dependency modules, if not found use meson wrap to get them
242# automatically during the configure step
243bmcweb_dependencies = []
244
245pam = cxx.find_library('pam', required: true)
246atomic =  cxx.find_library('atomic', required: true)
247openssl = dependency('openssl', required : true)
248bmcweb_dependencies += [pam, atomic, openssl]
249
250sdbusplus = dependency('sdbusplus', required : false, include_type: 'system')
251if not sdbusplus.found()
252  sdbusplus_proj = subproject('sdbusplus', required: true)
253  sdbusplus = sdbusplus_proj.get_variable('sdbusplus_dep')
254  sdbusplus = sdbusplus.as_system('system')
255endif
256bmcweb_dependencies += sdbusplus
257
258if get_option('rest').enabled()
259  tinyxml = dependency('tinyxml2',
260      default_options: ['tests=false'],
261      include_type: 'system',
262  )
263  bmcweb_dependencies += tinyxml
264endif
265
266systemd = dependency('systemd')
267zlib = dependency('zlib')
268bmcweb_dependencies += [systemd, zlib]
269
270if cxx.has_header('nlohmann/json.hpp')
271    nlohmann_json = declare_dependency()
272else
273    nlohmann_json_proj = subproject('nlohmann', required: true)
274    nlohmann_json = nlohmann_json_proj.get_variable('nlohmann_json_dep')
275    nlohmann_json = nlohmann_json.as_system('system')
276endif
277bmcweb_dependencies += nlohmann_json
278
279boost = dependency('boost',version : '>=1.78.0', required : false, include_type: 'system')
280if not boost.found()
281  subproject('boost', required: false)
282  boost_inc = include_directories('subprojects/boost_1_78_0/', is_system:true)
283  boost  = declare_dependency(include_directories : boost_inc)
284  boost = boost.as_system('system')
285endif
286bmcweb_dependencies += boost
287
288if cxx.has_header('boost/url/url_view.hpp')
289  boost_url = declare_dependency()
290else
291  subproject('boost-url', required: false)
292  boost_url_inc = include_directories('subprojects/boost-url/include', is_system:true)
293  boost_url= declare_dependency(include_directories : boost_url_inc)
294  boost_url = boost_url.as_system('system')
295endif
296bmcweb_dependencies += boost_url
297
298if get_option('tests').enabled()
299  gtest = dependency('gtest', main: true,disabler: true, required : false)
300  gmock = dependency('gmock', required : false)
301  if not gtest.found() and get_option('tests').enabled()
302    gtest_proj = subproject('gtest', required: true)
303    gtest = gtest_proj.get_variable('gtest_main_dep')
304    gmock = gtest_proj.get_variable('gmock_dep')
305  endif
306  gtest = gtest.as_system('system')
307  gmock = gmock.as_system('system')
308endif
309
310# Gather the Configuration data
311
312conf_data = configuration_data()
313conf_data.set('BMCWEB_HTTP_REQ_BODY_LIMIT_MB', get_option('http-body-limit'))
314xss_enabled = get_option('insecure-disable-xss')
315conf_data.set10('BMCWEB_INSECURE_DISABLE_XSS_PREVENTION', xss_enabled.enabled())
316enable_redfish_query = get_option('insecure-enable-redfish-query')
317conf_data.set10('BMCWEB_INSECURE_ENABLE_QUERY_PARAMS', enable_redfish_query.enabled())
318insecure_push_style_notification = get_option('insecure-push-style-notification')
319conf_data.set10('BMCWEB_INSECURE_ENABLE_HTTP_PUSH_STYLE_EVENTING', insecure_push_style_notification.enabled())
320conf_data.set('MESON_INSTALL_PREFIX', get_option('prefix'))
321conf_data.set('HTTPS_PORT', get_option('https_port'))
322configure_file(input: 'bmcweb_config.h.in',
323               output: 'bmcweb_config.h',
324               configuration: conf_data)
325
326# Configure and install systemd unit files
327
328systemd_system_unit_dir = systemd.get_variable(pkgconfig: 'systemdsystemunitdir')
329
330bindir = get_option('prefix') + '/' +get_option('bindir')
331
332summary({
333          'prefix' : get_option('prefix'),
334          'bindir' : bindir,
335          'systemd unit directory' : systemd_system_unit_dir
336        }, section : 'Directories')
337
338configure_file(input : 'bmcweb.socket.in',
339               output : 'bmcweb.socket',
340               install_dir: systemd_system_unit_dir,
341               configuration: conf_data,
342               install : true)
343
344configure_file(input : 'bmcweb.service.in',
345               output : 'bmcweb.service',
346               install_dir: systemd_system_unit_dir,
347               configuration: conf_data,
348               install : true)
349
350# Copy pam-webserver to etc/pam.d
351configure_file(input : 'pam-webserver',
352               output : 'webserver',
353               copy : true,
354               install_dir: '/etc/pam.d',
355               install : true)
356
357install_subdir('static', install_dir : 'share/www', strip_directory : true)
358
359# Source files
360
361srcfiles_bmcweb = [
362  'redfish-core/src/error_messages.cpp',
363  'redfish-core/src/utils/json_utils.cpp',
364  'src/boost_asio_ssl.cpp',
365  'src/boost_asio.cpp',
366  'src/boost_beast.cpp',
367  'src/boost_url.cpp',
368]
369
370# Generate the bmcweb executable
371executable(
372  'bmcweb',
373  srcfiles_bmcweb + ['src/webserver_main.cpp'],
374  include_directories : incdir,
375  dependencies: bmcweb_dependencies,
376  link_args: '-Wl,--gc-sections',
377  install: true,
378  install_dir:bindir
379)
380
381srcfiles_unittest = [
382  'http/ut/utility_test.cpp',
383  'http/ut/router_test.cpp',
384  'include/ut/dbus_utility_test.cpp',
385  'include/ut/http_utility_test.cpp',
386  'include/ut/human_sort_test.cpp',
387  'include/ut/multipart_test.cpp',
388  'include/ut/openbmc_dbus_rest_test.cpp',
389  'redfish-core/include/utils/query_param_test.cpp',
390  'redfish-core/lib/ut/service_root_test.cpp',
391  'redfish-core/ut/configfile_test.cpp',
392  'redfish-core/ut/hex_utils_test.cpp',
393  'redfish-core/ut/json_utils_test.cpp',
394  'redfish-core/ut/lock_test.cpp',
395  'redfish-core/ut/privileges_test.cpp',
396  'redfish-core/ut/registries_test.cpp',
397  'redfish-core/ut/stl_utils_test.cpp',
398  'redfish-core/ut/time_utils_test.cpp',
399]
400
401if(get_option('tests').enabled())
402    # generate the test executable
403    ut_bin = executable(
404      'bmcweb_unit_test',
405      srcfiles_unittest + srcfiles_bmcweb,
406      include_directories : incdir,
407      install_dir: bindir,
408      dependencies: bmcweb_dependencies + [
409        gtest,
410        gmock,
411      ]
412    )
413    test('bmcweb_unit_test', ut_bin)
414endif
415