1SUMMARY = "Provide limited super user privileges to specific users"
2DESCRIPTION = "Sudo (superuser do) allows a system administrator to give certain users (or groups of users) the ability to run some (or all) commands as root while logging all commands and arguments."
3HOMEPAGE = "http://www.sudo.ws"
4BUGTRACKER = "http://www.sudo.ws/bugs/"
5SECTION = "admin"
6LICENSE = "ISC & BSD-3-Clause & BSD-2-Clause & Zlib"
7LIC_FILES_CHKSUM = "file://LICENSE.md;md5=0a6876cbeb2aa51837935ba3fd82ee87 \
8                    file://plugins/sudoers/redblack.c;beginline=1;endline=46;md5=03e35317699ba00b496251e0dfe9f109 \
9                    file://lib/util/reallocarray.c;beginline=3;endline=15;md5=397dd45c7683e90b9f8bf24638cf03bf \
10                    file://lib/util/fnmatch.c;beginline=3;endline=27;md5=004d7d2866ba1f5b41174906849d2e0f \
11                    file://lib/util/glob.c;beginline=2;endline=31;md5=2852f68687544e3eb8a0a61665506f0e \
12                    file://lib/util/snprintf.c;beginline=3;endline=33;md5=b70df6179969e38fcf68da91b53b8029 \
13                    file://include/sudo_queue.h;beginline=2;endline=27;md5=ad578e9664d17a010b63e4bc0576ee8d \
14                    file://lib/util/inet_pton.c;beginline=3;endline=17;md5=27785c9f5835093eda42aa0816a2d0b4 \
15                    file://lib/util/arc4random.c;beginline=3;endline=20;md5=ced8636ecefa2ba907cfe390bc3bd964 \
16                    file://lib/util/arc4random_uniform.c;beginline=3;endline=17;md5=e30c2b777cdc00cfcaf7c445a10b262f \
17                    file://lib/util/getentropy.c;beginline=1;endline=19;md5=a0f58be3d60b6dcd898ec5fe0866d36f \
18                    "
19
20inherit autotools
21
22PACKAGECONFIG ??= ""
23PACKAGECONFIG[zlib] = "--enable-zlib,--disable-zlib,zlib"
24PACKAGECONFIG[pam-wheel] = ",,,pam-plugin-wheel"
25PACKAGECONFIG[audit] = "--with-linux-audit,--without-linux-audit,audit"
26PACKAGECONFIG[selinux] = "--with-selinux,--without-selinux,libselinux"
27
28EXTRA_OECONF = "--with-editor=${base_bindir}/vi --with-env-editor"
29
30EXTRA_OECONF:append:libc-musl = " --disable-hardening "
31
32do_compile:prepend () {
33       # Remove build host references from config.h
34       sed -i  \
35           -e 's,--with-libtool-sysroot=${STAGING_DIR_TARGET},,g' \
36           -e 's,--build=${BUILD_SYS},,g' \
37           -e 's,--host=${HOST_SYS},,g' \
38           ${B}/config.h
39}
40
41# Explicitly create ${localstatedir}/lib before do_install to ensure
42# the directory is accessible by all users. Otherwise the mkinstalldirs
43# script (from sudo) will recursively create ${localstatedir}/lib/sudo
44# and then chmod each directory with 0700 permissions, which isn't what
45# we want (i.e, users would not be able to access /var/lib).
46do_install:prepend (){
47	mkdir -p ${D}/${localstatedir}/lib
48}
49
50CVE_VERSION_SUFFIX = "patch"
51