1# Setup extra CFLAGS and LDFLAGS which have 'security' benefits. These
2# don't work universally, there are recipes which can't use one, the other
3# or both so an override is maintained here. The idea would be over
4# time to reduce this list to nothing.
5# From a Yocto Project perspective, this file is included and tested
6# in the DISTRO="poky" configuration.
7
8GCCPIE ?= "--enable-default-pie"
9# If static PIE is known to work well, GLIBCPIE="--enable-static-pie" can be set
10
11# _FORTIFY_SOURCE requires -O1 or higher, so disable in debug builds as they use
12# -O0 which then results in a compiler warning.
13OPTLEVEL = "${@bb.utils.filter('SELECTED_OPTIMIZATION', '-O0 -O1 -O2 -O3 -Ofast -Og -Os -Oz -O', d)}"
14
15lcl_maybe_fortify ?= "${@oe.utils.conditional('OPTLEVEL','-O0','','${OPTLEVEL} -D_FORTIFY_SOURCE=2',d)}"
16
17# Error on use of format strings that represent possible security problems
18SECURITY_STRINGFORMAT ?= "-Wformat -Wformat-security -Werror=format-security"
19
20# Inject pie flags into compiler flags if not configured with gcc itself
21# especially useful with external toolchains
22SECURITY_PIE_CFLAGS ?= "${@'' if '${GCCPIE}' else '-pie -fPIE'}"
23
24SECURITY_NOPIE_CFLAGS ?= "-no-pie -fno-PIE"
25
26SECURITY_STACK_PROTECTOR ?= "-fstack-protector-strong"
27
28SECURITY_CFLAGS ?= "${SECURITY_STACK_PROTECTOR} ${SECURITY_PIE_CFLAGS} ${lcl_maybe_fortify} ${SECURITY_STRINGFORMAT}"
29SECURITY_NO_PIE_CFLAGS ?= "${SECURITY_STACK_PROTECTOR} ${lcl_maybe_fortify} ${SECURITY_STRINGFORMAT}"
30
31SECURITY_LDFLAGS ?= "-Wl,-z,relro,-z,now"
32SECURITY_X_LDFLAGS ?= "-Wl,-z,relro"
33
34# powerpc does not get on with pie for reasons not looked into as yet
35GCCPIE:powerpc = ""
36GLIBCPIE:powerpc = ""
37SECURITY_CFLAGS:remove:powerpc = "${SECURITY_PIE_CFLAGS}"
38SECURITY_CFLAGS:pn-libgcc:powerpc = ""
39
40SECURITY_CFLAGS:pn-glibc = ""
41SECURITY_CFLAGS:pn-glibc-testsuite = ""
42SECURITY_CFLAGS:pn-gcc-runtime = ""
43SECURITY_CFLAGS:pn-grub = ""
44SECURITY_CFLAGS:pn-grub-efi = ""
45SECURITY_CFLAGS:pn-mkelfimage:x86 = ""
46
47SECURITY_CFLAGS:pn-valgrind = "${SECURITY_NOPIE_CFLAGS}"
48SECURITY_LDFLAGS:pn-valgrind = ""
49SECURITY_CFLAGS:pn-sysklogd = "${SECURITY_NOPIE_CFLAGS}"
50SECURITY_LDFLAGS:pn-sysklogd = ""
51
52# Recipes which fail to compile when elevating -Wformat-security to an error
53SECURITY_STRINGFORMAT:pn-busybox = ""
54SECURITY_STRINGFORMAT:pn-gcc = ""
55
56TARGET_CC_ARCH:append:class-target = " ${SECURITY_CFLAGS}"
57TARGET_LDFLAGS:append:class-target = " ${SECURITY_LDFLAGS}"
58TARGET_CC_ARCH:append:class-cross-canadian = " ${SECURITY_CFLAGS}"
59TARGET_LDFLAGS:append:class-cross-canadian = " ${SECURITY_LDFLAGS}"
60
61SECURITY_STACK_PROTECTOR:pn-gcc-runtime = ""
62SECURITY_STACK_PROTECTOR:pn-glibc = ""
63SECURITY_STACK_PROTECTOR:pn-glibc-testsuite = ""
64SECURITY_STACK_PROTECTOR:pn-ltp = ""
65# All xorg module drivers need to be linked this way as well and are
66# handled in recipes-graphics/xorg-driver/xorg-driver-common.inc
67SECURITY_LDFLAGS:pn-xserver-xorg = "${SECURITY_X_LDFLAGS}"
68
69TARGET_CC_ARCH:append:pn-binutils = " ${SELECTED_OPTIMIZATION}"
70TARGET_CC_ARCH:append:pn-gcc = " ${SELECTED_OPTIMIZATION}"
71TARGET_CC_ARCH:append:pn-gdb = " ${SELECTED_OPTIMIZATION}"
72