xref: /openbmc/openpower-occ-control/meson.build (revision 6506e0d387edc7221edf31cc00fe4807da7566a3) 
1project(
2    'openpower-occ-control', 'cpp',
3    version : '1.0.0',
4    meson_version: '>=1.1.1',
5    default_options: [
6        'warning_level=3',
7        'werror=true',
8        'cpp_std=c++23',
9        'buildtype=debugoptimized'
10    ]
11)
12
13cxx = meson.get_compiler('cpp')
14
15conf_data = configuration_data()
16conf_data.set_quoted('OCC_CONTROL_BUSNAME', 'org.open_power.OCC.Control')
17conf_data.set_quoted('OCC_CONTROL_ROOT', '/org/open_power/control')
18conf_data.set_quoted('OCC_SENSORS_ROOT', '/xyz/openbmc_project/sensors')
19conf_data.set_quoted('CPU_NAME', 'cpu')
20conf_data.set_quoted('OCC_NAME', 'occ')
21conf_data.set_quoted('OCC_MASTER_NAME', 'occ-hwmon.1')
22conf_data.set_quoted('OCC_DEV_PATH', '/dev/occ')
23conf_data.set_quoted('CPU_SUBPATH', '/xyz/openbmc_project/inventory/system/chassis/motherboard')
24conf_data.set_quoted('OCC_CONTROL_PERSIST_PATH', '/var/lib/openpower-occ-control')
25
26conf_data.set('MAX_CPUS', get_option('max-cpus'))
27conf_data.set('OCC_CPU_TEMP_SENSOR_TYPE', 0xC0)
28conf_data.set('OCC_DIMM_TEMP_SENSOR_TYPE', 0xD0)
29conf_data.set('PS_DERATING_FACTOR', get_option('ps-derating-factor'))
30
31if get_option('i2c-occ').allowed()
32    conf_data.set_quoted('OCC_HWMON_PATH', '/sys/bus/i2c/drivers/occ-hwmon/')
33    conf_data.set_quoted('DEV_PATH', '/sys/bus/i2c/devices')
34    conf_data.set_quoted('I2C_OCC_DEVICE_NAME', 'p8-occ-hwmon')
35else
36    conf_data.set_quoted('OCC_HWMON_PATH', '/sys/bus/platform/drivers/occ-hwmon/')
37    conf_data.set_quoted('DEV_PATH', '/sys/bus/platform/devices/')
38endif
39
40conf_data.set('I2C_OCC', get_option('i2c-occ').allowed())
41conf_data.set('READ_OCC_SENSORS', get_option('read-occ-sensors').allowed())
42conf_data.set('PLDM', get_option('with-host-communication-protocol')=='pldm')
43conf_data.set('POWER10', get_option('power10-support').allowed())
44
45configure_file(output: 'config.h',
46    configuration: conf_data
47)
48
49install_data('occ-active.sh',
50    install_mode: 'rwxr-xr-x',
51    install_dir: get_option('bindir')
52)
53
54systemd = dependency('systemd')
55systemd_system_unit_dir = systemd.get_variable(
56    'systemdsystemunitdir')
57subdir('service_files')
58
59sdbusplus_dep = dependency('sdbusplus')
60
61python_prog = find_program('python3', required: true)
62
63deps = []
64sources = []
65
66cereal_dep = dependency('cereal', required: false)
67has_cereal = cxx.has_header_symbol(
68    'cereal/cereal.hpp',
69    'cereal::specialize',
70    dependencies: cereal_dep,
71    required: false)
72if not has_cereal
73    cereal_opts = import('cmake').subproject_options()
74    cereal_opts.add_cmake_defines({'BUILD_TESTS': 'OFF'})
75    cereal_proj = import('cmake').subproject(
76        'cereal',
77        options: cereal_opts,
78        required: false)
79    assert(cereal_proj.found(), 'cereal is required')
80    cereal_dep = cereal_proj.dependency('cereal')
81endif
82
83nlohmann_json_dep = dependency('nlohmann_json', include_type: 'system')
84phosphor_dbus_interfaces_dep = dependency('phosphor-dbus-interfaces')
85phosphor_logging_dep = dependency('phosphor-logging')
86sdeventplus_dep = dependency('sdeventplus')
87
88deps += [
89    cereal_dep,
90    nlohmann_json_dep,
91    phosphor_dbus_interfaces_dep,
92    phosphor_logging_dep,
93    sdbusplus_dep,
94    sdeventplus_dep,
95]
96
97sources += [
98    'app.cpp',
99    'occ_pass_through.cpp',
100    'occ_manager.cpp',
101    'occ_status.cpp',
102    'occ_device.cpp',
103    'occ_errors.cpp',
104    'occ_ffdc.cpp',
105    'occ_presence.cpp',
106    'occ_command.cpp',
107    'occ_dbus.cpp',
108    'powercap.cpp',
109    'i2c_occ.cpp',
110    'utils.cpp',
111]
112
113if get_option('with-host-communication-protocol')=='pldm'
114    libpldm_dep = dependency('libpldm')
115    deps += [
116        libpldm_dep,
117        cxx.find_library('pdbg'),
118        cxx.find_library('phal'),
119    ]
120    sources += [
121        'pldm.cpp',
122    ]
123endif
124
125if get_option('power10-support').allowed()
126    sources += [
127        'powermode.cpp',
128    ]
129endif
130
131yamldir = get_option('yamldir')
132if yamldir == ''
133    yamldir = meson.project_source_root() / 'example'
134endif
135
136# Generate occ-sensor.hpp.
137occ_sensor_hpp = custom_target(
138    'occ-sensor.hpp',
139    command : [
140        python_prog,
141        meson.project_source_root() + '/sensor_gen.py',
142        '-i', yamldir,
143    ],
144    output : 'occ-sensor.hpp')
145    sources += [occ_sensor_hpp]
146
147    executable(
148        'openpower-occ-control',
149        sources,
150        include_directories: '.',
151        implicit_include_directories: true,
152        dependencies: deps,
153        install: true,
154        install_dir: get_option('bindir')
155    )
156
157if not get_option('tests').disabled()
158  subdir('test')
159endif
160