xref: /openbmc/openbmc/meta-raspberrypi/recipes-multimedia/omxplayer/omxplayer_git.bb (revision 2edf0648b7c401072e7183c7f9e0e7c437e5f3f0) 
1SUMMARY = "A commandline OMX player for the Raspberry Pi"
2DESCRIPTION = "This player was developed as a testbed for the XBMC \
3Raspberry PI implementation and is quite handy to use standalone"
4HOMEPAGE = "https://github.com/popcornmix/omxplayer"
5SECTION = "console/utils"
6
7LICENSE = "GPL-2.0-only"
8LIC_FILES_CHKSUM = "file://COPYING;md5=00a27da7ac0f9bcd17320ec29ef4bbf6"
9
10DEPENDS = "alsa-lib libpcre virtual/egl boost freetype dbus openssl libssh virtual/libomxil coreutils-native curl-native userland"
11
12PR = "r6"
13
14SRCREV_FORMAT = "_ffmpeg"
15
16SRCREV_default = "1f1d0ccd65d3a1caa86dc79d2863a8f067c8e3f8"
17
18# omxplayer builds its own copy of ffmpeg from source instead of using the
19# system's ffmpeg library. This isn't ideal but it's ok for now. We do however
20# want to keep control of the exact version of ffmpeg used instead of just
21# fetching the latest commit on a release branch (which is what the checkout job
22# in Makefile.ffmpeg in the omxplayer source tree does).
23#
24# This SRCREV corresponds to the v4.0.3 release of ffmpeg.
25SRCREV_ffmpeg = "fcbd117df3077bad495e99e20f01cf93737bce76"
26
27SRC_URI = "git://github.com/popcornmix/omxplayer.git;protocol=https;branch=master \
28           git://github.com/FFmpeg/FFmpeg;branch=release/4.0;protocol=https;depth=1;name=ffmpeg;destsuffix=git/ffmpeg \
29           file://0002-Libraries-and-headers-from-ffmpeg-are-installed-in-u.patch \
30           file://0003-Remove-strip-step-in-Makefile.patch \
31           file://0004-Add-FFMPEG_EXTRA_CFLAGS-and-FFMPEG_EXTRA_LDFLAGS.patch \
32           file://fix-tar-command-with-DIST.patch \
33           file://use-native-pkg-config.patch \
34           file://0005-Don-t-require-internet-connection-during-build.patch \
35           file://0006-Prevent-ffmpeg-configure-compile-race-condition.patch \
36           file://0001-Specify-cc-cxx-and-ld-variables-from-environment.patch \
37           file://cross-crompile-ffmpeg.patch \
38           file://0007-Remove-Makefile-hardcoded-arch-tune.patch \
39           "
40
41SRC_URI:append = "${@bb.utils.contains("MACHINE_FEATURES", "vc4graphics", " file://0001-Fix-build-with-vc4-driver.patch ", "", d)}"
42
43S = "${WORKDIR}/git"
44
45COMPATIBLE_MACHINE = "^rpi$"
46COMPATIBLE_HOST:aarch64 = "null"
47
48def cpu(d):
49    for arg in (d.getVar('TUNE_CCARGS') or '').split():
50        if arg.startswith('-mcpu='):
51            return arg[6:]
52    return 'generic'
53
54export CPU = "${@cpu(d)}"
55
56inherit autotools-brokensep pkgconfig
57
58# This isn't used directly by omxplayer, but applied to Makefile.ffmpeg which
59# runs the ffmpeg configuration
60PACKAGECONFIG ??= ""
61PACKAGECONFIG[samba] = "--enable-libsmbclient,--disable-libsmbclient,samba"
62
63# Needed in ffmpeg configure
64export TEMPDIR = "${S}/tmp"
65
66# Needed in Makefile.ffmpeg
67export HOST = "${HOST_SYS}"
68export WORK = "${S}"
69export FFMPEG_EXTRA_CFLAGS  = "${TUNE_CCARGS} ${TOOLCHAIN_OPTIONS}"
70export FFMPEG_EXTRA_LDFLAGS  = "${TUNE_CCARGS} ${TOOLCHAIN_OPTIONS}"
71
72# Needed in top Makefile
73
74export LDFLAGS = "-L${S}/ffmpeg_compiled/usr/lib \
75                  -L${STAGING_DIR_HOST}/lib \
76                  -L${STAGING_DIR_HOST}/usr/lib \
77                 "
78export INCLUDES = "${@bb.utils.contains("MACHINE_FEATURES", "vc4graphics", " -D__GBM__", "", d)} \
79                   -isystem${STAGING_DIR_HOST}/usr/include/interface/vcos/pthreads \
80                   -isystem${STAGING_DIR_HOST}/usr/include/freetype2 \
81                   -isystem${STAGING_DIR_HOST}/usr/include/interface/vmcs_host/linux \
82                   -isystem${STAGING_DIR_HOST}/usr/include/dbus-1.0 \
83                   -isystem${STAGING_DIR_HOST}/usr/lib/dbus-1.0/include \
84                  "
85export DIST = "${D}"
86
87do_compile() {
88    bbwarn "omxplayer is being deprecated and resources are directed at improving vlc."
89
90    # Needed for compiler test in ffmpeg's configure
91    mkdir -p tmp
92
93    sed -i 's/--enable-libsmbclient/${@bb.utils.contains("PACKAGECONFIG", "samba", "--enable-libsmbclient", "--disable-libsmbclient", d)}/g' Makefile.ffmpeg
94
95    oe_runmake -f Makefile.ffmpeg
96    oe_runmake -f Makefile.ffmpeg install
97    oe_runmake
98}
99
100do_install() {
101    oe_runmake STRIP='echo skipping strip' dist
102    mkdir -p ${D}${datadir}/fonts/truetype/freefont/
103    install ${S}/fonts/* ${D}${datadir}/fonts/truetype/freefont/
104}
105
106FILES:${PN} = "${bindir}/omxplayer* \
107               ${libdir}/omxplayer/lib*${SOLIBS} \
108               ${datadir}/fonts"
109
110FILES:${PN}-dev += "${libdir}/omxplayer/*.so"
111
112RDEPENDS:${PN} += "bash procps userland"
113