xref: /openbmc/openbmc/poky/meta/recipes-graphics/cairo/cairo_1.18.2.bb (revision 8460358c3d24c71d9d38fd126c745854a6301564) 
1SUMMARY = "The Cairo 2D vector graphics library"
2DESCRIPTION = "Cairo is a multi-platform library providing anti-aliased \
3vector-based rendering for multiple target backends. Paths consist \
4of line segments and cubic splines and can be rendered at any width \
5with various join and cap styles. All colors may be specified with \
6optional translucence (opacity/alpha) and combined using the \
7extended Porter/Duff compositing algebra as found in the X Render \
8Extension."
9HOMEPAGE = "http://cairographics.org"
10BUGTRACKER = "https://gitlab.freedesktop.org/cairo/cairo/-/issues"
11SECTION = "libs"
12
13LICENSE = "(MPL-1.1 | LGPL-2.1-only) & GPL-3.0-or-later"
14LICENSE:${PN} = "MPL-1.1 | LGPL-2.1-only"
15LICENSE:${PN}-dev = "MPL-1.1 | LGPL-2.1-only"
16LICENSE:${PN}-doc = "MPL-1.1 | LGPL-2.1-only"
17LICENSE:${PN}-gobject = "MPL-1.1 | LGPL-2.1-only"
18LICENSE:${PN}-script-interpreter = "MPL-1.1 | LGPL-2.1-only"
19LICENSE:${PN}-perf-utils = "GPL-3.0-or-later"
20# Adapt the licenses for cairo-dbg and cairo-src depending on whether
21# cairo-trace is being built.
22LICENSE:${PN}-dbg = "(MPL-1.1 | LGPL-2.1-only)${@bb.utils.contains('PACKAGECONFIG', 'trace', ' & GPL-3.0-or-later', '', d)}"
23LICENSE:${PN}-src = "(MPL-1.1 | LGPL-2.1-only)${@bb.utils.contains('PACKAGECONFIG', 'trace', ' & GPL-3.0-or-later', '', d)}"
24
25LIC_FILES_CHKSUM = "file://COPYING;md5=e73e999e0c72b5ac9012424fa157ad77 \
26                    ${@bb.utils.contains('PACKAGECONFIG', 'trace', 'file://util/cairo-trace/COPYING-GPL-3;md5=d32239bcb673463ab874e80d47fae504', '', d)}"
27
28
29DEPENDS = "fontconfig freetype glib-2.0 libpng pixman zlib"
30
31SRC_URI = "http://cairographics.org/releases/cairo-${PV}.tar.xz \
32           file://cairo-get_bitmap_surface-bsc1036789-CVE-2017-7475.diff \
33          "
34
35SRC_URI[sha256sum] = "a62b9bb42425e844cc3d6ddde043ff39dbabedd1542eba57a2eb79f85889d45a"
36
37inherit meson pkgconfig upstream-version-is-even gtk-doc multilib_script
38
39# if qemu usermode isn't available, this value needs to be set statically
40# (otherwise it's determinted by running a small target executable with qemu)
41do_write_config:append() {
42    cat >${WORKDIR}/cairo.cross <<EOF
43[properties]
44ipc_rmid_deferred_release = 'true'
45EOF
46}
47EXTRA_OEMESON:append:class-nativesdk = "${@' --cross-file ${WORKDIR}/cairo.cross' if d.getVar('EXEWRAPPER_ENABLED') == 'False' else ''}"
48EXTRA_OEMESON:append:class-target = "${@' --cross-file ${WORKDIR}/cairo.cross' if d.getVar('EXEWRAPPER_ENABLED') == 'False' else ''}"
49
50GTKDOC_MESON_OPTION = "gtk_doc"
51
52MULTILIB_SCRIPTS = "${PN}-perf-utils:${bindir}/cairo-trace"
53
54PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'xlib xcb', '', d)} trace"
55PACKAGECONFIG[xlib] = "-Dxlib=enabled,-Dxlib=disabled,virtual/libx11 libxrender libxext"
56PACKAGECONFIG[xcb] = "-Dxcb=enabled,-Dxcb=disabled,libxcb"
57# cairo-trace is GPLv3 so add an option to remove it
58PACKAGECONFIG[trace] = ""
59
60EXTRA_OEMESON = "-Dsymbol-lookup=disabled -Dspectre=disabled -Dtests=disabled"
61
62do_install:append () {
63    if ! ${@bb.utils.contains('PACKAGECONFIG', 'trace', 'true', 'false', d)}; then
64        rm ${D}${bindir}/cairo-trace ${D}${libdir}/cairo/libcairo-trace.so
65        rmdir --ignore-fail-on-non-empty ${D}${bindir} ${D}${libdir}/cairo
66    fi
67}
68
69PACKAGES =+ "cairo-gobject cairo-script-interpreter cairo-perf-utils"
70
71SUMMARY:cairo-gobject = "The Cairo library GObject wrapper library"
72DESCRIPTION:cairo-gobject = "A GObject wrapper library for the Cairo API."
73
74SUMMARY:cairo-script-interpreter = "The Cairo library script interpreter"
75DESCRIPTION:cairo-script-interpreter = "The Cairo script interpreter implements \
76CairoScript.  CairoScript is used by tracing utilities to enable the ability \
77to replay rendering."
78
79DESCRIPTION:cairo-perf-utils = "The Cairo library performance utilities"
80
81FILES:${PN} = "${libdir}/libcairo.so.*"
82FILES:${PN}-gobject = "${libdir}/libcairo-gobject.so.*"
83FILES:${PN}-script-interpreter = "${libdir}/libcairo-script-interpreter.so.*"
84FILES:${PN}-perf-utils = "${bindir}/cairo-* ${libdir}/cairo/libcairo-trace.so ${libdir}/cairo/libcairo-fdr.so"
85
86BBCLASSEXTEND = "native nativesdk"
87
88UPSTREAM_CHECK_REGEX = "cairo-(?P<pver>\d+(\.\d+)+).tar.xz"
89