xref: /openbmc/bios-settings-mgr/meson.build (revision ae91a56d09bf50fe45b1760f29a81e188e07e163) 
1project(
2    'biosconfig-manager',
3    'cpp',
4    meson_version: '>=1.1.1',
5    default_options: [
6        'warning_level=3',
7        'werror=true',
8        'cpp_std=c++23',
9        'buildtype=debugoptimized',
10    ],
11    license: 'Apache-2.0',
12    version: '1.0',
13)
14
15# Wno-psabi reduces the number of "Note:" messages when cross-compiling some STL
16# stuff for ARM. See https://stackoverflow.com/questions/48149323/strange-gcc-warning-when-compiling-qt-project
17# Basically, gcc 6 and gcc 7 are not ABI compatible, but since the whole OpenBMC
18# project uses the same compiler, we can safely ignmore these info notes.
19add_project_arguments('-Wno-psabi', language: 'cpp')
20
21conf_data = configuration_data()
22if (get_option('enable-bios-secureboot').allowed())
23    add_project_arguments('-DENABLE_BIOS_SECUREBOOT', language: 'cpp')
24endif
25configure_file(output: 'configuration.h', configuration: conf_data)
26
27boost_args = [
28    '-DBOOST_ALL_NO_LIB',
29    '-DBOOST_ASIO_DISABLE_THREADS',
30    '-DBOOST_ERROR_CODE_HEADER_ONLY',
31    '-DBOOST_NO_RTTI',
32    '-DBOOST_NO_TYPEID',
33    '-DBOOST_SYSTEM_NO_DEPRECATED',
34]
35
36deps = [
37    dependency('boost'),
38    dependency('phosphor-dbus-interfaces'),
39    dependency('phosphor-logging'),
40    dependency('sdbusplus'),
41    dependency('libsystemd'),
42    dependency('openssl'),
43    dependency('nlohmann_json', include_type: 'system'),
44]
45
46cereal = dependency('cereal', required: false)
47cpp = meson.get_compiler('cpp')
48has_cereal = cpp.has_header_symbol(
49    'cereal/cereal.hpp',
50    'cereal::specialize',
51    dependencies: cereal,
52    required: false,
53)
54if not has_cereal
55    cereal_opts = import('cmake').subproject_options()
56    cereal_opts.add_cmake_defines(
57        {'BUILD_TESTS': 'OFF', 'SKIP_PERFORMANCE_COMPARISON': 'ON'},
58    )
59    cereal_proj = import('cmake').subproject(
60        'cereal',
61        options: cereal_opts,
62        required: false,
63    )
64    assert(cereal_proj.found(), 'cereal is required')
65    cereal = cereal_proj.dependency('cereal')
66endif
67deps += cereal
68
69src_files = [
70    'src/main.cpp',
71    'src/manager.cpp',
72    'src/manager_serialize.cpp',
73    'src/password.cpp',
74    'src/secureboot.cpp',
75]
76
77executable(
78    'biosconfig-manager',
79    src_files,
80    implicit_include_directories: true,
81    include_directories: ['include'],
82    dependencies: deps,
83    cpp_args: boost_args,
84    install: true,
85    install_dir: get_option('bindir'),
86)
87
88systemd = dependency('systemd')
89systemd_system_unit_dir = systemd.get_variable(
90    'systemd_system_unit_dir',
91    pkgconfig_define: ['prefix', get_option('prefix')],
92)
93
94fs = import('fs')
95fs.copyfile(
96    'service_files/xyz.openbmc_project.biosconfig_manager.service',
97    install: true,
98    install_dir: systemd_system_unit_dir,
99)
100