xref: /openbmc/bios-settings-mgr/meson.build (revision d37ce23a) 
1project(
2    'biosconfig-manager',
3    'cpp',
4    meson_version: '>=1.1.1',
5    default_options: [
6        'warning_level=3',
7        'werror=true',
8        'cpp_std=c++23',
9        'buildtype=debugoptimized'
10    ],
11    license: 'Apache-2.0',
12    version: '1.0',
13)
14
15# Wno-psabi reduces the number of "Note:" messages when cross-compiling some STL
16# stuff for ARM. See https://stackoverflow.com/questions/48149323/strange-gcc-warning-when-compiling-qt-project
17# Basically, gcc 6 and gcc 7 are not ABI compatible, but since the whole OpenBMC
18# project uses the same compiler, we can safely ignmore these info notes.
19add_project_arguments('-Wno-psabi', language: 'cpp')
20
21conf_data = configuration_data()
22conf_data.set_quoted('BIOS_PERSIST_PATH', get_option('bios-persist-path'))
23configure_file(output: 'config.h', configuration: conf_data)
24
25boost_args = ['-DBOOST_ALL_NO_LIB',
26              '-DBOOST_ASIO_DISABLE_THREADS',
27              '-DBOOST_ERROR_CODE_HEADER_ONLY',
28              '-DBOOST_NO_RTTI',
29              '-DBOOST_NO_TYPEID',
30              '-DBOOST_SYSTEM_NO_DEPRECATED']
31
32deps = [dependency('boost'),
33        dependency('phosphor-dbus-interfaces'),
34        dependency('phosphor-logging'),
35        dependency('sdbusplus'),
36        dependency('libsystemd'),
37        dependency('openssl'),
38        dependency('nlohmann_json',include_type: 'system'),
39]
40
41cereal = dependency('cereal', required: false)
42cpp = meson.get_compiler('cpp')
43has_cereal = cpp.has_header_symbol(
44    'cereal/cereal.hpp',
45    'cereal::specialize',
46    dependencies: cereal,
47    required: false)
48if not has_cereal
49    cereal_opts = import('cmake').subproject_options()
50    cereal_opts.add_cmake_defines({'BUILD_TESTS': 'OFF'})
51    cereal_proj = import('cmake').subproject(
52        'cereal',
53        options: cereal_opts,
54        required: false)
55    assert(cereal_proj.found(), 'cereal is required')
56    cereal = cereal_proj.dependency('cereal')
57endif
58deps += cereal
59
60src_files = ['src/main.cpp',
61             'src/manager.cpp',
62             'src/manager_serialize.cpp',
63             'src/password.cpp'
64]
65
66executable('biosconfig-manager',
67           src_files,
68           implicit_include_directories: true,
69           include_directories: ['include'],
70           dependencies: deps,
71           cpp_args : boost_args,
72           install: true,
73           install_dir: get_option('bindir'))
74
75systemd = dependency('systemd')
76systemd_system_unit_dir = systemd.get_variable(
77    'systemdsystemunitdir',
78    pkgconfig_define: ['prefix', get_option('prefix')])
79
80fs = import('fs')
81fs.copyfile(
82    'service_files/xyz.openbmc_project.biosconfig_manager.service',
83    install: true,
84    install_dir: systemd_system_unit_dir
85)
86