xref: /openbmc/phosphor-logging/extensions/openpower-pels/meson.build (revision d903057338a9bac97d06c9d8f6bbebc5b7478179)

libpldm_dep = dependency('libpldm', default_options: ['oem=ibm'])

python_inst = import('python').find_installation('python3')
python_ver = python_inst.language_version()
python_dep = python_inst.dependency()

extra_sources = []
extra_dependencies = []
extra_args = []

build_phal = get_option('phal').allowed()

if build_phal
    extra_sources += [
        'sbe_ffdc_handler.cpp',
        'fapi_data_process.cpp',
        'phal_service_actions.cpp',
    ]
    extra_dependencies += [
        dependency('libdt-api'),
        cpp.find_library('pdbg'),
        cpp.find_library('ekb'),
        cpp.find_library('phal'),
        cpp.find_library('libguard'),
    ]
    extra_args += ['-DPEL_ENABLE_PHAL']
    log_manager_ext_args += ['-DPEL_ENABLE_PHAL']
endif

libpel_sources = files(
    extra_sources,
    '../../paths.cpp',
    '../../util.cpp',
    'ascii_string.cpp',
    'bcd_time.cpp',
    'callout.cpp',
    'callouts.cpp',
    'data_interface.cpp',
    'device_callouts.cpp',
    'extended_user_header.cpp',
    'failing_mtms.cpp',
    'fru_identity.cpp',
    'generic.cpp',
    'journal.cpp',
    'json_utils.cpp',
    'log_id.cpp',
    'mru.cpp',
    'mtms.cpp',
    'pce_identity.cpp',
    'pel.cpp',
    'pel_rules.cpp',
    'pel_values.cpp',
    'private_header.cpp',
    'registry.cpp',
    'section_factory.cpp',
    'service_indicators.cpp',
    'severity.cpp',
    'temporary_file.cpp',
    'user_header.cpp',
)

libpel_deps = [
    conf_h_dep,
    libpldm_dep,
    nlohmann_json_dep,
    sdbusplus_dep,
    sdeventplus_dep,
    pdi_dep,
    phosphor_logging_dep,
    extra_dependencies,
]

libpel_lib = static_library(
    'pel',
    libpel_sources,
    'pel_paths.cpp',  # paths is separate because it is overridden during test.
    include_directories: include_directories('../..', '../../gen'),
    cpp_args: extra_args,
    dependencies: [libpel_deps],
)

libpel_dep = declare_dependency(
    include_directories: include_directories('.'),
    link_with: libpel_lib,
    dependencies: [
        libpldm_dep,
        nlohmann_json_dep,
        sdbusplus_dep,
        sdeventplus_dep,
        pdi_dep,
        phosphor_logging_dep,
    ],
)

log_manager_ext_deps += [libpel_dep, libpldm_dep, nlohmann_json_dep]

log_manager_ext_sources += files(
    'entry_points.cpp',
    'extended_user_data.cpp',
    'host_notifier.cpp',
    'manager.cpp',
    'pel_entry.cpp',
    'pldm_interface.cpp',
    'repository.cpp',
    'src.cpp',
    'user_data.cpp',
)

install_data(
    'registry/message_registry.json',
    'registry/O_component_ids.json',
    'registry/B_component_ids.json',
    install_dir: get_option('datadir') / 'phosphor-logging/pels',
)

peltool_sources = files(
    'extended_user_data.cpp',
    'src.cpp',
    'user_data.cpp',
    'user_data_json.cpp',
)

peltool_deps = [CLI11_dep, conf_h_dep, python_dep]

executable(
    'peltool',
    'tools/peltool.cpp',
    peltool_sources,
    cpp_args: ['-DPELTOOL'],
    link_args: ['-lpython' + python_ver],
    include_directories: include_directories('../..'),
    dependencies: [peltool_deps, libpel_dep],
    install: true,
)