xref: /openbmc/openbmc/poky/meta/conf/bitbake.conf (revision 44b3caf2) 
1##################################################################
2# Standard target filesystem paths.
3##################################################################
4#
5# If changing these values, beware that native/cross/nativesdk bbclass
6# files may also need changes to keep in sync.
7#
8
9# Used by multilib code to change the library paths
10baselib = "${BASELIB}"
11baselib[vardepvalue] = "${baselib}"
12BASELIB = "lib"
13BASELIB:libc-glibc:powerpc64 = "lib64"
14BASELIB:libc-glibc:powerpc64le = "lib64"
15
16# Path prefixes
17export base_prefix = ""
18export prefix = "/usr"
19export exec_prefix = "${prefix}"
20
21root_prefix = "${@bb.utils.contains('DISTRO_FEATURES', 'usrmerge', '${exec_prefix}', '${base_prefix}', d)}"
22
23# Base paths
24export base_bindir = "${root_prefix}/bin"
25export base_sbindir = "${root_prefix}/sbin"
26export base_libdir = "${root_prefix}/${baselib}"
27export nonarch_base_libdir = "${root_prefix}/lib"
28
29# Architecture independent paths
30export sysconfdir = "${base_prefix}/etc"
31export servicedir = "${base_prefix}/srv"
32export sharedstatedir = "${base_prefix}/com"
33export localstatedir = "${base_prefix}/var"
34runtimedir = "${base_prefix}/run"
35export datadir = "${prefix}/share"
36export infodir = "${datadir}/info"
37export mandir = "${datadir}/man"
38export docdir = "${datadir}/doc"
39export systemd_unitdir = "${nonarch_base_libdir}/systemd"
40export systemd_system_unitdir = "${nonarch_base_libdir}/systemd/system"
41export nonarch_libdir = "${exec_prefix}/lib"
42export systemd_user_unitdir = "${nonarch_libdir}/systemd/user"
43
44# Architecture dependent paths
45export bindir = "${exec_prefix}/bin"
46export sbindir = "${exec_prefix}/sbin"
47export libdir = "${exec_prefix}/${baselib}"
48export libexecdir = "${exec_prefix}/libexec"
49export includedir = "${exec_prefix}/include"
50localedir = "${libdir}/locale"
51
52# Linkage between native/cross/nativesdk layouts
53base_bindir_native = "/bin"
54base_sbindir_native = "/sbin"
55sysconfdir_native = "/etc"
56prefix_native = "/usr"
57bindir_native = "${prefix_native}/bin"
58sbindir_native = "${prefix_native}/sbin"
59includedir_native = "${prefix_native}/include"
60libdir_native = "${prefix_native}/lib"
61libexecdir_native = "${prefix_native}/libexec"
62base_libdir_native = "/lib"
63datadir_native = "${prefix_native}/share"
64bindir_cross = "/bin"
65bindir_crossscripts = "${bindir}/crossscripts"
66prefix_nativesdk = "/usr"
67bindir_nativesdk = "${prefix_nativesdk}/bin"
68sbindir_nativesdk = "${prefix_nativesdk}/sbin"
69base_bindir_nativesdk = "/bin"
70base_sbindir_nativesdk = "/sbin"
71includedir_nativesdk = "${prefix_nativesdk}/include"
72libdir_nativesdk = "${prefix_nativesdk}/lib"
73base_libdir_nativesdk = "/lib"
74localstatedir_nativesdk = "/var"
75
76#
77# Cross recipes need to know about the target layout
78# := is used carefully here
79#
80target_datadir := "${datadir}"
81# Used to find env/perl/python
82USRBINPATH = "${bindir}"
83USRBINPATH:class-native = "/usr/bin"
84USRBINPATH:class-nativesdk = "/usr/bin"
85
86# Root home directory
87ROOT_HOME ??= "/home/root"
88
89# If set to boolean true ('yes', 'y', 'true', 't', '1'), /var/log links to /var/volatile/log.
90# If set to boolean false ('no', 'n', 'false', 'f', '0'), /var/log is on persistent storage.
91VOLATILE_LOG_DIR ?= "yes"
92
93# if set to 'yes': /tmp links to /var/tmp which links to /var/volatile/tmp
94# otherwise:       /tmp is on persistent storage
95VOLATILE_TMP_DIR ?= "yes"
96
97BB_RENAMED_VARIABLES[PNBLACKLIST] = "SKIP_RECIPE"
98BB_RENAMED_VARIABLES[CVE_CHECK_PN_WHITELIST] = "CVE_CHECK_SKIP_RECIPE"
99BB_RENAMED_VARIABLES[CVE_CHECK_WHITELIST] = "CVE_CHECK_IGNORE"
100BB_RENAMED_VARIABLES[MULTI_PROVIDER_WHITELIST] = "BB_MULTI_PROVIDER_ALLOWED"
101BB_RENAMED_VARIABLES[PNBLACKLIST] = "SKIP_RECIPE"
102BB_RENAMED_VARIABLES[SDK_LOCAL_CONF_BLACKLIST] = "ESDK_LOCALCONF_REMOVE"
103BB_RENAMED_VARIABLES[SDK_LOCAL_CONF_WHITELIST] = "ESDK_LOCALCONF_ALLOW"
104BB_RENAMED_VARIABLES[SDK_INHERIT_BLACKLIST] = "ESDK_CLASS_INHERIT_DISABLE"
105BB_RENAMED_VARIABLES[SSTATE_DUPWHITELIST] = "SSTATE_ALLOW_OVERLAP_FILES"
106BB_RENAMED_VARIABLES[SYSROOT_DIRS_BLACKLIST] = "SYSROOT_DIRS_IGNORE"
107BB_RENAMED_VARIABLES[UNKNOWN_CONFIGURE_WHITELIST] = "UNKNOWN_CONFIGURE_OPT_IGNORE"
108BB_RENAMED_VARIABLES[ICECC_USER_CLASS_BL] = "ICECC_CLASS_DISABLE"
109BB_RENAMED_VARIABLES[ICECC_SYSTEM_CLASS_BL] = "ICECC_CLASS_DISABLE"
110BB_RENAMED_VARIABLES[ICECC_USER_PACKAGE_WL] = "ICECC_RECIPE_ENABLE"
111BB_RENAMED_VARIABLES[ICECC_USER_PACKAGE_BL] = "ICECC_RECIPE_DISABLE"
112BB_RENAMED_VARIABLES[ICECC_SYSTEM_PACKAGE_BL] = "ICECC_RECIPE_DISABLE"
113BB_RENAMED_VARIABLES[INHERIT_BLACKLIST] = "is a deprecated variable and no longer needed"
114BB_RENAMED_VARIABLES[TUNEABI_WHITELIST] = "is a deprecated variable and support has been removed"
115BB_RENAMED_VARIABLES[LICENSE_FLAGS_WHITELIST] = "LICENSE_FLAGS_ACCEPTED"
116
117BB_RENAMED_VARIABLES[WHITELIST_GPL-3.0-only] = "INCOMPATIBLE_LICENSE_EXCEPTIONS"
118BB_RENAMED_VARIABLES[WHITELIST_GPL-3.0-or-later] = "INCOMPATIBLE_LICENSE_EXCEPTIONS"
119BB_RENAMED_VARIABLES[WHITELIST_LGPL-3.0-only] = "INCOMPATIBLE_LICENSE_EXCEPTIONS"
120BB_RENAMED_VARIABLES[WHITELIST_LGPL-3.0-or-later] = "INCOMPATIBLE_LICENSE_EXCEPTIONS"
121
122# These are deprecated version and should be updated to approved names
123BB_RENAMED_VARIABLES[WHITELIST_GPL-3.0] = "is deprecated, convert to INCOMPATIBLE_LICENSE_EXCEPTIONS = '<pkg>:GPL-3.0-only'"
124BB_RENAMED_VARIABLES[WHITELIST_GPL-3.0+] = "is deprecated, convert to INCOMPATIBLE_LICENSE_EXCEPTIONS = '<pkg>:GPL-3.0-or-later'"
125BB_RENAMED_VARIABLES[WHITELIST_LGPL-3.0] = "is deprecated, convert to INCOMPATIBLE_LICENSE_EXCEPTIONS = '<pkg>:LGPL-3.0-only'"
126BB_RENAMED_VARIABLES[WHITELIST_LGPL-3.0+] = "is deprecated, convert to INCOMPATIBLE_LICENSE_EXCEPTIONS = '<pkg>:LGPL-3.0-or-later'"
127
128##################################################################
129# Architecture-dependent build variables.
130##################################################################
131
132# Immediate expansion since there is no point in repeatedly calling
133# os.uname() throughout parsing
134BUILD_ARCH := "${@os.uname()[4]}"
135BUILD_OS := "${@os.uname()[0].lower()}"
136BUILD_VENDOR = ""
137BUILD_SYS = "${BUILD_ARCH}${BUILD_VENDOR}-${BUILD_OS}"
138BUILD_PREFIX = ""
139BUILD_CC_ARCH = ""
140BUILD_LD_ARCH = ""
141BUILD_AS_ARCH = ""
142BUILD_EXEEXT = ""
143
144HOST_ARCH = "${TARGET_ARCH}"
145HOST_OS = "${TARGET_OS}"
146HOST_VENDOR = "${TARGET_VENDOR}"
147HOST_SYS = "${HOST_ARCH}${HOST_VENDOR}-${HOST_OS}"
148HOST_PREFIX = "${TARGET_PREFIX}"
149HOST_CC_ARCH = "${TARGET_CC_ARCH}"
150HOST_LD_ARCH = "${TARGET_LD_ARCH}"
151HOST_AS_ARCH = "${TARGET_AS_ARCH}"
152HOST_EXEEXT = ""
153
154TUNE_ARCH ??= "INVALID"
155TUNE_CCARGS ??= ""
156TUNE_CCARGS[vardepvalue] = "${TUNE_CCARGS}"
157TUNE_LDARGS ??= ""
158TUNE_ASARGS ??= ""
159TUNE_FEATURES ??= "${TUNE_FEATURES:tune-${DEFAULTTUNE}}"
160LIBCEXTENSION ??= ""
161ABIEXTENSION ??= ""
162USE_NLS ??= "yes"
163SDKUSE_NLS ??= "yes"
164
165TARGET_ARCH = "${TUNE_ARCH}"
166TARGET_OS = "linux${LIBCEXTENSION}${ABIEXTENSION}"
167TARGET_VENDOR = "-oe"
168TARGET_SYS = "${TARGET_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
169TARGET_PREFIX = "${TARGET_SYS}-"
170TARGET_CC_ARCH = "${TUNE_CCARGS}"
171TARGET_LD_ARCH = "${TUNE_LDARGS}"
172TARGET_AS_ARCH = "${TUNE_ASARGS}"
173
174SDKMACHINE ??= "${BUILD_ARCH}"
175SDK_OS = "${BUILD_OS}"
176SDK_VENDOR = "-oesdk"
177SDK_SYS = "${SDK_ARCH}${SDK_VENDOR}-${SDK_OS}"
178SDK_PREFIX = "${SDK_SYS}-"
179SDK_CC_ARCH = "${BUILD_CC_ARCH}"
180SDKPKGSUFFIX = "nativesdk"
181SDK_PACKAGE_ARCHS = "all any noarch ${SDK_ARCH}-${SDKPKGSUFFIX}"
182SDK_LD_ARCH = "${BUILD_LD_ARCH}"
183SDK_AS_ARCH = "${BUILD_AS_ARCH}"
184
185TUNE_PKGARCH ??= ""
186PACKAGE_ARCH ??= "${TUNE_PKGARCH}"
187MACHINE_ARCH = "${@[d.getVar('TUNE_PKGARCH'), d.getVar('MACHINE')][bool(d.getVar('MACHINE'))].replace('-', '_')}"
188PACKAGE_EXTRA_ARCHS ??= "${PACKAGE_EXTRA_ARCHS:tune-${DEFAULTTUNE}}"
189PACKAGE_ARCHS = "all any noarch ${PACKAGE_EXTRA_ARCHS} ${MACHINE_ARCH}"
190# MACHINE_ARCH shouldn't be included here as a variable dependency
191# since machine specific packages are handled using multimachine
192PACKAGE_ARCHS[vardepsexclude] = "MACHINE_ARCH"
193
194MULTIMACH_TARGET_SYS = "${PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
195
196##################################################################
197# Date/time variables.
198##################################################################
199
200DATE := "${@time.strftime('%Y%m%d',time.gmtime())}"
201TIME := "${@time.strftime('%H%M%S',time.gmtime())}"
202DATETIME = "${DATE}${TIME}"
203
204##################################################################
205# Openembedded Software Prerequisites.
206##################################################################
207
208# python-native should be here but python relies on building
209# its own in staging
210ASSUME_PROVIDED = "\
211    bash-native \
212    bzip2-native \
213    chrpath-native \
214    diffstat-native \
215    file-native \
216    findutils-native \
217    gawk-native \
218    git-native \
219    grep-native \
220    hostperl-runtime-native \
221    hostpython-runtime-native \
222    libgcc-native \
223    patch-native \
224    sed-native \
225    tar-native \
226    texinfo-native \
227    virtual/crypt-native \
228    virtual/libiconv-native \
229    virtual/libintl-native \
230    wget-native \
231    "
232# gzip-native should be listed above?
233
234##################################################################
235# Package default variables.
236##################################################################
237
238PN = "${@bb.parse.vars_from_file(d.getVar('FILE', False),d)[0] or 'defaultpkgname'}"
239PV = "${@bb.parse.vars_from_file(d.getVar('FILE', False),d)[1] or '1.0'}"
240PR = "r0"
241PE = ""
242PF = "${PN}-${EXTENDPE}${PV}-${PR}"
243EXTENDPE = "${@['','${PE}_'][int(d.getVar('PE') or 0) > 0]}"
244P = "${PN}-${PV}"
245
246PRSERV_PV_AUTOINC = "AUTOINC"
247PRAUTO = ""
248EXTENDPRAUTO = "${@['.${PRAUTO}', ''][not d.getVar('PRAUTO')]}"
249PRAUTOINX = "${PF}"
250
251PKGV ?= "${PV}"
252PKGR ?= "${PR}${EXTENDPRAUTO}"
253PKGE ?= "${@['','${PE}'][int(d.getVar('PE') or 0) > 0]}"
254EXTENDPKGEVER = "${@['','${PKGE}:'][d.getVar('PKGE').strip() != '']}"
255EXTENDPKGV ?= "${EXTENDPKGEVER}${PKGV}-${PKGR}"
256
257# Base package name
258# Automatically derives "foo" from "foo-native", "foo-cross" or "foo-initial"
259# otherwise it is the same as PN and P
260SPECIAL_PKGSUFFIX = "-native -cross -initial -intermediate -crosssdk -cross-canadian"
261BPN = "${@oe.utils.prune_suffix(d.getVar('PN'), d.getVar('SPECIAL_PKGSUFFIX').split(), d)}"
262BP = "${BPN}-${PV}"
263
264# Package info.
265
266SECTION = "base"
267PRIORITY = "optional"
268SUMMARY ?= "${PN} version ${PV}-${PR}"
269DESCRIPTION ?= "${SUMMARY}."
270
271# The following two are commented out because they result in a recursive
272# definition of the variable in some corner cases.  These are left in
273# to illustrate the intended behavior.
274#SUMMARY:${PN} ?= "${SUMMARY}"
275#DESCRIPTION:${PN} ?= "${DESCRIPTION}"
276
277SUMMARY:${PN}-src ?= "${SUMMARY} - Source files"
278DESCRIPTION:${PN}-src ?= "${DESCRIPTION}  \
279This package contains sources for debugging purposes."
280
281SUMMARY:${PN}-dbg ?= "${SUMMARY} - Debugging files"
282DESCRIPTION:${PN}-dbg ?= "${DESCRIPTION}  \
283This package contains ELF symbols and related sources for debugging purposes."
284
285SUMMARY:${PN}-dev ?= "${SUMMARY} - Development files"
286DESCRIPTION:${PN}-dev ?= "${DESCRIPTION}  \
287This package contains symbolic links, header files, and \
288related items necessary for software development."
289
290SUMMARY:${PN}-staticdev ?= "${SUMMARY} - Development files (Static Libraries)"
291DESCRIPTION:${PN}-staticdev ?= "${DESCRIPTION}  \
292This package contains static libraries for software development."
293
294SUMMARY:${PN}-doc ?= "${SUMMARY} - Documentation files"
295DESCRIPTION:${PN}-doc ?= "${DESCRIPTION}  \
296This package contains documentation."
297
298LICENSE ??= "INVALID"
299MAINTAINER = "OE-Core Developers <openembedded-core@lists.openembedded.org>"
300HOMEPAGE = ""
301
302# Package dependencies and provides.
303
304# Ensure that -dev packages recommend the corresponding -dev packages of their
305# deps, and the same for -dbg.
306DEPCHAIN_PRE = ""
307DEPCHAIN_POST = "-dev -dbg"
308
309DEPENDS = ""
310PROVIDES = ""
311PROVIDES:prepend = "${PN} "
312
313BB_MULTI_PROVIDER_ALLOWED = "virtual/libintl virtual/libintl-native virtual/nativesdk-libintl virtual/xserver virtual/update-alternatives-native virtual/update-alternatives"
314
315SOLIBS = ".so.*"
316SOLIBS:darwin = ".dylib"
317
318SOLIBSDEV = ".so"
319# Due to the ordering of PACKAGES and the naming of the dev symlinks on darwin,
320# we can't make the symlinks end up in the -dev packages easily at this point. This hack
321# at least means builds aren't completely broken and symlinks don't take up much space.
322SOLIBSDEV:darwin = ".dylibbroken"
323
324PACKAGE_DEBUG_SPLIT_STYLE ?= "debug-with-srcpkg"
325
326PACKAGE_BEFORE_PN ?= ""
327PACKAGES = "${PN}-src ${PN}-dbg ${PN}-staticdev ${PN}-dev ${PN}-doc ${PN}-locale ${PACKAGE_BEFORE_PN} ${PN}"
328PACKAGES_DYNAMIC = "^${PN}-locale-.*"
329FILES = ""
330
331FILES:${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*${SOLIBS} \
332            ${sysconfdir} ${sharedstatedir} ${localstatedir} \
333            ${base_bindir}/* ${base_sbindir}/* \
334            ${base_libdir}/*${SOLIBS} \
335            ${base_prefix}/lib/udev ${prefix}/lib/udev \
336            ${base_libdir}/udev ${libdir}/udev \
337            ${datadir}/${BPN} ${libdir}/${BPN}/* \
338            ${datadir}/pixmaps ${datadir}/applications \
339            ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
340            ${libdir}/bonobo/servers"
341
342FILES:${PN}-bin = "${bindir}/* ${sbindir}/*"
343
344FILES:${PN}-doc = "${docdir} ${mandir} ${infodir} ${datadir}/gtk-doc \
345            ${datadir}/gnome/help"
346SECTION:${PN}-doc = "doc"
347
348FILES_SOLIBSDEV ?= "${base_libdir}/lib*${SOLIBSDEV} ${libdir}/lib*${SOLIBSDEV}"
349FILES:${PN}-dev = "${includedir} ${FILES_SOLIBSDEV} ${libdir}/*.la \
350                ${libdir}/*.o ${libdir}/pkgconfig ${datadir}/pkgconfig \
351                ${datadir}/aclocal ${base_libdir}/*.o \
352                ${libdir}/${BPN}/*.la ${base_libdir}/*.la \
353                ${libdir}/cmake ${datadir}/cmake"
354SECTION:${PN}-dev = "devel"
355ALLOW_EMPTY:${PN}-dev = "1"
356DEV_PKG_DEPENDENCY = "${PN} (= ${EXTENDPKGV})"
357RRECOMMENDS:${PN}-dev = "${DEV_PKG_DEPENDENCY}"
358
359FILES:${PN}-staticdev = "${libdir}/*.a ${base_libdir}/*.a ${libdir}/${BPN}/*.a"
360SECTION:${PN}-staticdev = "devel"
361RDEPENDS:${PN}-staticdev = "${PN}-dev (= ${EXTENDPKGV})"
362
363FILES:${PN}-dbg = "/usr/lib/debug /usr/lib/debug-static /usr/src/debug"
364SECTION:${PN}-dbg = "devel"
365ALLOW_EMPTY:${PN}-dbg = "1"
366
367# The files list for source packages are dynamically set based on
368# PACKAGE_DEBUG_SPLIT_STYLE
369FILES:${PN}-src = ""
370SECTION:${PN}-src = "devel"
371
372FILES:${PN}-locale = "${datadir}/locale"
373
374# File manifest
375
376FILE_DIRNAME = "${@os.path.dirname(d.getVar('FILE', False))}"
377# FILESPATH is set in base.bbclass
378#FILESPATH = "${FILE_DIRNAME}/${PF}:${FILE_DIRNAME}/${P}:${FILE_DIRNAME}/${PN}:${FILE_DIRNAME}/${BP}:${FILE_DIRNAME}/${BPN}:${FILE_DIRNAME}/files:${FILE_DIRNAME}"
379# This default was only used for checking
380FILESEXTRAPATHS ?= "__default:"
381
382# The default list of fs-perms files to process.  If the list is empty only
383# the builtin definitions will be used.  Builtin definitions included:
384#  base_prefix, prefix, exec_prefix, base_bindir, base_sbindir, base_libdir,
385#  datadir, sysconfdir, servicedir, sharedstatedir, localstatedir, infodir,
386#  mandir, docdir, bindir, sbindir, libexecdir, libdir and includedir
387FILESYSTEM_PERMS_TABLES ?= "${@'files/fs-perms.txt' if oe.types.boolean(d.getVar('VOLATILE_LOG_DIR')) else 'files/fs-perms-persistent-log.txt'}"
388
389##################################################################
390# General work and output directories for the build system.
391##################################################################
392
393TCMODE ??= "default"
394TCLIBC ??= "glibc"
395TC_CXX_RUNTIME ??= "gnu"
396TMPDIR ?= "${TOPDIR}/tmp"
397
398CACHE = "${TMPDIR}/cache"
399# The persistent cache should be shared by all builds
400PERSISTENT_DIR = "${TOPDIR}/cache"
401LOG_DIR = "${TMPDIR}/log"
402
403STAMPS_DIR ?= "${TMPDIR}/stamps"
404STAMP = "${STAMPS_DIR}/${MULTIMACH_TARGET_SYS}/${PN}/${PV}"
405STAMPCLEAN = "${STAMPS_DIR}/${MULTIMACH_TARGET_SYS}/${PN}/*-*"
406BASE_WORKDIR ?= "${TMPDIR}/work"
407WORKDIR = "${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}/${PN}/${PV}"
408T = "${WORKDIR}/temp"
409D = "${WORKDIR}/image"
410S = "${WORKDIR}/${BP}"
411B = "${S}"
412
413STAGING_DIR = "${TMPDIR}/sysroots"
414COMPONENTS_DIR = "${STAGING_DIR}-components"
415RECIPE_SYSROOT = "${WORKDIR}/recipe-sysroot"
416RECIPE_SYSROOT_NATIVE = "${WORKDIR}/recipe-sysroot-native"
417
418STAGING_DIR_NATIVE = "${RECIPE_SYSROOT_NATIVE}"
419STAGING_BINDIR_NATIVE = "${STAGING_DIR_NATIVE}${bindir_native}"
420STAGING_BINDIR_CROSS = "${STAGING_BINDIR}/crossscripts"
421STAGING_BINDIR_TOOLCHAIN = "${STAGING_DIR_NATIVE}${bindir_native}/${TARGET_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
422STAGING_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${libdir_native}"
423STAGING_LIBEXECDIR_NATIVE = "${STAGING_DIR_NATIVE}${libexecdir_native}"
424STAGING_BASE_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${base_libdir_native}"
425STAGING_SBINDIR_NATIVE = "${STAGING_DIR_NATIVE}${sbindir_native}"
426STAGING_INCDIR_NATIVE = "${STAGING_DIR_NATIVE}${includedir_native}"
427STAGING_ETCDIR_NATIVE = "${STAGING_DIR_NATIVE}${sysconfdir_native}"
428STAGING_DATADIR_NATIVE = "${STAGING_DIR_NATIVE}${datadir_native}"
429
430STAGING_DIR_HOST = "${RECIPE_SYSROOT}"
431STAGING_BINDIR = "${STAGING_DIR_HOST}${bindir}"
432STAGING_LIBDIR = "${STAGING_DIR_HOST}${libdir}"
433STAGING_LIBEXECDIR = "${STAGING_DIR_HOST}${libexecdir}"
434STAGING_BASELIBDIR = "${STAGING_DIR_HOST}${base_libdir}"
435STAGING_INCDIR = "${STAGING_DIR_HOST}${includedir}"
436STAGING_DATADIR = "${STAGING_DIR_HOST}${datadir}"
437STAGING_EXECPREFIXDIR = "${STAGING_DIR_HOST}${exec_prefix}"
438STAGING_LOADER_DIR = "${STAGING_DIR_HOST}/loader"
439STAGING_FIRMWARE_DIR = "${STAGING_DIR_HOST}/firmware"
440
441STAGING_DIR_TARGET = "${RECIPE_SYSROOT}"
442
443# Setting DEPLOY_DIR outside of TMPDIR is helpful, when you are using
444# packaged staging and/or multimachine.
445DEPLOY_DIR ?= "${TMPDIR}/deploy"
446DEPLOY_DIR_IPK = "${DEPLOY_DIR}/ipk"
447DEPLOY_DIR_RPM = "${DEPLOY_DIR}/rpm"
448DEPLOY_DIR_DEB = "${DEPLOY_DIR}/deb"
449DEPLOY_DIR_IMAGE ?= "${DEPLOY_DIR}/images/${MACHINE}"
450DEPLOY_DIR_TOOLS = "${DEPLOY_DIR}/tools"
451
452PKGDATA_DIR = "${TMPDIR}/pkgdata/${MACHINE}"
453PKGDATA_DIR_SDK = "${TMPDIR}/pkgdata/${SDK_SYS}"
454
455##################################################################
456# SDK variables.
457##################################################################
458
459SDK_NAME_PREFIX ?= "oecore"
460SDK_NAME = "${SDK_NAME_PREFIX}-${IMAGE_BASENAME}-${SDK_ARCH}-${TUNE_PKGARCH}-${MACHINE}"
461SDKPATH = "/usr/local/oe-sdk-hardcoded-buildpath"
462SDKPATHNATIVE = "${SDKPATH}/sysroots/${SDK_SYS}"
463# The path to default to installing the SDK to
464SDKPATHINSTALL = "/usr/local/${SDK_NAME_PREFIX}-${SDK_ARCH}"
465
466##################################################################
467# Kernel info.
468##################################################################
469
470OLDEST_KERNEL = "5.15"
471
472# SDK_OLDEST_KERNEL can't be set using overrides since there are
473# none for the SDK architecture. Best to set it from a machine-sdk
474# include file if you need an SDK arch-specific value
475SDK_OLDEST_KERNEL = "3.2.0"
476
477# Define where the kernel headers are installed on the target as well as where
478# they are staged.
479KERNEL_SRC_PATH = "/usr/src/kernel"
480
481STAGING_KERNEL_DIR = "${TMPDIR}/work-shared/${MACHINE}/kernel-source"
482STAGING_KERNEL_BUILDDIR = "${TMPDIR}/work-shared/${MACHINE}/kernel-build-artifacts"
483
484##################################################################
485# Specific image creation and rootfs population info.
486##################################################################
487
488IMAGE_ROOTFS = "${WORKDIR}/rootfs"
489
490# This option allows for a percentage overage of the actual image size rather than a
491# fixed extra space, this is space needed for initial startup and basic operations.
492IMAGE_OVERHEAD_FACTOR ?= "1.3"
493# This option allows for adding additional space in K above and beyond what the
494# IMAGE_OVERHEAD_FACTOR might add. This space is for additional packages, user data, ...
495# To set a fixed size then overriding IMAGE_ROOTFS_SIZE with the max size one wants
496# should do the trick
497IMAGE_ROOTFS_EXTRA_SPACE ?= "0"
498
499EXTRA_IMAGEDEPENDS = ""
500
501##################################################################
502# Toolchain info.
503##################################################################
504
505PATH:prepend = "${COREBASE}/scripts:${STAGING_BINDIR_TOOLCHAIN}:${STAGING_BINDIR_CROSS}:${STAGING_DIR_NATIVE}${sbindir_native}:${STAGING_BINDIR_NATIVE}:${STAGING_DIR_NATIVE}${base_sbindir_native}:${STAGING_DIR_NATIVE}${base_bindir_native}:"
506export PATH
507
508##################################################################
509# Build utility info.
510##################################################################
511
512# Directory with symlinks to host tools used by build
513HOSTTOOLS_DIR = "${TMPDIR}/hosttools"
514
515# Tools needed to run builds with OE-Core
516HOSTTOOLS += " \
517    [ ar as awk basename bash bunzip2 bzip2 cat chgrp chmod chown chrpath cmp comm cp cpio \
518    cpp cut date dd diff diffstat dirname du echo egrep env expand expr false \
519    fgrep file find flock g++ gawk gcc getconf getopt git grep gunzip gzip \
520    head hostname iconv id install ld ldd ln ls lz4c make md5sum mkdir mkfifo mknod \
521    mktemp mv nm objcopy objdump od patch perl pr printf pwd \
522    python3 pzstd ranlib readelf readlink realpath rm rmdir rpcgen sed seq sh \
523    sha1sum sha224sum sha256sum sha384sum sha512sum \
524    sleep sort split stat strings strip tail tar tee test touch tr true uname \
525    uniq unzstd wc wget which xargs zstd \
526"
527
528# Tools needed to run testimage runtime image testing
529HOSTTOOLS += "${@'ip ping ps scp ssh stty' if (bb.utils.contains_any('IMAGE_CLASSES', 'testimage testsdk', True, False, d) or any(x in (d.getVar("BBINCLUDED") or "") for x in ["testimage.bbclass", "testsdk.bbclass"])) else ''}"
530
531# Used by archiver.bbclass when compression is xz
532HOSTTOOLS += "${@'xz' if (('archiver.bbclass' in (d.getVar('BBINCLUDED') or '')) and (d.getVarFlag('ARCHIVER_MODE', 'compression') == 'xz')) else ''}"
533
534# Link to these if present
535HOSTTOOLS_NONFATAL += "aws gcc-ar gpg gpg-agent ld.bfd ld.gold nc pigz sftp socat ssh sudo"
536
537# Temporary add few more detected in bitbake world
538HOSTTOOLS_NONFATAL += "join nl size yes zcat"
539
540# Used by bzr fetcher
541HOSTTOOLS_NONFATAL += "bzr"
542
543# Used by ssh fetcher
544HOSTTOOLS_NONFATAL += "scp"
545
546# Used by Mercurial fetcher
547HOSTTOOLS_NONFATAL += "hg"
548
549# Used by gcp fetcher
550HOSTTOOLS_NONFATAL += "gsutil"
551
552# Link to git-lfs if present
553HOSTTOOLS_NONFATAL += "git-lfs"
554
555CCACHE ??= ""
556
557TOOLCHAIN_OPTIONS = " --sysroot=${STAGING_DIR_TARGET}"
558
559export CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
560export CXX = "${CCACHE}${HOST_PREFIX}g++ ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
561export FC = "${HOST_PREFIX}gfortran ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
562export CPP = "${HOST_PREFIX}gcc -E${TOOLCHAIN_OPTIONS} ${HOST_CC_ARCH}"
563export LD = "${HOST_PREFIX}ld${TOOLCHAIN_OPTIONS} ${HOST_LD_ARCH}"
564export CCLD = "${CC}"
565export AR = "${HOST_PREFIX}gcc-ar"
566export AS = "${HOST_PREFIX}as ${HOST_AS_ARCH}"
567export RANLIB = "${HOST_PREFIX}gcc-ranlib"
568export STRIP = "${HOST_PREFIX}strip"
569export OBJCOPY = "${HOST_PREFIX}objcopy"
570export OBJDUMP = "${HOST_PREFIX}objdump"
571export STRINGS = "${HOST_PREFIX}strings"
572export NM = "${HOST_PREFIX}gcc-nm"
573export READELF = "${HOST_PREFIX}readelf"
574PYTHON = "${@sys.executable}"
575
576export BUILD_CC = "${CCACHE}${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
577export BUILD_CXX = "${CCACHE}${BUILD_PREFIX}g++ ${BUILD_CC_ARCH}"
578export BUILD_FC = "${BUILD_PREFIX}gfortran ${BUILD_CC_ARCH}"
579export BUILD_CPP = "${BUILD_PREFIX}gcc ${BUILD_CC_ARCH} -E"
580export BUILD_LD = "${BUILD_PREFIX}ld ${BUILD_LD_ARCH}"
581export BUILD_CCLD = "${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
582export BUILD_AR = "${BUILD_PREFIX}ar"
583export BUILD_AS = "${BUILD_PREFIX}as ${BUILD_AS_ARCH}"
584export BUILD_RANLIB = "${BUILD_PREFIX}ranlib -D"
585export BUILD_STRIP = "${BUILD_PREFIX}strip"
586BUILD_OBJCOPY = "${BUILD_PREFIX}objcopy"
587BUILD_OBJDUMP = "${BUILD_PREFIX}objdump"
588export BUILD_NM = "${BUILD_PREFIX}nm"
589BUILD_READELF = "${BUILD_PREFIX}readelf"
590
591export MAKE = "make"
592EXTRA_OEMAKE = ""
593EXTRA_OECONF = ""
594export LC_ALL = "en_US.UTF-8"
595export TZ = 'UTC'
596
597##################################################################
598# Patch handling.
599##################################################################
600PATCHTOOL = "quilt"
601PATCHRESOLVE = "noop"
602
603##################################################################
604# Build flags and options.
605##################################################################
606
607export BUILD_CPPFLAGS = "-isystem${STAGING_INCDIR_NATIVE}"
608BUILDSDK_CPPFLAGS = ""
609export CPPFLAGS = "${TARGET_CPPFLAGS}"
610TARGET_CPPFLAGS = ""
611
612export BUILD_CFLAGS = "${BUILD_CPPFLAGS} ${BUILD_OPTIMIZATION}"
613BUILDSDK_CFLAGS = "${BUILDSDK_CPPFLAGS} ${BUILD_OPTIMIZATION} ${DEBUG_PREFIX_MAP}"
614export CFLAGS = "${TARGET_CFLAGS}"
615TARGET_CFLAGS = "${TARGET_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
616
617export BUILD_CXXFLAGS = "${BUILD_CFLAGS}"
618BUILDSDK_CXXFLAGS = "${BUILDSDK_CFLAGS}"
619export CXXFLAGS = "${TARGET_CXXFLAGS}"
620TARGET_CXXFLAGS = "${TARGET_CFLAGS}"
621
622export BUILD_LDFLAGS = "-L${STAGING_LIBDIR_NATIVE} \
623                        -L${STAGING_BASE_LIBDIR_NATIVE} \
624                        -Wl,--enable-new-dtags \
625                        -Wl,-rpath-link,${STAGING_LIBDIR_NATIVE} \
626                        -Wl,-rpath-link,${STAGING_BASE_LIBDIR_NATIVE} \
627                        -Wl,-rpath,${STAGING_LIBDIR_NATIVE} \
628                        -Wl,-rpath,${STAGING_BASE_LIBDIR_NATIVE} \
629                        -Wl,-O1"
630
631BUILDSDK_LDFLAGS = "-Wl,-O1"
632
633LINKER_HASH_STYLE ??= "gnu"
634
635TARGET_LINK_HASH_STYLE ?= "${@['-Wl,--hash-style=gnu',''][d.getVar('LINKER_HASH_STYLE') != 'gnu']}"
636
637ASNEEDED ?= "-Wl,--as-needed"
638
639export LDFLAGS = "${TARGET_LDFLAGS}"
640TARGET_LDFLAGS = "-Wl,-O1 ${TARGET_LINK_HASH_STYLE} ${ASNEEDED} ${DEBUG_PREFIX_MAP}"
641# mips does not support GNU hash style therefore we override
642LINKER_HASH_STYLE:mipsarch:libc-musl = "sysv"
643
644# Pass parallel make options to the compile task
645EXTRA_OEMAKE:prepend:task-compile = "${PARALLEL_MAKE} "
646PARALLEL_MAKEINST ??= "${PARALLEL_MAKE}"
647PARALLEL_MAKEINST[vardepvalue] = "1"
648# Pass parallel make options to the install task
649EXTRA_OEMAKE:prepend:task-install = "${PARALLEL_MAKEINST} "
650
651##################################################################
652# Optimization flags.
653##################################################################
654TARGET_DBGSRC_DIR ?= "/usr/src/debug/${PN}/${PV}"
655# Beware: applied last to first
656DEBUG_PREFIX_MAP ?= "-fcanon-prefix-map \
657 -fmacro-prefix-map=${S}=${TARGET_DBGSRC_DIR} \
658 -fdebug-prefix-map=${S}=${TARGET_DBGSRC_DIR} \
659 -fmacro-prefix-map=${B}=${TARGET_DBGSRC_DIR} \
660 -fdebug-prefix-map=${B}=${TARGET_DBGSRC_DIR} \
661 -fdebug-prefix-map=${STAGING_DIR_HOST}= \
662 -fmacro-prefix-map=${STAGING_DIR_HOST}= \
663 -fdebug-prefix-map=${STAGING_DIR_NATIVE}= \
664"
665DEBUG_FLAGS ?= "-g -feliminate-unused-debug-types ${DEBUG_PREFIX_MAP}"
666
667# Disabled until the option works properly -feliminate-dwarf2-dups
668FULL_OPTIMIZATION = "-O2 -pipe ${DEBUG_FLAGS}"
669DEBUG_OPTIMIZATION = "-Og ${DEBUG_FLAGS} -pipe"
670SELECTED_OPTIMIZATION = "${@d.getVar(oe.utils.vartrue('DEBUG_BUILD', 'DEBUG_OPTIMIZATION', 'FULL_OPTIMIZATION', d))}"
671SELECTED_OPTIMIZATION[vardeps] += "FULL_OPTIMIZATION DEBUG_OPTIMIZATION DEBUG_BUILD"
672BUILD_OPTIMIZATION = "${@oe.utils.vartrue('DEBUG_BUILD', '-Og -g -feliminate-unused-debug-types', '-O2', d)} -pipe"
673BUILD_OPTIMIZATION[vardeps] += "DEBUG_BUILD"
674
675##################################################################
676# Reproducibility
677##################################################################
678
679SDE_DIR = "${WORKDIR}/source-date-epoch"
680SDE_FILE = "${SDE_DIR}/__source_date_epoch.txt"
681SDE_DEPLOYDIR = "${WORKDIR}/deploy-source-date-epoch"
682
683export PYTHONHASHSEED = "0"
684export PERL_HASH_SEED = "0"
685export SOURCE_DATE_EPOCH ?= "${@get_source_date_epoch_value(d)}"
686# A SOURCE_DATE_EPOCH of '0' might be misinterpreted as no SDE
687SOURCE_DATE_EPOCH_FALLBACK ??= "1302044400"
688REPRODUCIBLE_TIMESTAMP_ROOTFS ??= "1520598896"
689
690##################################################################
691# Settings used by bitbake-layers.
692##################################################################
693BBLAYERS_LAYERINDEX_URL ??= "https://layers.openembedded.org/layerindex/"
694BBLAYERS_FETCH_DIR ??= "${COREBASE}"
695
696##################################################################
697# Download locations and utilities.
698##################################################################
699
700APACHE_MIRROR = "https://archive.apache.org/dist"
701CPAN_MIRROR = "https://search.cpan.org/CPAN"
702DEBIAN_MIRROR = "http://ftp.debian.org/debian/pool"
703GENTOO_MIRROR = "http://distfiles.gentoo.org/distfiles"
704GNOME_GIT = "git://gitlab.gnome.org/GNOME"
705GNOME_MIRROR = "https://download.gnome.org/sources/"
706GNU_MIRROR = "https://ftp.gnu.org/gnu"
707GNUPG_MIRROR = "https://www.gnupg.org/ftp/gcrypt"
708GPE_MIRROR = "http://gpe.linuxtogo.org/download/source"
709KERNELORG_MIRROR = "https://cdn.kernel.org/pub"
710SAMBA_MIRROR = "http://samba.org/samba/ftp"
711SAVANNAH_GNU_MIRROR = "https://download.savannah.gnu.org/releases"
712SAVANNAH_NONGNU_MIRROR = "https://download.savannah.nongnu.org/releases"
713SOURCEFORGE_MIRROR = "https://downloads.sourceforge.net"
714XLIBS_MIRROR = "https://xlibs.freedesktop.org/release"
715XORG_MIRROR = "https://www.x.org/releases/"
716
717SRC_URI[vardepsexclude] += "\
718    APACHE_MIRROR \
719    CPAN_MIRROR \
720    DEBIAN_MIRROR \
721    GENTOO_MIRROR \
722    GNOME_GIT \
723    GNOME_MIRROR \
724    GNU_MIRROR \
725    GNUPG_MIRROR \
726    GPE_MIRROR \
727    KERNELORG_MIRROR \
728    SAMBA_MIRROR \
729    SAVANNAH_GNU_MIRROR \
730    SAVANNAH_NONGNU_MIRROR \
731    SOURCEFORGE_MIRROR \
732    XLIBS_MIRROR \
733    XORG_MIRROR \
734"
735
736# You can use the mirror of your country to get faster downloads by putting
737#  export DEBIAN_MIRROR = "http://ftp.de.debian.org/debian/pool"
738#     into your local.conf
739
740SRCDATE = "${DATE}"
741SRCREV ??= "INVALID"
742AUTOREV = "${@bb.fetch2.get_autorev(d)}"
743SRCPV = ""
744
745SRC_URI = ""
746
747# Use pseudo as the fakeroot implementation
748PSEUDO_LOCALSTATEDIR ?= "${WORKDIR}/pseudo/"
749PSEUDO_PASSWD ?= "${STAGING_DIR_TARGET}:${PSEUDO_SYSROOT}"
750PSEUDO_SYSROOT = "${COMPONENTS_DIR}/${BUILD_ARCH}/pseudo-native"
751PSEUDO_IGNORE_PATHS = "/usr/,/etc/,/lib,/dev/,/run/,${T},${WORKDIR}/recipe-sysroot,${SSTATE_DIR},${STAMPS_DIR}"
752PSEUDO_IGNORE_PATHS .= ",${TMPDIR}/sstate-control,${TMPDIR}/buildstats,${TMPDIR}/sysroots-components,${TMPDIR}/pkgdata"
753PSEUDO_IGNORE_PATHS .= ",${WORKDIR}/deploy-,${WORKDIR}/sstate-build-package_,${WORKDIR}/sstate-install-package_,${WORKDIR}/pkgdata-sysroot"
754PSEUDO_IGNORE_PATHS .= ",${DEPLOY_DIR},${BUILDHISTORY_DIR},${TOPDIR}/cache,${COREBASE}/scripts,${CCACHE_DIR}"
755
756export PSEUDO_DISABLED = "1"
757#export PSEUDO_PREFIX = "${STAGING_DIR_NATIVE}${prefix_native}"
758#export PSEUDO_BINDIR = "${STAGING_DIR_NATIVE}${bindir_native}"
759#export PSEUDO_LIBDIR = "${STAGING_DIR_NATIVE}$PSEUDOBINDIR/../lib/pseudo/lib
760FAKEROOTBASEENV = "PSEUDO_BINDIR=${PSEUDO_SYSROOT}${bindir_native} PSEUDO_LIBDIR=${PSEUDO_SYSROOT}${prefix_native}/lib/pseudo/lib PSEUDO_PREFIX=${PSEUDO_SYSROOT}${prefix_native} PSEUDO_IGNORE_PATHS=${@oe.path.canonicalize(d.getVar('PSEUDO_IGNORE_PATHS'))} PSEUDO_DISABLED=1 PYTHONDONTWRITEBYTECODE=1"
761FAKEROOTCMD = "${PSEUDO_SYSROOT}${bindir_native}/pseudo"
762FAKEROOTENV = "PSEUDO_PREFIX=${PSEUDO_SYSROOT}${prefix_native} PSEUDO_LOCALSTATEDIR=${PSEUDO_LOCALSTATEDIR} PSEUDO_PASSWD=${PSEUDO_PASSWD} PSEUDO_NOSYMLINKEXP=1 PSEUDO_IGNORE_PATHS=${@oe.path.canonicalize(d.getVar('PSEUDO_IGNORE_PATHS'))} PSEUDO_DISABLED=0"
763FAKEROOTNOENV = "PSEUDO_UNLOAD=1"
764FAKEROOTDIRS = "${PSEUDO_LOCALSTATEDIR}"
765FAKEROOTLOGS = "${WORKDIR}/pseudo/pseudo.log"
766PREFERRED_PROVIDER_virtual/fakeroot-native ?= "pseudo-native"
767
768##################################################################
769# Not sure about the rest of this yet.
770##################################################################
771
772# Pre-build configuration output
773BUILDCFG_HEADER = "Build Configuration${@" (mc:${BB_CURRENT_MC})" if d.getVar("BBMULTICONFIG") else ""}:"
774BUILDCFG_VARS = "BB_VERSION BUILD_SYS NATIVELSBSTRING TARGET_SYS MACHINE DISTRO DISTRO_VERSION TUNE_FEATURES TARGET_FPU"
775BUILDCFG_VARS[type] = "list"
776BUILDCFG_NEEDEDVARS = "TARGET_ARCH TARGET_OS"
777BUILDCFG_NEEDEDVARS[type] = "list"
778
779# Other
780
781export PKG_CONFIG_DIR = "${STAGING_DIR_HOST}${libdir}/pkgconfig"
782export PKG_CONFIG_PATH = "${PKG_CONFIG_DIR}:${STAGING_DATADIR}/pkgconfig"
783export PKG_CONFIG_LIBDIR = "${PKG_CONFIG_DIR}"
784export PKG_CONFIG_SYSROOT_DIR = "${STAGING_DIR_HOST}"
785export PKG_CONFIG_DISABLE_UNINSTALLED = "yes"
786export PKG_CONFIG_SYSTEM_LIBRARY_PATH = "${base_libdir}:${libdir}"
787export PKG_CONFIG_SYSTEM_INCLUDE_PATH = "${includedir}"
788
789# Don't allow git to chdir up past WORKDIR so that it doesn't detect the OE
790# repository when building a recipe
791export GIT_CEILING_DIRECTORIES = "${WORKDIR}"
792
793###
794### Config file processing
795###
796
797# An empty distro leads to :: entries in OVERRIDES and FILEOVERRIDES which
798# is a bad idea. Setting a dummy value is better than a ton of anonymous python.
799DISTRO ??= "nodistro"
800DISTRO_NAME ??= "OpenEmbedded"
801
802# Overrides are processed left to right, so the ones that are named later take precedence.
803# You generally want them to go from least to most specific. This means that:
804# A variable '<foo>:arm' overrides a variable '<foo>' when ${TARGET_ARCH} is arm.
805# A variable '<foo>:qemuarm' overrides '<foo>' and overrides '<foo>:arm' when ${MACHINE} is 'qemuarm'.
806# If you use combination ie '<foo>:qemuarm:arm', then '<foo>:qemuarm:arm' will override
807# '<foo>:qemuarm' and then '<foo>' will be overriden with that value from '<foo>:qemuarm'.
808# And finally '<foo>:forcevariable' overrides any standard variable, with the highest priority.
809# This works for functions as well, they are really just variables.
810#
811OVERRIDES = "${TARGET_OS}:${TRANSLATED_TARGET_ARCH}:pn-${PN}:layer-${FILE_LAYERNAME}:${MACHINEOVERRIDES}:${DISTROOVERRIDES}:${CLASSOVERRIDE}${LIBCOVERRIDE}:forcevariable"
812FILE_LAYERNAME ??= "config"
813LIBCOVERRIDE ?= ""
814CLASSOVERRIDE ?= "class-target"
815DISTROOVERRIDES ?= "${@d.getVar('DISTRO') or ''}"
816MACHINEOVERRIDES ?= "${MACHINE}"
817
818FILESOVERRIDES = "${TRANSLATED_TARGET_ARCH}:${MACHINEOVERRIDES}:${DISTROOVERRIDES}"
819
820##################################################################
821# Include the rest of the config files.
822##################################################################
823
824require conf/abi_version.conf
825include conf/site.conf
826include conf/auto.conf
827include conf/local.conf
828require conf/multiconfig/${BB_CURRENT_MC}.conf
829include conf/machine/${MACHINE}.conf
830include conf/machine-sdk/${SDKMACHINE}.conf
831include conf/distro/${DISTRO}.conf
832include conf/distro/defaultsetup.conf
833include conf/documentation.conf
834include conf/licenses.conf
835require conf/sanity.conf
836require conf/cve-check-map.conf
837include conf/bblock.conf
838
839##################################################################
840# Weak variables (usually to retain backwards compatibility)
841##################################################################
842
843DL_DIR ?= "${TOPDIR}/downloads"
844SSTATE_DIR ?= "${TOPDIR}/sstate-cache"
845IMAGE_FSTYPES ?= "tar.gz"
846IMAGE_FSTYPES_DEBUGFS ?= "tar.gz"
847
848INITRAMFS_FSTYPES ?= "cpio.gz"
849# The maximum size in Kbytes for the generated initramfs image size.
850# Usually, it should be less than 1/2 of ram size, or you may fail to
851# boot it.
852INITRAMFS_MAXSIZE ??= "131072"
853
854DEFAULT_TASK_PROVIDER ?= "packagegroup-base"
855MACHINE_TASK_PROVIDER ?= "${DEFAULT_TASK_PROVIDER}"
856
857# The size in Kbytes for the generated image if it is larger than
858# the required size (du -ks IMAGE_ROOTFS * IMAGE_OVERHEAD_FACTOR),
859# and no effect if less than it.
860IMAGE_ROOTFS_SIZE ??= "65536"
861
862# Forcefully set CACHE now so future changes to things like
863# MACHINE don't change the path to the cache
864CACHE := "${CACHE}"
865
866# Default to setting automatically based on cpu count
867BB_NUMBER_THREADS ?= "${@oe.utils.cpu_count()}"
868
869# Default to setting automatically based on cpu count
870PARALLEL_MAKE ?= "-j ${@oe.utils.cpu_count()}"
871
872# Default parallelism and resource usage for xz
873XZ_MEMLIMIT ?= "50%"
874XZ_THREADS ?= "${@oe.utils.cpu_count(at_least=2)}"
875XZ_THREADS[vardepvalue] = "1"
876XZ_DEFAULTS ?= "--memlimit=${XZ_MEMLIMIT} --threads=${XZ_THREADS}"
877XZ_DEFAULTS[vardepsexclude] += "XZ_MEMLIMIT XZ_THREADS"
878
879# Default parallelism for zstd
880ZSTD_THREADS ?= "${@oe.utils.cpu_count(at_least=2)}"
881ZSTD_THREADS[vardepvalue] = "1"
882
883ZSTD_COMPRESSION_LEVEL ?= "-3"
884ZSTD_DEFAULTS ?= "--threads=${ZSTD_THREADS} ${ZSTD_COMPRESSION_LEVEL}"
885ZSTD_DEFAULTS[vardepsexclude] = "ZSTD_THREADS"
886
887# Limit the number of threads that OpenMP libraries will use. Otherwise they
888# may fallback to using all CPUs
889export OMP_NUM_THREADS = "${BB_NUMBER_THREADS}"
890
891##################################################################
892# Magic Cookie for SANITY CHECK
893##################################################################
894OES_BITBAKE_CONF = "1"
895
896##################################################################
897# Machine properties and packagegroup-base stuff
898##################################################################
899
900MACHINE_FEATURES ?= ""
901SDK_MACHINE_FEATURES ?= ""
902
903DISTRO_FEATURES ?= ""
904
905DISTRO_EXTRA_RDEPENDS ?= ""
906DISTRO_EXTRA_RRECOMMENDS ?= ""
907MACHINE_EXTRA_RDEPENDS ?= ""
908MACHINE_EXTRA_RRECOMMENDS ?= ""
909MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
910MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
911
912EXTRA_IMAGE_FEATURES ??= ""
913IMAGE_FEATURES += "${EXTRA_IMAGE_FEATURES}"
914
915# Native distro features (will always be used for -native, even if they
916# are not enabled for target)
917DISTRO_FEATURES_NATIVE ?= "acl x11 ipv6 xattr"
918DISTRO_FEATURES_NATIVESDK ?= "x11"
919
920# Normally target distro features will not be applied to native builds:
921# Native distro features on this list will use the target feature value
922DISTRO_FEATURES_FILTER_NATIVE ?= "api-documentation debuginfod opengl wayland"
923DISTRO_FEATURES_FILTER_NATIVESDK ?= "api-documentation debuginfod opengl wayland"
924
925DISTRO_FEATURES_BACKFILL = "pulseaudio sysvinit gobject-introspection-data ldconfig"
926MACHINE_FEATURES_BACKFILL = "rtc qemu-usermode"
927
928COMBINED_FEATURES = "${@oe.utils.set_intersect('DISTRO_FEATURES', 'MACHINE_FEATURES', d)}"
929COMBINED_FEATURES[vardeps] += "DISTRO_FEATURES MACHINE_FEATURES"
930
931SERIAL_CONSOLES ??= ""
932
933NO_RECOMMENDATIONS ??= ""
934BAD_RECOMMENDATIONS ?= ""
935
936# Make sure SHELL isn't exported
937# (can break any number of things if the user's shell isn't POSIX-compliant,
938# including the flock command). The user's shell shouldn't affect our builds.
939SHELL[unexport] = "1"
940
941# Used by canadian-cross to handle string conversions on TARGET_ARCH where needed
942TRANSLATED_TARGET_ARCH ??= "${@d.getVar('TARGET_ARCH').replace("_", "-")}"
943
944# Set a default umask to use for tasks for determinism
945BB_DEFAULT_UMASK ??= "022"
946
947# Complete output from bitbake
948BB_CONSOLELOG ?= "${LOG_DIR}/cooker/${MACHINE}/${DATETIME}.log"
949BB_DEFAULT_EVENTLOG ?= "${LOG_DIR}/eventlog/${DATETIME}.json"
950
951# Setup our default hash policy
952BB_SIGNATURE_HANDLER ?= "OEBasicHash"
953BB_HASHEXCLUDE_COMMON ?= "TMPDIR FILE PATH PWD BB_TASKHASH BBPATH BBSERVER DL_DIR \
954    THISDIR FILESEXTRAPATHS FILE_DIRNAME HOME LOGNAME SHELL \
955    USER FILESPATH STAGING_DIR_HOST STAGING_DIR_TARGET COREBASE PRSERV_HOST \
956    STAMPS_DIR PRSERV_DUMPDIR PRSERV_DUMPFILE PRSERV_LOCKDOWN PARALLEL_MAKE \
957    CCACHE_DIR EXTERNAL_TOOLCHAIN CCACHE CCACHE_NOHASHDIR LICENSE_PATH SDKPKGSUFFIX \
958    WARN_QA WORKDIR STAMPCLEAN PKGDATA_DIR BUILD_ARCH SSTATE_PKGARCH \
959    BB_WORKERCONTEXT BB_LIMITEDDEPS BB_UNIHASH extend_recipe_sysroot DEPLOY_DIR \
960    SSTATE_HASHEQUIV_METHOD SSTATE_HASHEQUIV_REPORT_TASKDATA \
961    SSTATE_HASHEQUIV_OWNER CCACHE_TOP_DIR BB_HASHSERVE GIT_CEILING_DIRECTORIES \
962    OMP_NUM_THREADS BB_CURRENTTASK"
963BB_BASEHASH_IGNORE_VARS ?= "${BB_HASHEXCLUDE_COMMON} PSEUDO_IGNORE_PATHS BUILDHISTORY_DIR \
964    SSTATE_DIR SOURCE_DATE_EPOCH RUST_BUILD_SYS RUST_HOST_SYS RUST_TARGET_SYS"
965BB_HASHCONFIG_IGNORE_VARS ?= "${BB_HASHEXCLUDE_COMMON} DATE TIME SSH_AGENT_PID \
966    SSH_AUTH_SOCK PSEUDO_BUILD BB_ENV_PASSTHROUGH_ADDITIONS DISABLE_SANITY_CHECKS \
967    PARALLEL_MAKE BB_NUMBER_THREADS BB_ORIGENV BB_INVALIDCONF BBINCLUDED \
968    GIT_PROXY_COMMAND ALL_PROXY all_proxy NO_PROXY no_proxy FTP_PROXY ftp_proxy \
969    HTTP_PROXY http_proxy HTTPS_PROXY https_proxy SOCKS5_USER SOCKS5_PASSWD \
970    BB_SETSCENE_ENFORCE BB_CMDLINE BB_SERVER_TIMEOUT BB_NICE_LEVEL"
971BB_SIGNATURE_EXCLUDE_FLAGS ?= "doc deps depends \
972    lockfiles vardepsexclude vardeps vardepvalue vardepvalueexclude \
973    file-checksums python task nostamp \
974    sstate-lockfile-shared prefuncs postfuncs export_func deptask rdeptask \
975    recrdeptask nodeprrecs stamp-extra-info sstate-outputdirs filename lineno \
976    progress mcdepends number_threads"
977BB_HASH_CODEPARSER_VALS = "LOGFIFO=/ T=/ WORKDIR=/ DATE=1234 TIME=1234 PV=0.0-1 PN=no-pn METADATA_REVISION=1234 SRC_URI="
978
979MLPREFIX ??= ""
980MULTILIB_VARIANTS ??= ""
981
982# Older versions of bitbake (< 1.42) don't set BB_UNIHASH. For compatibility with these
983# versions, set BB_UNIHASH equivalent to BB_TASKHASH if unspecified, which is
984# what it would be anyway if the signature generator (e.g. OEEquivHash) doesn't
985# support unihashes.
986BB_UNIHASH ?= "${BB_TASKHASH}"
987
988oe.sstatesig.find_sstate_manifest[vardepsexclude] = "BBEXTENDCURR BBEXTENDVARIANT OVERRIDES PACKAGE_EXTRA_ARCHS"
989oe.utils.get_multilib_datastore[vardepsexclude] = "DEFAULTTUNE_MULTILIB_ORIGINAL OVERRIDES"
990oe.path.format_display[vardepsexclude] = "TOPDIR"
991oe.utils.get_bb_number_threads[vardepsexclude] = "BB_NUMBER_THREADS"
992oe.packagedata.emit_pkgdata[vardepsexclude] = "BB_NUMBER_THREADS"
993oe.packagedata.read_subpkgdata_extended[vardepsexclude] = "BB_NUMBER_THREADS"
994