xref: /openbmc/phosphor-power/meson.build (revision 48781aef031d0fcf7d947ceea1848b9dd1047485) 
1project(
2    'phosphor-power',
3    'cpp',
4    default_options: [
5        'warning_level=3',
6        'werror=true',
7        'cpp_std=c++20',
8        'buildtype=debugoptimized',
9        'prefix=/usr'
10    ],
11    license: 'Apache-2.0',
12    version: '1.0',
13    meson_version: '>=0.58.0',
14)
15
16build_tests = get_option('tests')
17
18if get_option('oe-sdk').enabled()
19  # Setup OE SYSROOT
20  OECORE_TARGET_SYSROOT = run_command('sh', '-c', 'echo $OECORE_TARGET_SYSROOT').stdout().strip()
21  if OECORE_TARGET_SYSROOT == ''
22    error('Unable to get $OECORE_TARGET_SYSROOT, check your environment.')
23  endif
24  message('OE_SYSROOT: ' + OECORE_TARGET_SYSROOT)
25  rpath = ':'.join([OECORE_TARGET_SYSROOT + '/lib', OECORE_TARGET_SYSROOT + '/usr/lib'])
26  ld_so = run_command('sh', '-c', 'find ' + OECORE_TARGET_SYSROOT + '/lib/ld-*.so | sort -r -n | head -n1').stdout().strip()
27  dynamic_linker = ['-Wl,-dynamic-linker,' + ld_so]
28else
29  dynamic_linker = []
30endif
31
32
33cppfs = meson.get_compiler('cpp').find_library('stdc++fs')
34gmock = dependency('gmock', disabler: true, required: build_tests)
35gtest = dependency('gtest', main: true, disabler: true, required: build_tests)
36phosphor_dbus_interfaces = dependency('phosphor-dbus-interfaces')
37phosphor_logging = dependency('phosphor-logging')
38prog_python = import('python').find_installation('python3')
39sdbusplus = dependency('sdbusplus')
40sdbuspp = find_program('sdbus++')
41sdeventplus = dependency('sdeventplus')
42pthread = dependency('threads')
43stdplus = dependency('stdplus')
44boost = dependency('boost')
45fmt = dependency('fmt')
46libgpiodcxx = dependency('libgpiodcxx')
47
48systemd = dependency('systemd')
49servicedir = systemd.get_variable('systemdsystemunitdir')
50
51services = [
52    ['supply-monitor', 'power-supply-monitor@.service'],
53    ['sequencer-monitor', 'pseq-monitor-pgood.service'],
54    ['sequencer-monitor', 'pseq-monitor.service'],
55    ['supply-monitor-ng', 'phosphor-psu-monitor.service'],
56    ['regulators', 'phosphor-regulators.service'],
57    ['regulators', 'phosphor-regulators-config.service'],
58    ['regulators', 'phosphor-regulators-monitor-enable.service'],
59    ['regulators', 'phosphor-regulators-monitor-disable.service'],
60    ['power-control', 'phosphor-power-control.service'],
61]
62
63foreach service : services
64    if get_option(service[0])
65        configure_file(input: 'services/' + service[1],
66                 output: service[1],
67                 copy: true,
68                 install_dir: servicedir)
69    endif
70endforeach
71
72# Get the power sequencer class name
73sequencer = get_option('power_sequencer')
74if sequencer == 'ucd90160'
75    sequencer_class = 'UCD90160'
76elif sequencer == 'mihawk-cpld'
77    sequencer_class = 'MihawkCPLD'
78else
79    # power sequencer is incorrect
80    error('power sequencer is incorrect')
81endif
82
83conf = configuration_data()
84conf.set_quoted(
85    'INPUT_HISTORY_BUSNAME_ROOT', get_option('input-history-busname-root'))
86conf.set_quoted(
87    'INPUT_HISTORY_SENSOR_ROOT', get_option('input-history-sensor-root'))
88conf.set_quoted(
89    'INPUT_HISTORY_SYNC_GPIO', get_option('input-history-sync-gpio'))
90conf.set_quoted(
91    'PSU_JSON_PATH', '/usr/share/phosphor-power/psu.json')
92conf.set(
93    'SEQUENCER', sequencer_class)
94conf.set10(
95    'DEVICE_ACCESS', get_option('device-access'))
96conf.set10('IBM_VPD', get_option('ibm-vpd'))
97
98configure_file(output: 'config.h', configuration: conf)
99
100# Ensure the generated header here winds up in the correct path in the build
101# tree such that it actually get used and doesn't get found in the sysroot
102# somewhere.  Meson doesn't allow path elements (rightfully so) when specifying
103# the output filename of a target definition so the target must be defined in
104# the directory where the artifacts need to be placed.  Do that now, because
105# the generated source (cpp) is needed to define the library target.
106subdir('org/open_power/Witherspoon/Fault')
107
108libpower = static_library(
109    'power',
110    error_cpp,
111    error_hpp,
112    'gpio.cpp',
113    'pmbus.cpp',
114    'utility.cpp',
115    dependencies: [
116        cppfs,
117        phosphor_dbus_interfaces,
118        phosphor_logging,
119        sdbusplus,
120        sdeventplus,
121    ],
122)
123
124libpower_inc = include_directories('.')
125
126# Build the tools/i2c sub-directory first.  Other sub-directories depend on
127# Meson variables defined there.
128subdir('tools/i2c')
129
130if get_option('regulators')
131    subdir('phosphor-regulators')
132endif
133if get_option('sequencer-monitor')
134    subdir('power-sequencer')
135endif
136if get_option('power-control')
137    subdir('phosphor-power-sequencer')
138endif
139if get_option('supply-monitor')
140    subdir('power-supply')
141endif
142if get_option('supply-monitor-ng')
143    subdir('phosphor-power-supply')
144endif
145if get_option('utils')
146    subdir('tools/power-utils')
147endif
148if get_option('tests').enabled()
149    subdir('test')
150endif
151if get_option('cold-redundancy')
152    subdir('cold-redundancy')
153endif
154