xref: /openbmc/openpower-hw-diags/meson.build (revision 46b5e2ba568283569f6b73ad273dfb52ec1dd5ad) 
1# See README.md for details.
2project('openpower-hw-diags', 'cpp',
3        version: '0.1', meson_version: '>=0.57.0',
4        default_options: [
5          'warning_level=3',
6          'werror=true',
7          'cpp_std=c++20',
8        ])
9
10# Package directory root, which will contain required data files.
11package_dir = join_paths( get_option('prefix'),
12                          get_option('datadir'),
13                          meson.project_name() )
14
15# Compiler option so that source knows the package directory.
16package_args = [ '-DPACKAGE_DIR="' + package_dir + '/"' ]
17
18#-------------------------------------------------------------------------------
19# Versioning
20#-------------------------------------------------------------------------------
21buildinfo = vcs_tag(command: ['git', 'describe', '--always', '--long'],
22                  input: 'buildinfo.hpp.in',
23                  output: 'buildinfo.hpp',
24                  replace_string:'@BUILDINFO@',
25                  fallback: '0')
26
27#-------------------------------------------------------------------------------
28# Compiler
29#-------------------------------------------------------------------------------
30
31cmplr = meson.get_compiler('cpp')
32
33#-------------------------------------------------------------------------------
34# Config file
35#-------------------------------------------------------------------------------
36
37conf = configuration_data()
38
39conf.set('CONFIG_PHAL_API', get_option('phal').enabled())
40
41configure_file(input: 'config.h.in', output: 'config.h', configuration: conf)
42
43#-------------------------------------------------------------------------------
44# Include directories
45#-------------------------------------------------------------------------------
46
47# Only using the base directory. All header includes should provide the full
48# path from the base directory.
49incdir = include_directories('.')
50
51#-------------------------------------------------------------------------------
52# External library dependencies
53#-------------------------------------------------------------------------------
54
55# Look if the libhei library has already been built and installed. If not,
56# default to the subproject.
57libhei_dep = dependency('hei', fallback : ['libhei', 'libhei_dep'])
58
59sdbusplus_dep       = dependency('sdbusplus', version : '>=1.0')
60dbus_interfaces_dep = dependency('phosphor-dbus-interfaces')
61
62libpdbg_dep = cmplr.find_library('pdbg')
63
64fmt_dep = dependency('fmt')
65
66if get_option('phal').enabled()
67  libphal_dep = cmplr.find_library('phal')
68endif
69
70# See if phosphor-logging is available, if not use test case logging code.
71h = 'phosphor-logging/log.hpp'
72if cmplr.compiles('#include <@0@>'.format(h), name : '#include <@0@>'.format(h))
73    test_arg = []
74else
75    test_arg = [
76        '-DTEST_TRACE',
77    ]
78endif
79
80pthread = declare_dependency(link_args : '-pthread')
81lrt = declare_dependency(link_args : '-lrt')
82
83# JSON parser
84if cmplr.has_header('nlohmann/json.hpp')
85    nlohmann_json_dep = declare_dependency()
86else
87    subproject('nlohmann', required: false)
88    nlohmann_json_dep = declare_dependency(
89        include_directories: [
90            'subprojects/nlohmann/single_include',
91            'subprojects/nlohmann/single_include/nlohmann',
92        ]
93    )
94    nlohmann_json_dep = nlohmann_json_dep.as_system('system')
95endif
96
97# JSON validator
98if cmplr.has_header('valijson/validator.hpp')
99    valijson_dep = declare_dependency()
100else
101    subproject('valijson', required: false)
102    valijson_dep = declare_dependency(
103        include_directories: 'subprojects/valijson/include'
104    )
105    valijson_dep = valijson_dep.as_system('system')
106endif
107
108#-------------------------------------------------------------------------------
109# Build the local static libraries
110#-------------------------------------------------------------------------------
111
112subdir('analyzer')
113subdir('attn')
114subdir('util')
115
116hwdiags_libs = [
117    analyzer_lib,
118    attn_lib,
119    util_lib,
120]
121
122#-------------------------------------------------------------------------------
123# Build the executable
124#-------------------------------------------------------------------------------
125
126no_listener_mode = get_option('nlmode')
127
128if not no_listener_mode.disabled()
129  executable('openpower-hw-diags',
130              sources : [ 'main_nl.cpp', 'cli.cpp', buildinfo, plugins_src ],
131              dependencies : [ libhei_dep ],
132              link_with : hwdiags_libs,
133              install : true)
134else
135  executable('openpower-hw-diags',
136              sources : [ 'main.cpp', 'cli.cpp', 'listener.cpp', buildinfo,
137                          plugins_src ],
138              dependencies : [lrt, pthread, libhei_dep],
139              link_with : hwdiags_libs,
140              cpp_args : test_arg,
141              install : true)
142endif
143
144#-------------------------------------------------------------------------------
145# Test, if configured
146#-------------------------------------------------------------------------------
147
148build_tests = get_option('tests')
149
150if not build_tests.disabled()
151  subdir('test')
152endif
153