1SUMMARY = "A TCP/IP Daemon simplifying the communication with GPS devices"
2SECTION = "console/network"
3LICENSE = "BSD-2-Clause"
4LIC_FILES_CHKSUM = "file://COPYING;md5=7a5d174db44ec45f9638b2c747806821"
5DEPENDS = "dbus ncurses python3 pps-tools"
6PROVIDES = "virtual/gpsd"
7
8SRC_URI = "${SAVANNAH_GNU_MIRROR}/${BPN}/${BP}.tar.gz \
9           file://gpsd.init \
10           "
11SRC_URI[sha256sum] = "00ee13f615655284874a661be13553abe66128e6deb5cd648af9bc0cb345fe5c"
12
13inherit scons update-rc.d python3-dir python3native systemd update-alternatives pkgconfig
14
15INITSCRIPT_PACKAGES = "gpsd-conf"
16INITSCRIPT_NAME = "gpsd"
17INITSCRIPT_PARAMS = "defaults 35"
18
19SYSTEMD_OESCONS = "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false',d)}"
20
21export STAGING_INCDIR
22export STAGING_LIBDIR
23
24CLEANBROKEN = "1"
25
26PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez', '', d)} usb"
27PACKAGECONFIG[bluez] = "bluez='true',bluez='false',bluez5"
28PACKAGECONFIG[qt] = "qt='yes' qt_versioned=5,qt='no',qtbase"
29PACKAGECONFIG[usb] = "usb='true',usb='false',libusb1"
30EXTRA_OESCONS = " \
31    sysroot=${STAGING_DIR_TARGET} \
32    libQgpsmm='false' \
33    debug='false' \
34    nostrip='true' \
35    systemd='${SYSTEMD_OESCONS}' \
36    libdir='${libdir}' \
37    sbindir='${sbindir}' \
38    udevdir='${nonarch_base_libdir}/udev' \
39    unitdir='${systemd_system_unitdir}' \
40    manbuild='false' \
41    LINK='${CC}' \
42    ${PACKAGECONFIG_CONFARGS} \
43"
44# This cannot be used, because then chrpath is not found and only static lib is built
45# target=${HOST_SYS}
46
47do_compile:prepend() {
48    export PKG_CONFIG_PATH="${PKG_CONFIG_PATH}"
49    export PKG_CONFIG="PKG_CONFIG_SYSROOT_DIR=\"${PKG_CONFIG_SYSROOT_DIR}\" pkg-config"
50    export STAGING_PREFIX="${STAGING_DIR_HOST}/${prefix}"
51    export CC="${CC}"
52    export LD="${CC}"
53    export LINKFLAGS="${LDFLAGS}"
54}
55
56do_install() {
57    export PKG_CONFIG_PATH="${PKG_CONFIG_PATH}"
58    export PKG_CONFIG="PKG_CONFIG_SYSROOT_DIR=\"${PKG_CONFIG_SYSROOT_DIR}\" pkg-config"
59    export STAGING_PREFIX="${STAGING_DIR_HOST}/${prefix}"
60    export LD="${CC}"
61    export LINKFLAGS="${LDFLAGS}"
62
63    export DESTDIR="${D}"
64    # prefix is used for RPATH and DESTDIR/prefix for installation
65    ${STAGING_BINDIR_NATIVE}/scons prefix=${prefix} python_libdir=${libdir} udev-install ${EXTRA_OESCONS} || \
66      bbfatal "scons install execution failed."
67}
68
69do_install:append() {
70    install -d ${D}${sysconfdir}/init.d
71    install -m 0755 ${WORKDIR}/gpsd.init ${D}${sysconfdir}/init.d/gpsd
72    install -d ${D}${sysconfdir}/default
73    install -m 0644 ${S}/packaging/deb/etc_default_gpsd ${D}${sysconfdir}/default/gpsd.default
74
75    # Support for python
76    if [ -d ${D}${libdir}/gps ]; then
77        install -d ${D}${PYTHON_SITEPACKAGES_DIR}/gps
78        install -m 755 ${D}${libdir}/gps/*.py ${D}${PYTHON_SITEPACKAGES_DIR}/gps
79    fi
80}
81
82PACKAGES =+ "libgps python3-pygps gpsd-udev gpsd-conf gpsd-gpsctl gps-utils gps-utils-python"
83
84RPROVIDES:${PN}-dbg += "python-pygps-dbg"
85
86FILES:${PN}-dev += "${libdir}/libQgpsmm.prl"
87
88FILES:${PN}-doc += "${datadir}/${BPN}/doc"
89
90RDEPENDS:${PN} = "gpsd-gpsctl"
91RRECOMMENDS:${PN} = "gpsd-conf gpsd-udev gpsd-machine-conf"
92
93SUMMARY:gpsd-udev = "udev relevant files to use gpsd hotplugging"
94FILES:gpsd-udev = "${nonarch_base_libdir}/udev"
95RDEPENDS:gpsd-udev += "udev gpsd-conf"
96
97SUMMARY:libgps = "C service library used for communicating with gpsd"
98FILES:libgps = "${libdir}/libgps.so.*"
99
100SUMMARY:gpsd-conf = "gpsd configuration files and init scripts"
101FILES:gpsd-conf = "${sysconfdir}"
102CONFFILES:gpsd-conf = "${sysconfdir}/default/gpsd.default"
103
104SUMMARY:gpsd-gpsctl = "Tool for tweaking GPS modes"
105FILES:gpsd-gpsctl = "${bindir}/gpsctl"
106
107SUMMARY:gps-utils = "Utils used for simulating, monitoring,... a GPS"
108FILES:gps-utils = "\
109    ${bindir}/cgps         \
110    ${bindir}/gps2udp      \
111    ${bindir}/gpsctl       \
112    ${bindir}/gpsdebuginfo \
113    ${bindir}/gpsdecode    \
114    ${bindir}/gpsmon       \
115    ${bindir}/gpspipe      \
116    ${bindir}/gpsrinex     \
117    ${bindir}/gpssnmp      \
118    ${bindir}/gpxlogger    \
119    ${bindir}/lcdgps       \
120    ${bindir}/ntpshmmon    \
121    ${bindir}/ppscheck     \
122"
123RRECOMMENDS:gps-utils = "gps-utils-python"
124
125SUMMARY:gps-utils-python = "Python utils used for simulating, monitoring,... a GPS"
126FILES:gps-utils-python = "\
127    ${bindir}/gegps        \
128    ${bindir}/gpscat       \
129    ${bindir}/gpscsv       \
130    ${bindir}/gpsfake      \
131    ${bindir}/gpsplot      \
132    ${bindir}/gpsprof      \
133    ${bindir}/gpssubframe  \
134    ${bindir}/ubxtool      \
135    ${bindir}/xgps         \
136    ${bindir}/xgpsspeed    \
137    ${bindir}/zerk         \
138"
139RDEPENDS:gps-utils-python = "python3-pygps"
140
141SUMMARY:python3-pygps = "Python bindings to gpsd"
142FILES:python3-pygps = "${PYTHON_SITEPACKAGES_DIR}/* ${libdir}/gps/*.py ${libdir}/*.egg-info"
143RDEPENDS:python3-pygps = " \
144    python3-core \
145    python3-io \
146    python3-pyserial \
147    python3-threading \
148    python3-terminal \
149    gpsd \
150    python3-json"
151
152RPROVIDES:${PN} += "${PN}-systemd"
153RREPLACES:${PN} += "${PN}-systemd"
154RCONFLICTS:${PN} += "${PN}-systemd"
155SYSTEMD_SERVICE:${PN} = "${BPN}.socket ${BPN}ctl@.service"
156
157ALTERNATIVE:${PN} = "gpsd-defaults"
158ALTERNATIVE_LINK_NAME[gpsd-defaults] = "${sysconfdir}/default/gpsd"
159ALTERNATIVE_TARGET[gpsd-defaults] = "${sysconfdir}/default/gpsd.default"
160