xref: /openbmc/obmc-console/test/meson.build (revision a1f911aaf2b730005f9aebca1f7ff752add26e0a) 
1tests = [
2    'test-ringbuffer-boundary-poll',
3    'test-ringbuffer-boundary-read',
4    'test-ringbuffer-contained-offset-read',
5    'test-ringbuffer-contained-read',
6    'test-ringbuffer-poll-force',
7    'test-ringbuffer-read-commit',
8    'test-ringbuffer-simple-poll',
9]
10
11foreach t : tests
12    test(
13        t,
14        executable(
15            t,
16            f'@t@.c',
17            c_args: ['-DSYSCONFDIR=""'],
18            include_directories: '..',
19        ),
20    )
21endforeach
22
23tests_depend_iniparser = [
24    'test-client-escape',
25    'test-config-parse',
26    'test-config-parse-bytesize',
27    'test-config-resolve-console-id',
28]
29
30foreach ct : tests_depend_iniparser
31    test(
32        ct,
33        executable(
34            ct,
35            f'@ct@.c',
36            c_args: ['-DSYSCONFDIR=""'],
37            dependencies: [iniparser_dep],
38            include_directories: '..',
39        ),
40    )
41endforeach
42
43socat = find_program('socat', native: true)
44
45server_tests = [
46    'test-console-logs-to-file',
47    'test-console-logs-to-file-no-sections',
48    'test-console-socket-read',
49    'test-console-socket-write',
50    'test-multiple-consoles',
51]
52
53foreach st : server_tests
54    test(
55        st,
56        find_program(st),
57        args: [socat.full_path(), server.full_path()],
58        depends: [server],
59        suite: 'itests',
60    )
61endforeach
62
63client_tests = [
64    'test-console-client-can-read',
65    'test-console-client-can-write',
66    'test-console-client-no-args',
67]
68
69foreach ct : client_tests
70    test(
71        ct,
72        find_program(ct),
73        args: [socat.full_path(), server.full_path(), client.full_path()],
74        depends: [server, client],
75        suite: 'itests',
76    )
77endforeach
78