xref: /openbmc/qemu/ui/meson.build (revision 7b1070a7) 
1system_ss.add(pixman)
2specific_ss.add(when: ['CONFIG_SYSTEM_ONLY'], if_true: pixman)   # for the include path
3specific_ss.add(when: ['CONFIG_SYSTEM_ONLY'], if_true: opengl)   # for the include path
4
5system_ss.add(png)
6system_ss.add(files(
7  'clipboard.c',
8  'console.c',
9  'cursor.c',
10  'dmabuf.c',
11  'input-keymap.c',
12  'input-legacy.c',
13  'input-barrier.c',
14  'input.c',
15  'kbd-state.c',
16  'keymaps.c',
17  'qemu-pixman.c',
18  'ui-hmp-cmds.c',
19  'ui-qmp-cmds.c',
20  'util.c',
21))
22system_ss.add(when: pixman, if_true: files('console-vc.c'), if_false: files('console-vc-stubs.c'))
23if dbus_display
24  system_ss.add(files('dbus-module.c'))
25endif
26system_ss.add([spice_headers, files('spice-module.c')])
27system_ss.add(when: spice_protocol, if_true: files('vdagent.c'))
28
29if host_os == 'linux'
30  system_ss.add(files('input-linux.c', 'udmabuf.c'))
31endif
32system_ss.add(when: cocoa, if_true: files('cocoa.m'))
33
34vnc_ss = ss.source_set()
35vnc_ss.add(files(
36  'vnc.c',
37  'vnc-enc-zlib.c',
38  'vnc-enc-hextile.c',
39  'vnc-enc-tight.c',
40  'vnc-palette.c',
41  'vnc-enc-zrle.c',
42  'vnc-auth-vencrypt.c',
43  'vnc-ws.c',
44  'vnc-jobs.c',
45  'vnc-clipboard.c',
46))
47vnc_ss.add(zlib, jpeg)
48vnc_ss.add(when: sasl, if_true: files('vnc-auth-sasl.c'))
49system_ss.add_all(when: [vnc, pixman], if_true: vnc_ss)
50system_ss.add(when: vnc, if_false: files('vnc-stubs.c'))
51
52ui_modules = {}
53
54if curses.found()
55  curses_ss = ss.source_set()
56  curses_ss.add(when: [curses, iconv], if_true: [files('curses.c'), pixman])
57  ui_modules += {'curses' : curses_ss}
58endif
59
60system_ss.add(opengl)
61if opengl.found()
62  opengl_ss = ss.source_set()
63  opengl_ss.add(gbm, pixman)
64  opengl_ss.add(when: [opengl],
65               if_true: files('shader.c', 'console-gl.c', 'egl-helpers.c', 'egl-context.c'))
66  ui_modules += {'opengl' : opengl_ss}
67endif
68
69if opengl.found()
70  egl_headless_ss = ss.source_set()
71  egl_headless_ss.add(when: [opengl, pixman],
72                      if_true: [files('egl-headless.c'), gbm])
73  ui_modules += {'egl-headless' : egl_headless_ss}
74endif
75
76if dbus_display
77  dbus_ss = ss.source_set()
78  env = environment()
79  env.set('HOST_OS', host_os)
80  xml = custom_target('dbus-display preprocess',
81                      input: 'dbus-display1.xml',
82                      output: 'dbus-display1.xml',
83                      env: env,
84                      command: [xml_pp, '@INPUT@', '@OUTPUT@'])
85  dbus_display1 = custom_target('dbus-display gdbus-codegen',
86                                output: ['dbus-display1.h', 'dbus-display1.c'],
87                                input: xml,
88                                command: [gdbus_codegen, '@INPUT@',
89                                          '--glib-min-required', '2.64',
90                                          '--output-directory', meson.current_build_dir(),
91                                          '--interface-prefix', 'org.qemu.',
92                                          '--c-namespace', 'QemuDBus',
93                                          '--generate-c-code', '@BASENAME@'])
94  dbus_ss.add(when: gio,
95              if_true: [files(
96                'dbus-chardev.c',
97                'dbus-clipboard.c',
98                'dbus-console.c',
99                'dbus-error.c',
100                'dbus-listener.c',
101                'dbus.c',
102              ), opengl, gbm, pixman, dbus_display1])
103  ui_modules += {'dbus' : dbus_ss}
104endif
105
106if gtk.found()
107  if host_os == 'windows'
108    system_ss.add(files('win32-kbd-hook.c'))
109  endif
110
111  gtk_ss = ss.source_set()
112  gtk_ss.add(gtk, vte, pixman, files('gtk.c'))
113  if have_gtk_clipboard
114    gtk_ss.add(files('gtk-clipboard.c'))
115  endif
116  gtk_ss.add(when: x11, if_true: files('x_keymap.c'))
117  gtk_ss.add(when: opengl, if_true: files('gtk-gl-area.c'))
118  gtk_ss.add(when: [x11, opengl], if_true: files('gtk-egl.c'))
119  ui_modules += {'gtk' : gtk_ss}
120endif
121
122if sdl.found()
123  if host_os == 'windows'
124    system_ss.add(files('win32-kbd-hook.c'))
125  endif
126
127  sdl_ss = ss.source_set()
128  sdl_ss.add(sdl, sdl_image, pixman, glib, files(
129    'sdl2-2d.c',
130    'sdl2-input.c',
131    'sdl2.c',
132  ))
133  sdl_ss.add(when: opengl, if_true: files('sdl2-gl.c'))
134  sdl_ss.add(when: x11, if_true: files('x_keymap.c'))
135  ui_modules += {'sdl' : sdl_ss}
136endif
137
138if spice.found()
139  spice_core_ss = ss.source_set()
140  spice_core_ss.add(spice, pixman, files(
141    'spice-core.c',
142    'spice-input.c',
143    'spice-display.c'
144  ))
145  ui_modules += {'spice-core' : spice_core_ss}
146
147  if gio.found()
148    spice_ss = ss.source_set()
149    spice_ss.add(spice, gio, pixman, files('spice-app.c'))
150    ui_modules += {'spice-app': spice_ss}
151  endif
152endif
153
154keymaps = [
155  ['atset1', 'qcode'],
156  ['linux', 'qcode'],
157  ['qcode', 'atset1'],
158  ['qcode', 'atset2'],
159  ['qcode', 'atset3'],
160  ['qcode', 'linux'],
161  ['qcode', 'qnum'],
162  ['qcode', 'sun'],
163  ['qnum', 'qcode'],
164  ['usb', 'qcode'],
165  ['win32', 'qcode'],
166  ['x11', 'qcode'],
167  ['xorgevdev', 'qcode'],
168  ['xorgkbd', 'qcode'],
169  ['xorgxquartz', 'qcode'],
170  ['xorgxwin', 'qcode'],
171  ['osx', 'qcode'],
172]
173
174if have_system or xkbcommon.found()
175  keycodemapdb_proj = subproject('keycodemapdb', required: true)
176  foreach e : keymaps
177    output = 'input-keymap-@0@-to-@1@.c.inc'.format(e[0], e[1])
178    genh += custom_target(output,
179                  output: output,
180                  capture: true,
181                  input: keycodemapdb_proj.get_variable('keymaps_csv'),
182                  command: [python, keycodemapdb_proj.get_variable('keymap_gen').full_path(),
183                            'code-map', '--lang', 'glib2',
184                            '--varname', 'qemu_input_map_@0@_to_@1@'.format(e[0], e[1]),
185                            '@INPUT0@', e[0], e[1]])
186  endforeach
187endif
188
189subdir('shader')
190
191if have_system
192  subdir('icons')
193
194  install_data('qemu.desktop', install_dir: qemu_desktopdir)
195endif
196
197modules += {'ui': ui_modules}
198