xref: /openbmc/bmcweb/meson.build (revision 2ae81db9) 
1project('bmcweb', 'cpp',
2        version : '1.0',
3        meson_version: '>=0.63.0',
4        default_options: [
5            'b_lto_mode=default',
6            'b_lto_threads=0',
7            'b_lto=true',
8            'b_ndebug=if-release',
9            'buildtype=debugoptimized',
10            'cpp_rtti=false',
11            'cpp_std=c++20',
12            'warning_level=3',
13            'werror=true',
14           ])
15
16# Project related links
17
18project_pretty_name = 'bmcweb'
19project_url = 'https://github.com/openbmc/' + project_pretty_name
20project_issues_url = project_url + '/issues/new'
21summary('Issues',project_issues_url, section: 'Report Issues')
22
23# Validate the c++ Standard
24
25if get_option('cpp_std') != 'c++20'
26    error('This project requires c++20 support')
27endif
28
29# Get compiler and default build type
30
31cxx = meson.get_compiler('cpp')
32build = get_option('buildtype')
33optimization = get_option('optimization')
34summary('Build Type',build, section : 'Build Info')
35summary('Optimization',optimization, section : 'Build Info')
36
37
38# remove debug information for minsize buildtype
39if(get_option('buildtype') == 'minsize')
40  add_project_arguments(['-fdata-sections', '-ffunction-sections'], language : 'cpp')
41  add_project_arguments('-DNDEBUG', language : 'cpp')
42endif
43
44if(get_option('dns-resolver') == 'systemd-dbus')
45  add_project_arguments('-DBMCWEB_DBUS_DNS_RESOLVER', language : 'cpp')
46endif
47
48# Disable lto when compiling with no optimization
49if(get_option('optimization') == '0')
50  add_project_arguments('-fno-lto', language: 'cpp')
51  message('Disabling lto & its supported features as optimization is disabled')
52endif
53
54# Include Directories
55
56incdir = include_directories(
57  'include',
58  'redfish-core/include',
59  'redfish-core/lib',
60  'http'
61)
62
63# Get the options and enable the respective features
64## create a MAP of  "options : feature_flag"
65
66feature_map = {
67  'basic-auth'                                  : '-DBMCWEB_ENABLE_BASIC_AUTHENTICATION',
68  'cookie-auth'                                 : '-DBMCWEB_ENABLE_COOKIE_AUTHENTICATION',
69  'google-api'                                  : '-DBMCWEB_ENABLE_GOOGLE_API',
70  'host-serial-socket'                          : '-DBMCWEB_ENABLE_HOST_SERIAL_WEBSOCKET',
71  'ibm-management-console'                      : '-DBMCWEB_ENABLE_IBM_MANAGEMENT_CONSOLE',
72  'insecure-disable-auth'                       : '-DBMCWEB_INSECURE_DISABLE_AUTHX',
73  'insecure-disable-csrf'                       : '-DBMCWEB_INSECURE_DISABLE_CSRF_PREVENTION',
74  'insecure-disable-ssl'                        : '-DBMCWEB_INSECURE_DISABLE_SSL',
75  'insecure-push-style-notification'            : '-DBMCWEB_INSECURE_ENABLE_HTTP_PUSH_STYLE_EVENTING',
76  'insecure-tftp-update'                        : '-DBMCWEB_INSECURE_ENABLE_REDFISH_FW_TFTP_UPDATE',
77  'insecure-ignore-content-type'                : '-DBMCWEB_INSECURE_IGNORE_CONTENT_TYPE',
78  'kvm'                                         : '-DBMCWEB_ENABLE_KVM' ,
79  'mutual-tls-auth'                             : '-DBMCWEB_ENABLE_MUTUAL_TLS_AUTHENTICATION',
80  'redfish-aggregation'                         : '-DBMCWEB_ENABLE_REDFISH_AGGREGATION',
81  'redfish-allow-deprecated-power-thermal'      : '-DBMCWEB_ALLOW_DEPRECATED_POWER_THERMAL',
82  'redfish-bmc-journal'                         : '-DBMCWEB_ENABLE_REDFISH_BMC_JOURNAL',
83  'redfish-cpu-log'                             : '-DBMCWEB_ENABLE_REDFISH_CPU_LOG',
84  'redfish-dbus-log'                            : '-DBMCWEB_ENABLE_REDFISH_DBUS_LOG_ENTRIES',
85  'redfish-dump-log'                            : '-DBMCWEB_ENABLE_REDFISH_DUMP_LOG',
86  'redfish-host-logger'                         : '-DBMCWEB_ENABLE_REDFISH_HOST_LOGGER',
87  'redfish-new-powersubsystem-thermalsubsystem' : '-DBMCWEB_NEW_POWERSUBSYSTEM_THERMALSUBSYSTEM',
88  'redfish-oem-manager-fan-data'                : '-DBMCWEB_ENABLE_REDFISH_OEM_MANAGER_FAN_DATA',
89  'redfish-provisioning-feature'                : '-DBMCWEB_ENABLE_REDFISH_PROVISIONING_FEATURE',
90  'redfish'                                     : '-DBMCWEB_ENABLE_REDFISH',
91  'rest'                                        : '-DBMCWEB_ENABLE_DBUS_REST',
92  'session-auth'                                : '-DBMCWEB_ENABLE_SESSION_AUTHENTICATION',
93  'static-hosting'                              : '-DBMCWEB_ENABLE_STATIC_HOSTING',
94  'experimental-redfish-multi-computer-system'  : '-DBMCWEB_ENABLE_MULTI_COMPUTERSYSTEM',
95  'vm-websocket'                                : '-DBMCWEB_ENABLE_VM_WEBSOCKET',
96  'xtoken-auth'                                 : '-DBMCWEB_ENABLE_XTOKEN_AUTHENTICATION',
97  #'vm-nbdproxy'                                : '-DBMCWEB_ENABLE_VM_NBDPROXY',
98}
99
100# Get the options status and build a project summary to show which flags are
101# being enabled during the configuration time.
102
103foreach option_key,option_value : feature_map
104  if(get_option(option_key).allowed())
105    if(option_key == 'mutual-tls-auth' or option_key == 'insecure-disable-ssl')
106      if(get_option('insecure-disable-ssl').disabled() or get_option('mutual-tls-auth').disabled())
107        add_project_arguments(option_value,language:'cpp')
108        summary(option_key,option_value, section : 'Enabled Features')
109      endif
110    elif (option_key in ['basic-auth', 'cookie-auth', 'session-auth', 'xtoken-auth', 'mutual-tls-auth'])
111      if (get_option('insecure-disable-auth').disabled())
112        add_project_arguments(option_value, language:'cpp')
113        summary(option_key,option_value, section : 'Enabled Features')
114      endif
115    else
116      summary(option_key,option_value, section : 'Enabled Features')
117      add_project_arguments(option_value,language:'cpp')
118    endif
119  else
120      if(option_key == 'insecure-disable-ssl')
121        summary('ssl','-DBMCWEB_ENABLE_SSL', section : 'Enabled Features')
122        add_project_arguments('-DBMCWEB_ENABLE_SSL', language : 'cpp')
123      endif
124  endif
125endforeach
126
127if(get_option('tests').allowed())
128  summary('unittest','NA', section : 'Enabled Features')
129endif
130
131# Add compiler arguments
132
133# -Wpedantic, -Wextra comes by default with warning level
134add_project_arguments(
135  cxx.get_supported_arguments([
136  '-Wcast-align',
137  '-Wconversion',
138  '-Wformat=2',
139  '-Woverloaded-virtual',
140  '-Wsign-conversion',
141  '-Wunused',
142  '-Wno-attributes',
143  ]),
144  language: 'cpp'
145)
146
147if (cxx.get_id() == 'clang' and cxx.version().version_compare('>9.0'))
148add_project_arguments(
149  cxx.get_supported_arguments([
150    '-Weverything',
151    '-Wno-c++98-compat-pedantic',
152    '-Wno-c++98-compat',
153    '-Wno-documentation-unknown-command',
154    '-Wno-documentation',
155    '-Wno-exit-time-destructors',
156    '-Wno-global-constructors',
157    '-Wno-newline-eof',
158    '-Wno-padded',
159    '-Wno-shadow',
160    '-Wno-used-but-marked-unused',
161    '-Wno-weak-vtables',
162    '-Wno-switch-enum',
163    '-Wno-unused-macros',
164  ]),
165  language:'cpp')
166endif
167
168# if compiler is gnu-gcc , and version is > 8.0 then we add few more
169# compiler arguments , we know that will pass
170
171if (cxx.get_id() == 'gcc' and cxx.version().version_compare('>8.0'))
172  add_project_arguments(
173    cxx.get_supported_arguments([
174     '-Wduplicated-cond',
175     '-Wduplicated-branches',
176     '-Wlogical-op',
177     '-Wnull-dereference',
178     '-Wunused-parameter',
179     '-Wdouble-promotion',
180     '-Wshadow',
181     '-Wno-psabi',
182     ]),
183    language:'cpp')
184endif
185
186if (get_option('buildtype') != 'plain')
187  if (get_option('b_lto') == true and get_option('optimization')!='0')
188    # Reduce the binary size by removing unnecessary
189    # dynamic symbol table entries
190
191    add_project_arguments(
192     cxx.get_supported_arguments([
193     '-fno-fat-lto-objects',
194     '-fvisibility=hidden',
195     '-fvisibility-inlines-hidden'
196     ]),
197     language: 'cpp')
198
199    if cxx.has_link_argument('-Wl,--exclude-libs,ALL')
200      add_project_link_arguments('-Wl,--exclude-libs,ALL', language: 'cpp')
201    endif
202  endif
203endif
204
205if( get_option('bmcweb-logging') != 'disabled' or \
206    get_option('buildtype').startswith('debug'))
207 add_project_arguments([
208   '-DBMCWEB_ENABLE_DEBUG'
209   ],
210  language : 'cpp')
211
212  summary('debug', '-DBMCWEB_ENABLE_DEBUG', section : 'Enabled Features')
213endif
214
215# Set Compiler Security flags
216
217security_flags = [
218  '-fstack-protector-strong',
219  '-fPIE',
220  '-fPIC',
221  '-D_FORTIFY_SOURCE=2',
222  '-Wformat',
223  '-Wformat-security'
224]
225
226## Add security flags for builds of type 'release','debugoptimized' and 'minsize'
227
228if not (get_option('buildtype') == 'plain' or get_option('buildtype').startswith('debug'))
229  add_project_arguments(
230   cxx.get_supported_arguments([
231    security_flags
232  ]),
233  language: 'cpp')
234endif
235
236# Boost dependency configuration
237
238add_project_arguments(
239cxx.get_supported_arguments([
240  '-DBOOST_ASIO_DISABLE_CONCEPTS',
241  '-DBOOST_ALL_NO_LIB',
242  '-DBOOST_ALLOW_DEPRECATED_HEADERS',
243  '-DBOOST_ASIO_DISABLE_THREADS',
244  '-DBOOST_ASIO_NO_DEPRECATED',
245  '-DBOOST_ASIO_SEPARATE_COMPILATION',
246  '-DBOOST_BEAST_SEPARATE_COMPILATION',
247  '-DBOOST_EXCEPTION_DISABLE',
248  '-DBOOST_NO_EXCEPTIONS',
249  '-DBOOST_URL_NO_SOURCE_LOCATION',
250  '-DJSON_NOEXCEPTION',
251  '-DOPENSSL_NO_FILENAMES',
252  '-DSDBUSPLUS_DISABLE_BOOST_COROUTINES',
253]),
254language : 'cpp')
255
256# Find the dependency modules, if not found use meson wrap to get them
257# automatically during the configure step
258bmcweb_dependencies = []
259
260pam = cxx.find_library('pam', required: true)
261atomic =  cxx.find_library('atomic', required: true)
262bmcweb_dependencies += [pam, atomic]
263
264openssl = dependency('openssl', required : false, version: '>=3.0.0')
265if not openssl.found() or get_option('b_sanitize') != 'none'
266  openssl_proj = subproject(
267    'openssl',
268    required: true,
269    default_options: ['warning_level=0', 'werror=false']
270  )
271  openssl = openssl_proj.get_variable('openssl_dep')
272  openssl = openssl.as_system('system')
273else
274  # When we build openssl as a subproject, the warnings analyzer starts
275  # flagging all the C macros as old style casts, so only enable the
276  # warning for non subprojects.
277  add_project_arguments('-Wold-style-cast', language: 'cpp')
278endif
279bmcweb_dependencies += [openssl]
280
281nghttp2 = dependency('libnghttp2', version: '>=1.52.0', required : false)
282if not nghttp2.found()
283  cmake = import('cmake')
284  opt_var = cmake.subproject_options()
285  opt_var.add_cmake_defines({
286    'ENABLE_LIB_ONLY': true,
287    'ENABLE_STATIC_LIB': true
288  })
289  nghttp2_ex = cmake.subproject('nghttp2', options: opt_var)
290  nghttp2 = nghttp2_ex.dependency('nghttp2')
291endif
292bmcweb_dependencies += nghttp2
293
294sdbusplus = dependency('sdbusplus', required : false, include_type: 'system')
295if not sdbusplus.found()
296  sdbusplus_proj = subproject('sdbusplus', required: true)
297  sdbusplus = sdbusplus_proj.get_variable('sdbusplus_dep')
298  sdbusplus = sdbusplus.as_system('system')
299endif
300bmcweb_dependencies += sdbusplus
301
302tinyxml = dependency(
303    'tinyxml2',
304    include_type: 'system',
305    version: '>=9.0.0',
306)
307if not tinyxml.found()
308    tinyxml_proj = subproject('tinyxml2', required: true)
309    tinyxml = tinyxml_proj.get_variable('tinyxml_dep')
310    tinyxml = tinyxml.as_system('system')
311endif
312bmcweb_dependencies += tinyxml
313
314systemd = dependency('systemd')
315zlib = dependency('zlib')
316bmcweb_dependencies += [systemd, zlib]
317
318nlohmann_json_dep = dependency('nlohmann_json', version: '>=3.11.2', include_type: 'system')
319bmcweb_dependencies += nlohmann_json_dep
320
321boost = dependency(
322  'boost',
323  modules: [
324    'url',
325    ],
326  version : '>=1.83.0',
327  required : false,
328  include_type: 'system'
329)
330if boost.found()
331  bmcweb_dependencies += [boost]
332else
333  cmake = import('cmake')
334  opt = cmake.subproject_options()
335  opt.add_cmake_defines({
336    'BOOST_INCLUDE_LIBRARIES': 'asio;beast;callable_traits;headers;process;type_index;url;uuid'
337  })
338  boost = cmake.subproject('boost', required: true, options: opt)
339  boost_asio = boost.dependency('boost_asio').as_system()
340  boost_beast = boost.dependency('boost_beast').as_system()
341  boost_callable_traits = boost.dependency('boost_callable_traits').as_system()
342  boost_headers = boost.dependency('boost_headers').as_system()
343  boost_process = boost.dependency('boost_process').as_system()
344  boost_type_index = boost.dependency('boost_type_index').as_system()
345  boost_url = boost.dependency('boost_url').as_system()
346  boost_uuid = boost.dependency('boost_uuid').as_system()
347  bmcweb_dependencies += [
348    boost_asio,
349    boost_beast,
350    boost_callable_traits,
351    boost_headers,
352    boost_process,
353    boost_type_index,
354    boost_url,
355    boost_uuid
356  ]
357endif
358
359if get_option('tests').allowed()
360  gtest = dependency('gtest', main: true, disabler: true, required : false)
361  gmock = dependency('gmock', required : false)
362  if not gtest.found() and get_option('tests').allowed()
363    gtest_proj = subproject('gtest', required: true)
364    gtest = gtest_proj.get_variable('gtest_main_dep')
365    gmock = gtest_proj.get_variable('gmock_dep')
366  endif
367  gtest = gtest.as_system('system')
368  gmock = gmock.as_system('system')
369endif
370
371systemd_system_unit_dir = systemd.get_variable('systemdsystemunitdir')
372
373bindir = get_option('prefix') + '/' +get_option('bindir')
374
375summary({
376          'prefix' : get_option('prefix'),
377          'bindir' : bindir,
378          'systemd unit directory' : systemd_system_unit_dir
379        }, section : 'Directories')
380
381install_subdir('static', install_dir : 'share/www', strip_directory : true)
382
383# Config subdirectory
384
385subdir('config')
386bmcweb_dependencies += conf_h_dep
387
388# Source files
389fs = import('fs')
390
391srcfiles_bmcweb = files(
392  'redfish-core/src/error_messages.cpp',
393  'redfish-core/src/registries.cpp',
394  'redfish-core/src/utils/time_utils.cpp',
395  'redfish-core/src/utils/json_utils.cpp',
396  'src/boost_asio_ssl.cpp',
397  'src/boost_asio.cpp',
398  'src/boost_beast.cpp',
399  'src/dbus_singleton.cpp',
400  'src/json_html_serializer.cpp',
401  'src/ossl_random.cpp',
402)
403
404bmcweblib = static_library(
405  'bmcweblib',
406  srcfiles_bmcweb,
407  include_directories : incdir,
408  dependencies: bmcweb_dependencies,
409)
410
411# Generate the bmcweb executable
412executable(
413  'bmcweb',
414  'src/webserver_main.cpp',
415  include_directories : incdir,
416  dependencies: bmcweb_dependencies,
417  link_with: bmcweblib,
418  link_args: '-Wl,--gc-sections',
419  install: true,
420  install_dir:bindir
421)
422
423srcfiles_unittest = files(
424  'test/http/crow_getroutes_test.cpp',
425  'test/http/http_connection_test.cpp',
426  'test/http/mutual_tls.cpp',
427  'test/http/router_test.cpp',
428  'test/http/http_response_test.cpp',
429  'test/http/utility_test.cpp',
430  'test/http/verb_test.cpp',
431  'test/http/mutual_tls_meta.cpp',
432  'test/include/dbus_utility_test.cpp',
433  'test/include/google/google_service_root_test.cpp',
434  'test/include/json_html_serializer.cpp',
435  'test/include/http_utility_test.cpp',
436  'test/include/human_sort_test.cpp',
437  'test/include/async_resolve_test.cpp',
438  'test/include/credential_pipe_test.cpp',
439  'test/include/ibm/configfile_test.cpp',
440  'test/include/ibm/lock_test.cpp',
441  'test/include/multipart_test.cpp',
442  'test/include/openbmc_dbus_rest_test.cpp',
443  'test/include/str_utility_test.cpp',
444  'test/include/ossl_random.cpp',
445  'test/redfish-core/include/privileges_test.cpp',
446  'test/redfish-core/include/redfish_aggregator_test.cpp',
447  'test/redfish-core/include/registries_test.cpp',
448  'test/redfish-core/include/utils/hex_utils_test.cpp',
449  'test/redfish-core/include/utils/ip_utils_test.cpp',
450  'test/redfish-core/include/utils/json_utils_test.cpp',
451  'test/redfish-core/include/utils/query_param_test.cpp',
452  'test/redfish-core/include/utils/stl_utils_test.cpp',
453  'test/redfish-core/include/utils/time_utils_test.cpp',
454  'test/redfish-core/lib/chassis_test.cpp',
455  'test/redfish-core/lib/sensors_test.cpp',
456  'test/redfish-core/lib/log_services_dump_test.cpp',
457  'test/redfish-core/lib/log_services_test.cpp',
458  'test/redfish-core/lib/update_service_test.cpp',
459  'test/redfish-core/lib/service_root_test.cpp',
460  'test/redfish-core/lib/thermal_subsystem_test.cpp',
461  'test/redfish-core/lib/power_subsystem_test.cpp',
462)
463
464
465if(get_option('tests').allowed())
466    # generate the test executable
467    foreach test_src : srcfiles_unittest
468      test_bin = executable(
469        fs.stem(test_src),
470        test_src,
471        link_with: bmcweblib,
472        include_directories : incdir,
473        install_dir: bindir,
474        dependencies: bmcweb_dependencies + [
475          gtest,
476          gmock,
477        ]
478      )
479      test(fs.stem(test_src), test_bin)
480    endforeach
481endif
482