1project('phosphor-dbus-interfaces', 'cpp',
2    meson_version: '>=1.1.1',
3    default_options: [
4        'buildtype=debugoptimized',
5        'cpp_std=c++23',
6        'warning_level=3',
7        'werror=true',
8        'generate_md=' + (meson.is_subproject() ? 'false' : 'true'),
9    ],
10    version: '1.0.0',
11)
12
13sdbusplus_dep = dependency('sdbusplus')
14sdbusplusplus_prog = find_program('sdbus++', native: true)
15sdbuspp_gen_meson_prog = find_program('sdbus++-gen-meson', native: true)
16sdbusplusplus_depfiles = files()
17if sdbusplus_dep.type_name() == 'internal'
18    sdbusplusplus_depfiles = subproject('sdbusplus').get_variable('sdbusplusplus_depfiles')
19endif
20
21# Parse options to determine appropriate subdirectories to support.
22selected_subdirs = []
23if get_option('data_com_google')
24    selected_subdirs += 'com/google'
25endif
26if get_option('data_com_ibm')
27    selected_subdirs += 'com/ibm'
28endif
29if get_option('data_com_intel')
30    selected_subdirs += 'com/intel'
31endif
32if get_option('data_com_meta')
33    selected_subdirs += 'com/meta'
34endif
35if get_option('data_org_freedesktop')
36    selected_subdirs += 'org/freedesktop'
37endif
38if get_option('data_org_open_power')
39    selected_subdirs += 'org/open_power'
40endif
41if get_option('data_xyz_openbmc_project')
42    selected_subdirs += 'xyz/openbmc_project'
43endif
44
45# Install the selected YAML files.
46inst_yaml_dir = get_option('datadir') / 'phosphor-dbus-yaml/yaml'
47foreach d : selected_subdirs
48    install_subdir(
49        'yaml' / d,
50        install_dir: inst_yaml_dir / d,
51        strip_directory: true,
52    )
53endforeach
54
55# If libphosphor_dbus was not enabled, exit out from here.  We installed
56# the YAML which is all we are asked to do.
57if not get_option('libphosphor_dbus')
58    subdir_done()
59endif
60
61generated_sources = []
62generated_others = []
63yaml_sources = []
64
65# Source the generated meson files.
66subdir('gen')
67foreach d : selected_subdirs
68  subdir('gen' / d)
69endforeach
70custom_target(
71    'md',
72    command: 'true',
73    output: 'md',
74    capture: true,
75    depends: generated_others,
76    build_by_default: get_option('generate_md'))
77
78generated_files_headers = []
79generated_files_cpp = []
80foreach s : generated_sources
81    foreach f : s.to_list()
82        p = f.full_path()
83        if p.endswith('.hpp')
84            generated_files_headers += f
85        elif p.endswith('.cpp')
86            generated_files_cpp += f
87        else
88            error('Unknown filetype: ' + p)
89        endif
90    endforeach
91endforeach
92
93generated_root = meson.current_build_dir() / 'gen/'
94exclude_cpp = []
95foreach f : generated_files_cpp
96    exclude_cpp += f.full_path().replace(generated_root, '').strip('/')
97endforeach
98
99# Install the generated header files.
100exclude = exclude_cpp
101foreach o : generated_others
102    foreach f : o.to_list()
103        exclude += f.full_path().replace(generated_root, '').strip('/')
104    endforeach
105endforeach
106install_subdir(
107    generated_root,
108    exclude_files: exclude,
109    install_dir: get_option('includedir'),
110    strip_directory: true,
111)
112
113# Install the generated markdown files.
114exclude = exclude_cpp
115foreach f : generated_files_headers
116    exclude += f.full_path().replace(generated_root, '').strip('/')
117endforeach
118install_subdir(
119    generated_root,
120    exclude_files: exclude,
121    install_dir: get_option('datadir') / 'doc' / meson.project_name(),
122    strip_directory: true,
123)
124
125# Define and build libphosphor_dbus.so from the C++ files.
126libphosphor_dbus = library(
127    'phosphor_dbus',
128    generated_sources,
129    implicit_include_directories: false,
130    include_directories: include_directories('gen'),
131    dependencies: sdbusplus_dep,
132    version: meson.project_version(),
133    install: true,
134)
135
136import('pkgconfig').generate(
137    libphosphor_dbus,
138    name: meson.project_name(),
139    version: meson.project_version(),
140    description: 'Generated sdbusplus bindings for phosphor-dbus-interfaces',
141    variables: ['yamldir=' + '${pc_sysrootdir}${prefix}' / inst_yaml_dir],
142)
143
144phosphor_dbus_interfaces_dep = declare_dependency(
145    sources: generated_files_headers,
146    include_directories: include_directories('gen'),
147    link_with: libphosphor_dbus,
148    dependencies: sdbusplus_dep,
149    variables: ['yamldir=' + meson.project_source_root() / 'yaml'],
150)
151
152meson.override_dependency('phosphor-dbus-interfaces', phosphor_dbus_interfaces_dep)
153