xref: /openbmc/telemetry/meson.build (revision e6d4887453f0b23b46c012da7cb26f2beb38ef0e) 
1project(
2    'Telemetry',
3    'cpp',
4    meson_version: '>=0.57.0',
5    default_options: [
6        'buildtype=debugoptimized',
7        'cpp_std=c++20',
8        # TODO: Without RTTI telemetry does not build using Boost 1.74.0
9        # https://github.com/chriskohlhoff/asio/issues/533
10        #'cpp_rtti=false',
11        'warning_level=3',
12        'werror=true',
13        'b_lto=true',
14    ],
15    license: 'Apache-2.0',
16)
17
18summary({'Fast build with link-time optimizer disabled':
19            not get_option('b_lto')}, section: 'General')
20
21cpp = meson.get_compiler('cpp')
22add_project_arguments(
23    cpp.get_supported_arguments([
24        '-DBOOST_ASIO_DISABLE_THREADS',
25        '-DBOOST_ALL_NO_LIB',
26        '-DBOOST_SYSTEM_NO_DEPRECATED',
27        '-DBOOST_ASIO_NO_DEPRECATED',
28        '-DBOOST_NO_RTTI',
29        '-DBOOST_NO_TYPEID',
30        # TODO: Removed below arg after upgrade to Boost 1.75
31        '-DBOOST_ALLOW_DEPRECATED_HEADERS',
32        '-Wno-unused-parameter',
33    ]),
34    language: 'cpp'
35)
36
37boost = dependency(
38    'boost',
39    version: '>=1.74.0',
40    required: false,
41    modules: ['coroutine'])
42assert(boost.found(),
43       'Missing Boost 1.74.0 or higher, as WA you can set BOOST_ROOT ' +
44       'environemt to point at boost build. To build a boost you can use ' +
45       'script ./scripts/boost_build_1.74.0.sh')
46
47phosphor_logging = dependency(
48    'phosphor-logging',
49    fallback: ['phosphor-logging', 'phosphor_logging_dep'],
50)
51
52sdbusplus = dependency('sdbusplus', fallback: ['sdbusplus', 'sdbusplus_dep'])
53systemd = dependency('systemd')
54
55if cpp.has_header('nlohmann/json.hpp')
56    nlohmann_json = declare_dependency()
57else
58    nlohmann_json = dependency('nlohmann_json',
59                               fallback: ['nlohmann', 'nlohmann_json_dep'])
60endif
61
62add_project_arguments(
63    '-DTELEMETRY_MAX_REPORTS=' + get_option('max-reports').to_string(),
64    '-DTELEMETRY_MAX_READING_PARAMS=' +
65        get_option('max-reading-parameters').to_string(),
66    '-DTELEMETRY_MIN_INTERVAL=' + get_option('min-interval').to_string(),
67    '-DTELEMETRY_MAX_TRIGGERS=' + get_option('max-triggers').to_string(),
68    '-DTELEMETRY_MAX_DBUS_PATH_LENGTH=' +
69        get_option('max-dbus-path-length').to_string(),
70    '-DTELEMETRY_MAX_APPEND_LIMIT=' +
71        get_option('max-append-limit').to_string(),
72    language: 'cpp'
73)
74
75executable(
76    'telemetry',
77    [
78        'src/details/collection_function.cpp',
79        'src/discrete_threshold.cpp',
80        'src/main.cpp',
81        'src/metric.cpp',
82        'src/numeric_threshold.cpp',
83        'src/on_change_threshold.cpp',
84        'src/persistent_json_storage.cpp',
85        'src/report.cpp',
86        'src/report_factory.cpp',
87        'src/report_manager.cpp',
88        'src/sensor.cpp',
89        'src/sensor_cache.cpp',
90        'src/trigger.cpp',
91        'src/trigger_actions.cpp',
92        'src/trigger_factory.cpp',
93        'src/trigger_manager.cpp',
94        'src/types/report_types.cpp',
95        'src/utils/conversion_trigger.cpp',
96        'src/utils/generate_id.cpp',
97        'src/utils/messanger_service.cpp',
98    ],
99    dependencies: [
100        boost,
101        nlohmann_json,
102        sdbusplus,
103        phosphor_logging,
104    ],
105    include_directories: 'src',
106    install: true,
107    install_dir: get_option('prefix') / get_option('bindir'),
108    pie: true,
109)
110
111configure_file(
112    input: 'xyz.openbmc_project.Telemetry.service.in',
113    output: 'xyz.openbmc_project.Telemetry.service',
114    configuration: {
115        'bindir': get_option('prefix') / get_option('bindir'),
116    },
117    install: true,
118    install_dir: systemd.get_variable(pkgconfig: 'systemdsystemunitdir'),
119)
120
121if get_option('buildtest')
122    subdir('tests')
123endif
124