xref: /openbmc/libcper/meson.build (revision cd9b1c5826323f8035a10513c832cc1a0d351247) 
1project(
2    'libcper',
3    'c',
4    version: '0.1',
5    meson_version: '>=1.2.0',
6    default_options: [
7        'c_std=c18',
8        'tests=' + (meson.is_subproject() ? 'disabled' : 'enabled'),
9        'warning_level=2',
10        'werror=true',
11    ],
12)
13
14spec_dir = meson.current_source_dir() + '/specification/json'
15example_dir = meson.current_source_dir() + '/examples'
16add_project_arguments(
17    [
18        '-DLIBCPER_EXAMPLES="' + example_dir + '"',
19        '-DLIBCPER_JSON_SPEC="' + spec_dir + '"',
20        '-D_POSIX_C_SOURCE=200809L',
21    ],
22    language: 'c',
23)
24
25library_is_share = get_option('default_library') == 'shared'
26
27if get_option('output-all-properties').enabled()
28    add_project_arguments('-DOUTPUT_ALL_PROPERTIES', language: 'c')
29endif
30
31project_description = 'libcper library'
32
33libcper_parse_sources = files(
34    'sections/cper-section-ampere.c',
35    'sections/cper-section-arm.c',
36    'sections/cper-section-ccix-per.c',
37    'sections/cper-section-cxl-component.c',
38    'sections/cper-section-cxl-protocol.c',
39    'sections/cper-section-dmar-generic.c',
40    'sections/cper-section-dmar-iommu.c',
41    'sections/cper-section-dmar-vtd.c',
42    'sections/cper-section-firmware.c',
43    'sections/cper-section-generic.c',
44    'sections/cper-section-ia32x64.c',
45    'sections/cper-section-ipf.c',
46    'sections/cper-section-memory.c',
47    'sections/cper-section-nvidia.c',
48    'sections/cper-section-pci-bus.c',
49    'sections/cper-section-pci-dev.c',
50    'sections/cper-section-pcie.c',
51    'sections/cper-section.c',
52)
53
54edk_sources = files('Cper.c')
55
56libcper_generate_sources = files(
57    'generator/sections/gen-section-ampere.c',
58    'generator/sections/gen-section-arm.c',
59    'generator/sections/gen-section-ccix-per.c',
60    'generator/sections/gen-section-cxl-component.c',
61    'generator/sections/gen-section-cxl-protocol.c',
62    'generator/sections/gen-section-dmar.c',
63    'generator/sections/gen-section-firmware.c',
64    'generator/sections/gen-section-generic.c',
65    'generator/sections/gen-section-ia32x64.c',
66    'generator/sections/gen-section-memory.c',
67    'generator/sections/gen-section-nvidia.c',
68    'generator/sections/gen-section-pci-bus.c',
69    'generator/sections/gen-section-pci-dev.c',
70    'generator/sections/gen-section-pcie.c',
71    'generator/sections/gen-section.c',
72)
73
74cc = meson.get_compiler('c')
75
76json_c = dependency('json-c', default_options: {'warning_level': '0'})
77json_c_dep = declare_dependency(
78    include_directories: include_directories('subprojects'),
79    dependencies: json_c,
80)
81libcper_include = ['include']
82libcper_include_dir = include_directories(libcper_include, is_system: true)
83
84libcper_parse_sources += files(
85    'base64.c',
86    'common-utils.c',
87    'cper-parse.c',
88    'cper-utils.c',
89    'ir-parse.c',
90    'log.c',
91)
92
93subdir('include')
94
95install = get_option('install').allowed()
96
97libcper_parse = library(
98    'cper-parse',
99    libcper_parse_sources,
100    edk_sources,
101    version: meson.project_version(),
102    include_directories: libcper_include_dir,
103    c_args: '-Wno-address-of-packed-member',
104    dependencies: [json_c_dep],
105    install: install,
106)
107libcper_parse_dep = declare_dependency(
108    include_directories: libcper_include_dir,
109    link_with: [libcper_parse],
110)
111
112libcper_generate_sources += files(
113    'generator/cper-generate.c',
114    'generator/gen-utils.c',
115)
116
117libcper_generate = library(
118    'cper-generate',
119    libcper_generate_sources,
120    version: meson.project_version(),
121    include_directories: libcper_include_dir,
122    dependencies: [json_c_dep],
123    link_with: [libcper_parse],
124    install: install,
125)
126libcper_generate_dep = declare_dependency(
127    include_directories: libcper_include_dir,
128    link_with: libcper_generate,
129)
130
131if get_option('pkgconfig').allowed()
132    import('pkgconfig').generate(
133        libcper_parse,
134        name: meson.project_name(),
135        version: meson.project_version(),
136        description: 'C bindings for parsing CPER',
137    )
138endif
139
140if get_option('utility').allowed()
141    executable(
142        'cper-convert',
143        'cli-app/cper-convert.c',
144        include_directories: libcper_include_dir,
145        dependencies: [json_c_dep],
146        link_with: [libcper_parse, libcper_generate],
147        install: install,
148        install_dir: get_option('bindir'),
149    )
150
151    executable(
152        'cper-generate',
153        'generator/cper-generate-cli.c',
154        edk_sources,
155        include_directories: libcper_include_dir,
156        link_with: [libcper_parse, libcper_generate],
157        install: install,
158        install_dir: get_option('bindir'),
159    )
160endif
161
162# Disable unit tests when output-all-properties is enabled
163# because it changes CPER-IR output format.
164if get_option('output-all-properties').disabled()
165    if get_option('tests').allowed()
166        subdir('tests')
167    endif
168endif
169
170if get_option('python').allowed()
171    py = import('python').find_installation(pure: false)
172    py.extension_module(
173        'cper',
174        'pycper.c',
175        c_args: ['-DLIBCPER_PYTHON'],
176        dependencies: [libcper_parse_dep, json_c_dep],
177        install: true,
178    )
179endif
180