xref: /openbmc/qemu/hw/display/meson.build (revision 9022e80a4235f272799720ee4e9037f6dae7cf0e) 
1hw_display_modules = {}
2
3system_ss.add(when: 'CONFIG_DDC', if_true: files('i2c-ddc.c'))
4system_ss.add(when: 'CONFIG_EDID', if_true: files('edid-generate.c', 'edid-region.c'))
5
6system_ss.add(when: 'CONFIG_FW_CFG_DMA', if_true: files('ramfb.c'), if_false: files('ramfb-stubs.c'))
7system_ss.add(when: 'CONFIG_FW_CFG_DMA', if_true: files('ramfb-standalone.c'))
8
9system_ss.add(when: 'CONFIG_VGA_CIRRUS', if_true: files('cirrus_vga.c'))
10system_ss.add(when: ['CONFIG_VGA_CIRRUS', 'CONFIG_VGA_ISA'], if_true: files('cirrus_vga_isa.c'))
11system_ss.add(when: 'CONFIG_G364FB', if_true: files('g364fb.c'))
12system_ss.add(when: 'CONFIG_JAZZ_LED', if_true: files('jazz_led.c'))
13system_ss.add(when: 'CONFIG_PL110', if_true: files('pl110.c'))
14system_ss.add(when: 'CONFIG_SII9022', if_true: files('sii9022.c'))
15system_ss.add(when: 'CONFIG_SSD0303', if_true: files('ssd0303.c'))
16system_ss.add(when: 'CONFIG_SSD0323', if_true: files('ssd0323.c'))
17system_ss.add(when: 'CONFIG_XEN_BUS', if_true: files('xenfb.c'))
18
19system_ss.add(when: 'CONFIG_VGA_PCI', if_true: files('vga-pci.c'))
20system_ss.add(when: 'CONFIG_VGA_ISA', if_true: files('vga-isa.c'))
21system_ss.add(when: 'CONFIG_VGA_MMIO', if_true: files('vga-mmio.c'))
22system_ss.add(when: 'CONFIG_VMWARE_VGA', if_true: files('vmware_vga.c'))
23system_ss.add(when: 'CONFIG_BOCHS_DISPLAY', if_true: files('bochs-display.c'))
24
25system_ss.add(when: 'CONFIG_BLIZZARD', if_true: files('blizzard.c'))
26system_ss.add(when: 'CONFIG_EXYNOS4', if_true: files('exynos4210_fimd.c'))
27system_ss.add(when: 'CONFIG_FRAMEBUFFER', if_true: files('framebuffer.c'))
28
29system_ss.add(when: 'CONFIG_OMAP', if_true: files('omap_dss.c'))
30system_ss.add(when: 'CONFIG_RASPI', if_true: files('bcm2835_fb.c'))
31system_ss.add(when: 'CONFIG_SM501', if_true: files('sm501.c'))
32system_ss.add(when: 'CONFIG_TCX', if_true: files('tcx.c'))
33system_ss.add(when: 'CONFIG_CG3', if_true: files('cg3.c'))
34system_ss.add(when: 'CONFIG_MACFB', if_true: files('macfb.c'))
35system_ss.add(when: 'CONFIG_NEXTCUBE', if_true: files('next-fb.c'))
36
37system_ss.add(when: 'CONFIG_VGA', if_true: files('vga.c'))
38system_ss.add(when: 'CONFIG_VIRTIO', if_true: files('virtio-dmabuf.c'))
39system_ss.add(when: 'CONFIG_DM163', if_true: files('dm163.c'))
40
41if (config_all_devices.has_key('CONFIG_VGA_CIRRUS') or
42    config_all_devices.has_key('CONFIG_VGA_PCI') or
43    config_all_devices.has_key('CONFIG_VMWARE_VGA') or
44    config_all_devices.has_key('CONFIG_ATI_VGA')
45   )
46  system_ss.add(when: 'CONFIG_ACPI', if_true: files('acpi-vga.c'),
47                                      if_false: files('acpi-vga-stub.c'))
48endif
49
50if config_all_devices.has_key('CONFIG_QXL')
51  qxl_ss = ss.source_set()
52  qxl_ss.add(when: 'CONFIG_QXL', if_true: [files('qxl.c', 'qxl-logger.c', 'qxl-render.c'),
53                                           pixman, spice])
54  qxl_ss.add(when: 'CONFIG_ACPI', if_true: files('acpi-vga.c'),
55                                  if_false: files('acpi-vga-stub.c'))
56  hw_display_modules += {'qxl': qxl_ss}
57endif
58
59system_ss.add(when: 'CONFIG_DPCD', if_true: files('dpcd.c'))
60system_ss.add(when: 'CONFIG_XLNX_DISPLAYPORT', if_true: files('xlnx_dp.c'))
61
62system_ss.add(when: 'CONFIG_ARTIST', if_true: files('artist.c'))
63
64system_ss.add(when: 'CONFIG_ATI_VGA', if_true: [files('ati.c', 'ati_2d.c', 'ati_dbg.c'), pixman])
65
66
67if config_all_devices.has_key('CONFIG_VIRTIO_GPU')
68  virtio_gpu_ss = ss.source_set()
69  virtio_gpu_ss.add(when: 'CONFIG_VIRTIO_GPU',
70                    if_true: [files('virtio-gpu-base.c', 'virtio-gpu.c'), pixman])
71  if host_os == 'linux'
72    virtio_gpu_ss.add(files('virtio-gpu-udmabuf.c'))
73  else
74    virtio_gpu_ss.add(files('virtio-gpu-udmabuf-stubs.c'))
75  endif
76  virtio_gpu_ss.add(when: 'CONFIG_VHOST_USER_GPU', if_true: files('vhost-user-gpu.c'))
77  hw_display_modules += {'virtio-gpu': virtio_gpu_ss}
78
79  if virgl.found() and opengl.found()
80    virtio_gpu_gl_ss = ss.source_set()
81    virtio_gpu_gl_ss.add(when: ['CONFIG_VIRTIO_GPU', virgl, opengl],
82                         if_true: [files('virtio-gpu-gl.c', 'virtio-gpu-virgl.c'), pixman, virgl])
83    hw_display_modules += {'virtio-gpu-gl': virtio_gpu_gl_ss}
84  endif
85
86  if rutabaga.found()
87    virtio_gpu_rutabaga_ss = ss.source_set()
88    virtio_gpu_rutabaga_ss.add(when: ['CONFIG_VIRTIO_GPU', rutabaga],
89                               if_true: [files('virtio-gpu-rutabaga.c'), pixman])
90    hw_display_modules += {'virtio-gpu-rutabaga': virtio_gpu_rutabaga_ss}
91  endif
92endif
93
94if config_all_devices.has_key('CONFIG_VIRTIO_PCI')
95  virtio_gpu_pci_ss = ss.source_set()
96  virtio_gpu_pci_ss.add(when: ['CONFIG_VIRTIO_GPU', 'CONFIG_VIRTIO_PCI'],
97                        if_true: [files('virtio-gpu-pci.c'), pixman])
98  virtio_gpu_pci_ss.add(when: ['CONFIG_VHOST_USER_GPU', 'CONFIG_VIRTIO_PCI'],
99                        if_true: files('vhost-user-gpu-pci.c'))
100  hw_display_modules += {'virtio-gpu-pci': virtio_gpu_pci_ss}
101
102  if virgl.found() and opengl.found()
103    virtio_gpu_pci_gl_ss = ss.source_set()
104    virtio_gpu_pci_gl_ss.add(when: ['CONFIG_VIRTIO_GPU', 'CONFIG_VIRTIO_PCI', virgl, opengl],
105                             if_true: [files('virtio-gpu-pci-gl.c'), pixman])
106    hw_display_modules += {'virtio-gpu-pci-gl': virtio_gpu_pci_gl_ss}
107  endif
108  if rutabaga.found()
109    virtio_gpu_pci_rutabaga_ss = ss.source_set()
110    virtio_gpu_pci_rutabaga_ss.add(when: ['CONFIG_VIRTIO_GPU', 'CONFIG_VIRTIO_PCI', rutabaga],
111                                   if_true: [files('virtio-gpu-pci-rutabaga.c'), pixman])
112    hw_display_modules += {'virtio-gpu-pci-rutabaga': virtio_gpu_pci_rutabaga_ss}
113  endif
114endif
115
116if config_all_devices.has_key('CONFIG_VIRTIO_VGA')
117  virtio_vga_ss = ss.source_set()
118  virtio_vga_ss.add(when: 'CONFIG_VIRTIO_VGA',
119                    if_true: [files('virtio-vga.c'), pixman])
120  virtio_vga_ss.add(when: 'CONFIG_VHOST_USER_VGA',
121                    if_true: files('vhost-user-vga.c'))
122  virtio_vga_ss.add(when: 'CONFIG_ACPI', if_true: files('acpi-vga.c'),
123                                         if_false: files('acpi-vga-stub.c'))
124  hw_display_modules += {'virtio-vga': virtio_vga_ss}
125
126  if virgl.found() and opengl.found()
127    virtio_vga_gl_ss = ss.source_set()
128    virtio_vga_gl_ss.add(when: ['CONFIG_VIRTIO_VGA', virgl, opengl],
129                         if_true: [files('virtio-vga-gl.c'), pixman])
130    virtio_vga_gl_ss.add(when: 'CONFIG_ACPI', if_true: files('acpi-vga.c'),
131                                              if_false: files('acpi-vga-stub.c'))
132    hw_display_modules += {'virtio-vga-gl': virtio_vga_gl_ss}
133  endif
134
135  if rutabaga.found()
136    virtio_vga_rutabaga_ss = ss.source_set()
137    virtio_vga_rutabaga_ss.add(when: ['CONFIG_VIRTIO_VGA', rutabaga],
138                               if_true: [files('virtio-vga-rutabaga.c'), pixman])
139    virtio_vga_rutabaga_ss.add(when: 'CONFIG_ACPI', if_true: files('acpi-vga.c'),
140                                                    if_false: files('acpi-vga-stub.c'))
141    hw_display_modules += {'virtio-vga-rutabaga': virtio_vga_rutabaga_ss}
142  endif
143endif
144
145system_ss.add(when: 'CONFIG_OMAP', if_true: files('omap_lcdc.c'))
146
147modules += { 'hw-display': hw_display_modules }
148