xref: /openbmc/openpower-hw-diags/meson.build (revision 710101c03fee69d998e3596cc02574ee495d19ad) 
1# See README.md for details.
2project('openpower-hw-diags', 'cpp',
3        version: '0.1', meson_version: '>=1.1.1',
4        default_options: [
5          'warning_level=3',
6          'werror=true',
7          'cpp_std=c++23',
8        ])
9
10# Package directory root, which will contain required data files.
11package_dir = join_paths( get_option('prefix'),
12                          get_option('datadir'),
13                          meson.project_name() )
14
15# Compiler option so that source knows the package directory.
16package_args = [ '-DPACKAGE_DIR="' + package_dir + '/"' ]
17
18#-------------------------------------------------------------------------------
19# Versioning
20#-------------------------------------------------------------------------------
21buildinfo = vcs_tag(command: ['git', 'describe', '--always', '--long'],
22                  input: 'buildinfo.hpp.in',
23                  output: 'buildinfo.hpp',
24                  replace_string:'@BUILDINFO@',
25                  fallback: '0')
26
27#-------------------------------------------------------------------------------
28# Compiler
29#-------------------------------------------------------------------------------
30
31cmplr = meson.get_compiler('cpp')
32
33#-------------------------------------------------------------------------------
34# Config file
35#-------------------------------------------------------------------------------
36
37conf = configuration_data()
38
39conf.set('CONFIG_PHAL_API', get_option('phal').allowed())
40
41configure_file(input: 'config.h.in', output: 'config.h', configuration: conf)
42
43#-------------------------------------------------------------------------------
44# Include directories
45#-------------------------------------------------------------------------------
46
47# Only using the base directory. All header includes should provide the full
48# path from the base directory.
49incdir = include_directories('.')
50
51#-------------------------------------------------------------------------------
52# External library dependencies
53#-------------------------------------------------------------------------------
54
55# Look if the libhei library has already been built and installed. If not,
56# default to the subproject.
57libhei_dep = dependency('hei', fallback : ['libhei', 'libhei_dep'])
58
59phosphor_logging_dep = dependency('phosphor-logging',
60    fallback: ['phosphor-logging', 'phosphor_logging_dep'])
61
62sdbusplus_dep       = dependency('sdbusplus', version : '>=1.0')
63dbus_interfaces_dep = dependency('phosphor-dbus-interfaces')
64
65libpdbg_dep = cmplr.find_library('pdbg')
66
67if get_option('phal').allowed()
68  libphal_dep = cmplr.find_library('phal')
69endif
70
71libpldm_dep = dependency('libpldm')
72
73pthread = declare_dependency(link_args : '-pthread')
74lrt = declare_dependency(link_args : '-lrt')
75
76# JSON parser
77nlohmann_json_dep = dependency('nlohmann_json', include_type: 'system')
78
79# JSON validator
80if cmplr.has_header('valijson/validator.hpp')
81    valijson_dep = declare_dependency()
82else
83    subproject('valijson', required: false)
84    valijson_dep = declare_dependency(
85        include_directories: 'subprojects/valijson/include'
86    )
87    valijson_dep = valijson_dep.as_system('system')
88endif
89
90#-------------------------------------------------------------------------------
91# Build the local static libraries
92#-------------------------------------------------------------------------------
93
94subdir('analyzer')
95subdir('attn')
96subdir('util')
97
98hwdiags_libs = [
99    analyzer_lib,
100    attn_lib,
101    util_lib,
102]
103
104#-------------------------------------------------------------------------------
105# Build the executable
106#-------------------------------------------------------------------------------
107
108no_listener_mode = get_option('nlmode')
109
110if not no_listener_mode.disabled()
111  executable('openpower-hw-diags',
112              sources : [ 'main_nl.cpp', 'cli.cpp', buildinfo, plugins_src ],
113              dependencies : [ libhei_dep ],
114              link_with : hwdiags_libs,
115              install : true)
116else
117  executable('openpower-hw-diags',
118              sources : [ 'main.cpp', 'cli.cpp', 'listener.cpp', buildinfo,
119                          plugins_src ],
120              dependencies : [lrt, pthread, libhei_dep],
121              link_with : hwdiags_libs,
122              install : true)
123endif
124
125#-------------------------------------------------------------------------------
126# Test, if configured
127#-------------------------------------------------------------------------------
128
129build_tests = get_option('tests')
130
131if not build_tests.disabled()
132
133  # IMPORTANT NOTE:
134  # We cannot link the test executables to `util_lib` because:
135  #   - It is built without `-DTEST_TRACE` and any of the util functions that
136  #     use `trace.hpp` will throw a linker error because we don't have access
137  #     to phosphor-logging in test ... yet. This issue will go away once we
138  #     have converted all of our trace to use the `lg2` interfaces.
139  #   - Some functions related to pdbg and dbus simply cannot be built in the
140  #     test environment. Instead, there are alternate implementation of those
141  #     functions to simulate them for testing (see `test/*-sim-only.cpp`).
142  # Instead we will build a `test_util_lib` that will contain the `util` files
143  # that we need in test along with simulated versions of some util functions.
144
145  # IMPORTANT NOTE:
146  # When running GCOV reports, the Jenkins CI script explicitly ignores any
147  # libraries and executables built in the `test/` directory. Therefore, this
148  # `test_util_lib` library must be built here instead in order to get any GCOV
149  # credit for the code.
150
151  test_args = [
152    '-DTEST_TRACE',
153    package_args,
154  ]
155
156  test_util_srcs = [
157    files(
158      'util/data_file.cpp',
159      'util/ffdc_file.cpp',
160      'util/pdbg.cpp',
161      'util/temporary_file.cpp',
162      'test/dbus-sim-only.cpp',
163      'test/pdbg-sim-only.cpp',
164    ),
165  ]
166
167  test_util_deps = [
168    libhei_dep,
169    libpdbg_dep,
170    phosphor_logging_dep,
171  ]
172
173  test_util_lib = static_library('test_util_lib',
174    sources             : test_util_srcs,
175    include_directories : incdir,
176    dependencies        : test_util_deps,
177    cpp_args            : test_args,
178    install             : true,
179  )
180
181  test_libs = [
182    analyzer_lib,
183    attn_lib,
184    test_util_lib,
185  ]
186
187  subdir('test')
188endif
189